如何檢查 excel 單元格是否包含單詞

Question

我正在尋找一個 excel 公式，如果單元格包含單詞模式（基本上想知道是否存在任何這樣的單元格），則該公式計數或返回 true，但公式僅在以下情況下才將單元格識別為有效

要求 1：存在完整的單詞模式並作為正在檢查的單元格中的單個單詞（例如：如果 ab12 是模式，ab123 無效，只有 ab12 有效）

要求2：匹配詞可以在被檢查單元格的開頭或結尾或中間

要求 3：被檢查的輸入單元格可能包含此匹配詞，並且可以包含前綴/后綴為“”（空格）或換行符/提要。 因此，該公式應將此單元格識別為對這兩種情況都有效

示例單詞模式：ab-1_cd_1234

目前我已經嘗試了下面的兩個公式（也嘗試在標准中使用“”、“*”、“~”）但沒有奏效：

公式 1：=ISNUMBER(SEARCH(A2,B2))

          Here, A2 is the pattern, B2 is the input to verify and will be verified in full B column

公式 2： =COUNTIF($B:$B, "* " &A2& " *")

          Here, B:B is the input column and A2 is the pattern

另外，我知道單詞 < 和 > 中有一個通配符，它定義了一個單詞的開頭和結尾，但在 excel 中同樣不起作用。

所以，如果我能得到任何適用於 excel 的公式，那就太好了

Answer 1

請試試這個公式，其中 A3 是要搜索的文本，要找到的文本在 A1 中。

=IF(ISERROR(FIND(" "&$A$1&" "," "&SUBSTITUTE(A3,CHAR(10)," ")&" ")),"",TRUE)

Answer 2

您可以嘗試以下公式：

=SUMPRODUCT(--($A$2=FILTERXML("<a><b>" & SUBSTITUTE(SUBSTITUTE(B2,CHAR(10),"</b><b>")," ","</b><b>") & "</b></a>","//b")))>0

編輯

要解決空字符串的問題：

=SUMPRODUCT(--($A$2 & "#"=FILTERXML("<a><b>" & SUBSTITUTE(SUBSTITUTE(B2,CHAR(10),"#</b><b>")," ","#</b><b>") & "#</b></a>","//b")))>0

編輯2：要計算包含模式的單元格數，您可以使用數組公式：

=SUMPRODUCT(--(IFERROR(SEARCH(" " & A2 & " "," " & SUBSTITUTE($B$2:$B$10,CHAR(10)," ") & " "),0)>0))

按ctrl + shift + enter確認編輯后的數組公式