如何在NSIS中檢測windows 7

Question

現在我們使用 windows 表格。 NSIS 用於 windows 表單安裝。 但是我需要在 windows 7 os 中阻止安裝該怎么做？ 我正在使用下面的代碼。

; Script generated by the HM NIS Edit Script Wizard.

; HM NIS Edit Wizard helper defines
!define PRODUCT_TYPE "Home"    ; Home/Clinic ------
!define CONFIG_TYPE "Prod"    ; Release/Local/Devl/Devl_Test/Demo/Test/Prod ------
!define PRODUCT_NAME "nQ Medical ${PRODUCT_TYPE} Keyboard"
!define PRODUCT_VERSION "1.2.0"
!define PRODUCT_PUBLISHER "nQ Medical Inc."
!define PRODUCT_WEB_SITE "https://platform.nq-medical.com"
!define PRODUCT_DIR_REGKEY "Software\Microsoft\Windows\CurrentVersion\App Paths\${APP_NAME}"
!define PRODUCT_UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_NAME}"
!define PRODUCT_UNINST_ROOT_KEY "HKLM"
!define APP_NAME "nQKeyboard.exe"

; MUI 1.67 compatible ------
!include "MUI.nsh"
; MUI Settings
!define MUI_ABORTWARNING
!define MUI_ICON "nQKeyboard\iconNQ.ico"
!define MUI_UNICON "${NSISDIR}\Contrib\Graphics\Icons\modern-uninstall.ico"

RequestExecutionLevel admin

; Welcome page
!insertmacro MUI_PAGE_WELCOME
; License page
!insertmacro MUI_PAGE_LICENSE "nQKeyboard\bin\${CONFIG_TYPE}\EULA.txt"
; Directory page
!insertmacro MUI_PAGE_DIRECTORY
; Instfiles page
!insertmacro MUI_PAGE_INSTFILES
; Finish page
!define MUI_FINISHPAGE_RUN "$INSTDIR\${APP_NAME}"
!insertmacro MUI_PAGE_FINISH
; Uninstaller pages
!insertmacro MUI_UNPAGE_INSTFILES
; Language files
!insertmacro MUI_LANGUAGE "English"
; MUI end ------

Name "${PRODUCT_NAME}"
;Currently deploys the installer file to a 'Published' sub-directory in the 'Solution' directory
OutFile "Published\nQ Medical ${PRODUCT_TYPE} Keyboard.exe"
InstallDir "$PROGRAMFILES\nQ Medical Keyboard"
InstallDirRegKey HKLM "${PRODUCT_DIR_REGKEY}" ""
ShowInstDetails show
ShowUnInstDetails show

Section "MainSection" SEC01
  ; Kill the running application
  ExecWait "TaskKill /IM ${APP_NAME} /F"
  SetOutPath "$INSTDIR"
  SetOverwrite try
  File "nQKeyboard\bin\${CONFIG_TYPE}\iconNQ.ico"
  File "nQKeyboard\bin\${CONFIG_TYPE}\Newtonsoft.Json.dll"
  File "nQKeyboard\bin\${CONFIG_TYPE}\RestSharp.dll"
  File "nQKeyboard\bin\${CONFIG_TYPE}\RestSharp.Serializers.NewtonsoftJson.dll"
  File "nQKeyboard\bin\${CONFIG_TYPE}\GraphQL.Client.dll"
  File "nQKeyboard\bin\${CONFIG_TYPE}\GraphQL.Common.dll"
  File "nQKeyboard\bin\${CONFIG_TYPE}\EULA.txt"
  File "nQKeyboard\bin\${CONFIG_TYPE}\${APP_NAME}"
  CreateDirectory "$SMPROGRAMS\nQ Medical Keyboard"
  CreateShortCut "$SMPROGRAMS\nQ Medical Keyboard\nQ Medical Keyboard.lnk" "$INSTDIR\${APP_NAME}"
  CreateShortCut "$DESKTOP\nQ Medical Keyboard.lnk" "$INSTDIR\${APP_NAME}"
  File "nQKeyboard\bin\${CONFIG_TYPE}\${APP_NAME}.config"
SectionEnd.

那么如何添加代碼段呢？ IE; 如果 windows 7 是操作系統，則不會進行安裝。 執行腳本時顯示錯誤信息。 怎么做？

Answer 1

NSIS 提供了 WinVer.nsh header 文件，可以幫助您檢測各種 Windows 版本。

版本檢測乍一看似乎很簡單，但很容易出錯，而且您的問題並沒有真正提供足夠的信息來寫出明確的答案！

你的問題的天真答案是

!include WinVer.nsh

Function .onInit
${If} ${IsWin7}
    MessageBox MB_ICONSTOP "Windows version blah blah!"
    SetErrorLevel 1150 ; ERROR_OLD_WIN_VERSION
    Quit
${EndIf}
FunctionEnd

起初這似乎很好，但假設有一些技術原因導致您的應用程序無法在 Windows 7 上運行，那么您可能還需要阻止 Server 2008 R2，因為它與 Windows 的版本基本相同：

${If} ${IsWin7}
${OrIf} ${IsWin2008R2}
  ...

大多數時候你有一些你支持的 Windows 的最低版本，你真的應該阻止任何舊版本。 最好的方法是確保您使用的是您支持的版本：

!include WinVer.nsh

Function .onInit
${IfNot} ${AtLeastWin8}
    MessageBox MB_ICONSTOP "Windows version blah blah!"
    SetErrorLevel 1150 ; ERROR_OLD_WIN_VERSION
    Quit
${EndIf}
FunctionEnd

如果您真的熟悉各種 Windows 內部版本號，您也可以直接查看：

${IfNot} ${AtLeastBuild} 9200
  ...