VBA-Excel強制重新啟動

Question

我的代碼存在一個主要問題，該代碼應該重置工作表，而不是關閉整個工作簿並強制重新啟動。 這不是問題，僅在我添加了從On Error Resume Next開始的最后一段代碼以來才發生。

Sub Reset()

    Application.ScreenUpdating = False

    Dim ws As Worksheet

    For Each ws In ThisWorkbook.Worksheets
        If ws.Name = "Set Up" Or ws.Name = "Report" Then
            Else:
                Application.DisplayAlerts = False
                ws.Delete
        End If
    Next

    Worksheets("Report").Cells.ClearContents

    On Error Resume Next
    Application.DisplayAlerts = False
    ThisWorkbook.Charts.Delete
    Application.DisplayAlerts = True
    On Error GoTo 0

End Sub

提前致謝

Answer 1

如果有圖表表，則應使用以下代碼：

Sub DeleteChartSheets()

    Dim ch As Chart

    For Each ch In ThisWorkbook.Charts
        ch.Delete
    Next

End Sub

Answer 2

這會刪除工作清單（例如活動表）中的圖表，例如：

Sub DeleteallCharts() 
    Dim chtObj As ChartObject 
    For Each chtObj In ActiveSheet.ChartObjects
        chtObj.Delete 
    Next 
End Sub

如果要刪除工作簿中的所有圖表，則必須像這樣循環遍歷工作表：

Sub DeleteallChartsInWorkbook() 
    Dim chtObj As ChartObject 
    Dim WS As Worksheet
    For Each WS in Thisworkbook.Worksheets
        For Each chtObj In WS.ChartObjects
            chtObj.Delete 
        Next chtObj 
    Next WS
End Sub