XSLT xsl:param 循環 - 如果在文本字符串中找到返回值

Question

目標：評估每個<Report_Entry>元素。 如果<External_ID>值包含在<Addenda>文本中的任何位置，則返回<Internal_ID>值。

我當前的 XSLT 返回所需的 output 但我正在尋找更動態/可擴展的解決方案。 我的 XSLT 要求我為每個<Integration_Map_Value>創建 2 個xsl:param語句：

<xsl:param name="INT-MAP_External_ID_1" select="//Integration_Map_Value[1]/External_ID"/>

<xsl:param name="INT-MAP_Internal_ID_1" select="//Integration_Map_Value[1]/Internal_ID"/>

加上一個<xsl:when>語句：

<xsl:when test="contains(upper-case(Addenda), $INT-MAP_External_ID_1)">
   <Internal_ID>
      <xsl:value-of select="$INT-MAP_Internal_ID_1"/>
   </Internal_ID>
</xsl:when>

問題：理論上可能存在無限數量的<Integration_Map_Value>實例，因此我正在尋找一種動態循環所有<External_ID>值並將它們與<Addenda>字段進行比較的方法，而無需創建無窮無盡的參數，硬編碼的實例編號（即 [1]. [2]、[3] 等）和<xsl:when>語句。

來源 XML：

<root>
    <Integration_Map_Data>
        <Integration_Map_Value>
            <External_ID>MICROSOFT 1234</External_ID>
            <Internal_ID>XYZ-001</Internal_ID>
        </Integration_Map_Value>
        <Integration_Map_Value>
            <External_ID>MEGACORP</External_ID>
            <Internal_ID>C10025</Internal_ID>
        </Integration_Map_Value>
        <Integration_Map_Value>
            <External_ID>WIDGET TOOLS, INC ABC</External_ID>
            <Internal_ID>C-000338</Internal_ID>
        </Integration_Map_Value>
    </Integration_Map_Data>
    <Report_Data>
        <Report_Entry>
            <Addenda>abc microsoft 1234567</Addenda>
            <OrderNo>4444</OrderNo>
        </Report_Entry>
        <Report_Entry>
            <Addenda>fubar MEGACORP LLC</Addenda>
            <OrderNo>5555</OrderNo>
        </Report_Entry>
        <Report_Entry>
            <Addenda>no expected match here</Addenda>
            <OrderNo>6666</OrderNo>
        </Report_Entry>
    </Report_Data>
</root>

當前 XSLT：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/>

    <!-- External ID Parameters -->
    <xsl:param name="INT-MAP_External_ID_1" select="//Integration_Map_Value[1]/External_ID"/>
    <xsl:param name="INT-MAP_External_ID_2" select="//Integration_Map_Value[2]/External_ID"/>
    <xsl:param name="INT-MAP_External_ID_3" select="//Integration_Map_Value[3]/External_ID"/>

    <!-- Internal ID Parameters -->
    <xsl:param name="INT-MAP_Internal_ID_1" select="//Integration_Map_Value[1]/Internal_ID"/>
    <xsl:param name="INT-MAP_Internal_ID_2" select="//Integration_Map_Value[2]/Internal_ID"/>
    <xsl:param name="INT-MAP_Internal_ID_3" select="//Integration_Map_Value[3]/Internal_ID"/>

    <xsl:template match="/">
        <root>
            <xsl:for-each select="root/Report_Data/Report_Entry">
                <record>
                    <xsl:copy-of select="Addenda"/>
                    <xsl:copy-of select="OrderNo"/>

                    <xsl:choose>
                        <xsl:when test="contains(upper-case(Addenda), $INT-MAP_External_ID_1)">
                            <Internal_ID>
                                <xsl:value-of select="$INT-MAP_Internal_ID_1"/>
                            </Internal_ID>
                        </xsl:when>
                        <xsl:when test="contains(upper-case(Addenda), $INT-MAP_External_ID_2)">
                            <Internal_ID>
                                <xsl:value-of select="$INT-MAP_Internal_ID_2"/>
                            </Internal_ID>
                        </xsl:when>
                        <xsl:when test="contains(upper-case(Addenda), $INT-MAP_External_ID_3)">
                            <Internal_ID>
                                <xsl:value-of select="$INT-MAP_Internal_ID_3"/>
                            </Internal_ID>
                        </xsl:when>
                    </xsl:choose>
                </record>
            </xsl:for-each>
        </root>
    </xsl:template>
</xsl:stylesheet>

XML Output：

<?xml version="1.0" encoding="utf-8"?>
<root>
   <record>
      <Addenda>abc microsoft 1234567</Addenda>
      <OrderNo>4444</OrderNo>
      <Internal_ID>XYZ-001</Internal_ID>
   </record>
   <record>
      <Addenda>fubar MEGACORP LLC</Addenda>
      <OrderNo>5555</OrderNo>
      <Internal_ID>C10025</Internal_ID>
   </record>
   <record>
      <Addenda>no expected match here</Addenda>
      <OrderNo>6666</OrderNo>
   </record>
</root>

我已經用盡了我的初學者 XSLT 技能，似乎無法找到更優雅的解決方案來解決我的問題。 任何幫助是極大的贊賞。 我願意使用 XSLT 3.0，但這對我來說很新。

為這篇文章的標題道歉......很難描述我的問題。

Answer 1

使用對特定匹配元素的簡單引用，例如

  <xsl:template match="Report_Entry">
    <record>
      <xsl:apply-templates select="node(), //Integration_Map_Value[contains(upper-case(current()/Addenda), External_ID)]/Internal_ID"/>
    </record>
  </xsl:template>

加上身份轉換模板加上

  <xsl:template match="root">
    <xsl:copy>
      <xsl:apply-templates select="Report_Data/Report_Entry"/>
    </xsl:copy>
  </xsl:template>

身份轉換可以通過<xsl:mode on-no-match="shallow-copy"/>在 XSLT 3 中聲明，在早期版本中，您必須將其拼寫為

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>