為 Oracle function 定義一個 CLOB 輸入參數（或使用 CLOB 輸入參數定義一個 function）

Question

我將運行如下代碼塊：

CREATE OR REPLACE FUNCTION func_name (START_DATE NUMBER,END_DATE NUMBER, NAME clob)
                     .
                     .
                     .
        select * from table_name
        where name_desc in NAME
                     .
                     .
                     .
 END;

其中其目的是創建一個 function，其輸入參數之一是 CLOB 數據類型。 但是通過執行我的代碼，我得到以下錯誤：

ORA-01704: 字符串文字太長

我在互聯網上以及在 stackoverflow 問題中進行了搜索，但沒有得到任何結果。

你能幫我解決這個問題嗎？

Answer 1

我相信我理解你想要達到的目標。 根據評論，您對IN的使用是錯誤的。 IN需要來自 select 的文字列表或值列表，但您的 CLOB 值兩者都不是，它只是一個需要先處理的長字符串，然后才能在SELECT中使用它，就像您在評論中提到的那樣。

要使用以 分隔的名稱列表處理您的 CLOB ,您可以在 CLOB 中找到第一個逗號並從 CLOB 的開頭提取值，直到第一個分隔符和找到的值被放入集合中（分隔符被刪除 ofc 並且值被修剪，這可能是可選，因為我不確定您的輸入看起來如何）。 接下來，您從 CLOB 的開頭刪除找到的值並重復，直到在此 CLOB 中沒有要處理的內容。 一旦您擁有集合中的值列表，您就可以在原始SELECT SELECT

試試這個例子：

CREATE TABLE table_name (
  name_desc VARCHAR2(250) NOT NULL
);

INSERT INTO table_name (name_desc)
VALUES ('Lorem');
INSERT INTO table_name (name_desc)
VALUES ('ipsum');
INSERT INTO table_name (name_desc)
VALUES ('test');

COMMIT;

CREATE OR REPLACE TYPE name_list_tabt IS TABLE OF VARCHAR2(4000);
/

CREATE OR REPLACE PROCEDURE func_name(p_start_date NUMBER,
                                      p_end_date   NUMBER,
                                      p_name       CLOB) IS
  v_delimiter VARCHAR2(1) := ',';
  v_name CLOB := p_name;
  v_delimiter_pos NUMBER;
  v_name_value VARCHAR2(4000);
  v_name_list name_list_tabt := name_list_tabt();
BEGIN

  -- OTHER CODE ABOVE ...

  LOOP
    -- Get position of delimiter
    v_delimiter_pos := dbms_lob.instr(v_name, v_delimiter, 1, 1);
    -- If no comma is found we get rest of the CLOB for last name, if there is no more CLOB to process this will return 0
    IF v_delimiter_pos = 0
    THEN
      v_delimiter_pos := dbms_lob.getlength(v_name);
    END IF;
    -- Get next name based on delimiter position, can cause error if single name is over 4000 bytes long
    v_name_value := dbms_lob.substr(v_name, v_delimiter_pos, 1);
    -- Next code will remove found name from CLOB start
    v_name := regexp_replace(v_name, v_name_value, NULL, 1, 1);
    -- If we reached the end of CLOB, exit
    IF v_delimiter_pos = 0
    THEN
      EXIT;
    END IF;
    -- Add new name to collection if it is not empty
    IF TRIM(REPLACE(v_name_value, v_delimiter)) IS NOT NULL
    THEN
      v_name_list.extend();
      v_name_list(v_name_list.count) := TRIM(REPLACE(v_name_value, v_delimiter));
    END IF;
  END LOOP;
  -- Your select in for loop just to make this code working, adjust as you need
  FOR i IN (SELECT *
              FROM table_name
             WHERE name_desc IN (SELECT /*+ dynamic_sampling(t 2) */
                                  column_value
                                   FROM TABLE(v_name_list) t))
  LOOP
    dbms_output.put_line(i.name_desc); -- Just some test output
  END LOOP;

  -- OTHER CODE BELOW ...

END;
/

BEGIN
  -- Example with different, even possibly incorrect values
  func_name(p_start_date => 1,
            p_end_date   => 2,
            p_name       => 'Lorem,ipsum,dolor,sit,amet,consectetur, 
 ,,adipiscing,elit,Etiam,interdum,ligula,    ,     ,');
  -- Based on table values and CLOB here output should be "Lorem" and "ipsum"
END;
/