從一個存儲過程返回值到另一個

Question

我想使用從一個存儲過程到另一個存儲過程的返回值。 我在互聯網上搜索並嘗試了幾種解決方案，但所有解決方案均無法正常工作，我不知道自己犯了什么錯誤。

我要使用其返回值的存儲過程是：

CREATE PROCEDURE dbo.pro_ForeignKeyCheck
     (@tableName VARCHAR(100),
      @columnName VARCHAR(100),
      @idValue INT) 
AS BEGIN
    SET NOCOUNT ON

    DECLARE fksCursor CURSOR FAST_FORWARD FOR 
        SELECT 
            tc.table_name, ccu.column_name
        FROM
            information_schema.table_constraints tc 
        JOIN
            information_schema.constraint_column_usage ccu ON tc.constraint_name = ccu.constraint_name 
        JOIN
            information_schema.referential_constraints rc ON tc.constraint_name = rc.constraint_name 
        JOIN
            information_schema.table_constraints tc2 ON rc.unique_constraint_name = tc2.constraint_name 
        JOIN
            information_schema.constraint_column_usage ccu2 ON tc2.constraint_name = ccu2.constraint_name 
        WHERE
            tc.constraint_type = 'Foreign Key' 
            AND tc2.table_name = @tableName 
            AND ccu2.column_name = @columnName
        ORDER BY
            tc.table_name

    DECLARE @fkTableName VARCHAR(100),
            @fkColumnName VARCHAR(100),
            @fkFound BIT,
            @params NVARCHAR(100),
            @sql NVARCHAR(500)

    OPEN fksCursor

    FETCH NEXT FROM fksCursor INTO @fkTableName, @fkColumnName

    SET @fkFound = 0
    SET @params = N'@fkFound BIT OUTPUT'

    WHILE @@fetch_status = 0 AND COALESCE(@fkFound, 0) <> 1 
    BEGIN
        SELECT @sql = 'set @fkFound = (select top 1 1 from [' + @fkTableName + '] where [' + @fkColumnName + '] = ' + cast(@idValue as varchar(10)) + ')'
        PRINT @sql

        EXEC sp_executesql @sql, @params, @fkFound OUTPUT

        FETCH NEXT FROM fksCursor INTO @fkTableName, @fkColumnName
    END

    CLOSE fksCursor
    DEALLOCATE fksCursor

    SELECT COALESCE(@fkFound, 0)
    RETURN 0
END

並用於檢查所有子表中是否使用了主鍵值，我們這樣稱呼它

EXECUTE  pro_ForeignKeyCheck 'tablename','columnName', 1

要么

EXECUTE  pro_ForeignKeyCheck @tablename = 'tablename', @columnName = 'columnName', @idValue = 1

它將起作用，但是我不能在其他存儲過程中使用返回值

CREATE  PROCEDURE [dbo].[pro_Delete_acount]
    @UserID int,
    @Action NVARCHAR(10)
AS
BEGIN
    SET NOCOUNT ON;
    DECLARE  @count int , @ErrNo int , @ErrMsg varchar(2000), @exit int



    set @exit=0
    if @Action ='ADMIN'
    begin
    /*---------Call Store Procedure pro_ForeignKeyCheck to check if there is value are exit in child table*/
    --EXEC  @exit = pro_ForeignKeyCheck1 @tablename='tb_M_admin',@columnName='admin_id',@idValue= @UserID 
    --select @exit

    --EXEC   @exit = pro_ForeignKeyCheck  @tablename='tb_M_admin',@columnName='admin_id',@idValue= 1

    EXEC @exit = pro_ForeignKeyCheck 'tb_M_admin','admin_id', 0 
    --select @exit

    select -2[Ret_Status],@exit[ErrNo],0[ErrMsg] -- test 

    end
end

有人可以幫我嗎？

謝謝大家

Answer 1

加

@Status int OUTPUT

在pro_ForeignKeyCheck所以它以

CREATE PROCEDURE dbo.pro_ForeignKeyCheck1
@tableName VARCHAR(100),
@columnName VARCHAR(100),
@idValue int,
@Status int OUTPUT

最后它做了如下

--select coalesce(@fkFound,0)
select @Status = coalesce(@fkFound,0)
--return 0

停止最后一行並添加新的

在另一個存儲過程中，按如下方式調用它

EXEC  pro_ForeignKeyCheck1 'tb_M_admin','admin_id', 0 ,@exit output 
select @exit

現在將使用返回值。

謝謝大家

Answer 2

EXEC @exit = pro_ForeignKeyCheck 'tb_M_admin','admin_id', 0 

---
select coalesce(@fkFound,0)
return 0 --< this will be assigned to @exit

將此代碼替換為

return IsNull(@fkFound, 0)

您可以將select留作其他用途，但它不會影響RETURN值。 因此，您可以將其刪除。

Answer 3

這是從一個SP調用另一個SP的過度簡化的示例。 我希望它能給您一些想法。

create procedure dbo.first_proc
@bd datetime,
@d int output
as
select @d= DATEDIFF(day,@bd,getdate()) 
go

create procedure dbo.sec_proc
@birthday datetime
as
declare @days int
exec dbo.first_proc @birthday, @days output

select 'you live '+cast(@days as varchar) + ' days' result
go

exec dbo.sec_proc '1959-09-17'