自動過濾后excel VBA刪除行

Question

您好，我正在嘗試為我工作的部分業務創建一個按鈕，該按鈕根據條件進行過濾，然后刪除這些整行。 我對它的“過濾”部分很好，這是成功的，我只是無法刪除已過濾的整個行。 我嘗試了不同的代碼，下面是我嘗試過但失敗的最后一個。 失敗發生在“刪除行”注釋下方

Sub delete_stage()

Dim ws As Worksheet

Set ws = ThisWorkbook.Worksheets("Sales Pipeline Report")
ws.Activate

'Clear any existing filters
On Error Resume Next
ws.ShowAllData
On Error GoTo 0

' filter cells on criterea

ws.Range("$E$2").AutoFilter Field:=4, Criteria1:="Onboarding"

'Delete Rows

 ws.Range("$E$2").Offset(1, 0).SpecialCells(xlCellTypeVisible).EntireRow.Delete


'3. Clear Filter
On Error Resume Next
ws.ShowAllData
On Error GoTo 0

希望有人能幫忙。 我覺得它不應該像我做的那么難:-s

Answer 1

刪除過濾的行（自動過濾）

編碼

Option Explicit

Sub deleteFilteredRows()
  
    ' Define constants.
  
    Const wsName As String = "Sales Pipeline Report"
    Const FirstCell As String = "E2"
    Const afField As Long = 4
    Const Criteria As String = "Onboarding"
      
    ' Define Source Range.
    
    ' Define Success Boolean.
    Dim Success As Boolean
    ' Define Worksheet.
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Worksheets(wsName)
    ' Define First Cell Range ('cel').
    Dim cel As Range
    Set cel = ws.Range(FirstCell)
    ' Define Current Region ('rng').
    Dim rng As Range
    Set rng = cel.CurrentRegion
    ' Define Source Range ('rng').
    Set rng = cel _
      .Resize(rng.Rows.Count + rng.Row - cel.Row, _
              rng.Columns.Count + rng.Column - cel.Column)
    
    ' Delete filtered rows.
    
    ' Turn off screen updating.
    Application.ScreenUpdating = False
    ' Turn off AutoFilter.
    If ws.AutoFilterMode Then
        ws.AutoFilterMode = False
    End If
    ' Filter Source Range.
    rng.AutoFilter Field:=afField, Criteria1:=Criteria
    ' Try to define Filtered Range ('rng').
    Dim dRng As Range
    On Error Resume Next
    Set dRng = rng.Resize(rng.Rows.Count - 1).Offset(1) _
                                             .SpecialCells(xlCellTypeVisible)
    On Error GoTo 0
    ' Validate Filtered Range.
    If dRng Is Nothing Then
        GoTo SafeExit
    End If
    ' Delete entire rows of Filtered Range.
    dRng.EntireRow.Delete
    ' Validate Success.
    Success = True
SafeExit:
    ' Clear filter.
    ws.ShowAllData
    ' Turn on screen updating.        
    Application.ScreenUpdating = True

    ' Inform user.
    
    If Success = True Then
        MsgBox "Rows of filtered data deleted.", vbInformation, "Success"
    Else
        MsgBox "No action taken.", vbCritical, "Fail"
    End If

End Sub