VBA從Excel到Word查找並替換錯誤

Question

我試圖創建VBA宏，該宏復制用戶輸入的變量並在文本詞中搜索特定字段並替換它，我在堆棧溢出和其他論壇中嘗試了很多代碼，但我沒有成功下面的代碼可以正常工作，但它沒有不要替換單詞，代碼會搜索該字段並將變量放在旁邊。 如果有人有解決方案：D

Sub CreateNewWordDoc()
Dim wrdApp As Word.Application
Dim wrdDoc As Word.Document
Dim i As Integer
Set wrdApp = CreateObject("Word.Application")
wrdApp.Visible = True
Set wrdDoc = wrdApp.Documents.Add
Set wrdDoc = wrdApp.Documents.Open("D:\pfe\DECfinal1.doc")
With wrdDoc
.Application.Selection.Find.Text = "Nombre d'alésage"
.Application.Selection.Find.Execute
.Application.Selection = Sheets("Dec").Range("A2")

End With

End Sub

Answer 1

就像我說的那樣，您的代碼對我有用。 但是為了安全起見，請使用對象進行操作並直接搜索並替換。 看到這個

Sub CreateNewWordDoc()
    Dim wrdApp As Word.Application
    Dim wrdDoc As Word.Document

    Set wrdApp = CreateObject("Word.Application")
    wrdApp.Visible = True

    Set wrdDoc = wrdApp.Documents.Open("C:\Users\Siddharth\Desktop\DECfinal89.doc")

    With wrdDoc
        For Each rngStory In .StoryRanges
            Do
                With rngStory.Find
                    .Text = "Nombre d'alésage"
                    .Replacement.Text = Sheets("Dec").Range("A2")
                    .Wrap = wdFindContinue
                    .Execute Replace:=wdReplaceAll
                End With
                Set rngStory = rngStory.NextStoryRange
            Loop Until rngStory Is Nothing
          Next
    End With
End Sub