將多個數據放在一個單元格ASP.NET，VB.NET中

Question

如何將多個數據放入一個datagrid單元中？ 例如，用戶可以是不同組織的成員。

但是我不希望該表為屬於多個組織成員的同一用戶創建一個新的datagrid行。

現在的代碼如下所示：

Dim dSourceMemberOf As New SqlDataAdapter("QUERY", dbConn)

這將填充數據網格，但是對於某些用戶，則多於5行。 所以我想將所有數據放在一個單元格中的一列中。

如何才能做到這一點？

編輯：

這就是現在的樣子：

username    memberof 
user1       dft 
user1       kbo 
user2       test

這就是我想要的樣子：

username   memberof 
user1      dft
           kbo 
user2      test

Answer 1

我認為最好的解決方案是使用Linq查詢對數據進行分組，然后將分組的數據綁定到gridview：

因此，GridView將如下所示：

    <asp:GridView ID="GridView1" runat="server" AutoGenerateColumns="False">
    <Columns>
        <asp:BoundField DataField="UserName" />
        <asp:TemplateField>
            <ItemTemplate>
                <asp:ListBox ID="lst" runat="server" DataSource="<%# Container.DataItem.MemberOfGrouped %>" DataTextField="MemberOf"></asp:ListBox>
            </ItemTemplate>

        </asp:TemplateField>
    </Columns>
</asp:GridView>

這是一些示例代碼來填充它：

    Protected Sub Page_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load

    Dim UngroupedData As List(Of YourData) = New List(Of YourData)()
    Dim item1 As YourData = New YourData()
    item1.MemberOf = "dft"
    item1.UserName = "user1"
    UngroupedData.Add(item1)

    Dim item2 As YourData = New YourData()
    item2.MemberOf = "kbo"
    item2.UserName = "user1"
    UngroupedData.Add(item2)

    Dim grouped = From u In UngroupedData Group u By Key = u.UserName Into Group _
                  Select UserName = Key, MemberOfGrouped = Group.ToList()


    GridView1.DataSource = grouped
    GridView1.DataBind()
End Sub


Public Class YourData

    Private _userName As String
    Public Property UserName() As String
        Get
            Return _userName
        End Get
        Set(ByVal value As String)
            _userName = value
        End Set
    End Property


    Private _memberOf As String
    Public Property MemberOf() As String
        Get
            Return _memberOf
        End Get
        Set(ByVal value As String)
            _memberOf = value
        End Set
    End Property
End Class

Answer 2

抱歉，我認為在繪畫上是錯誤的，但是概念是正確的-看起來您需要在databind事件事件上進行操作... 更多在這里 （前三個鏈接將向您展示如何執行我認為的要求）-您可以查看您所在的行，獲取上一行，然后根據上一行確定如何處理當前行中的單元格

Answer 3

您可以在GridView-Cell內使用一個表（或像Ross Scott建議的列表框）。

<ItemTemplate>
    <asp:table id="TblUserGroups" runat="server" Height="100%" Width="100%" CellSpacing="0" CellPadding="0">
    </asp:table> 
</ItemTemplate>

並在gridview的RowDataBound中（Datagrid的ItemDataBound工作類似）：

Protected Sub Gridview1_RowDataBound(ByVal sender As Object, ByVal e As System.Web.UI.WebControls.GridViewRowEventArgs) Handles Gridview1.RowDataBound
    Select Case e.Row.RowType
        Case DataControlRowType.DataRow
            Dim drUser As DataRowView = DirectCast(e.Row.DataItem, DataRowView)
            Dim TblUserGroups As Table = DirectCast(e.Row.FindControl("TblUserGroups"), Table)
            Dim userID as int32 = Ctype(drUser(0), Int32)
            Dim tblGroups as DataTable = getTblUserGroups(userID) 'write a function that returns the Groups of a given User f.e. as DataTable'
            If tblGroups.Rows.Count = 0 Then
                Dim tr As New TableRow
                Dim td As New TableCell
                Dim LblNoGroup As New Label
                LblNoGroup .Text = "no user-group"
                td.CssClass = "UserWithoutGroup"
                td.Controls.Add(LblNoGroup)
                tr.Cells.Add(td)
                TblUserGroups.Rows.Add(tr)
            Else
                For Each groupRow As DataRow In tblGroups.Rows
                    Dim tr As New TableRow
                    Dim td As New TableCell
                    Dim LblGroup As New Label
                    LblGroup.Text = groupRow("GroupName").ToString 'The groups name column'
                    td.Controls.Add(LblGroup)
                    tr.Cells.Add(td)
                    TblUserGroups.Rows.Add(tr)
                Next
            End If
    End Select
End Sub

我認為這是最靈活的方式。