你能改變無序的xml以匹配xsd：sequence順序嗎？

Question

您好我需要使用xslt將無序的xml轉換為xsd架構中指定的正確順序

<Person>
    <property name="address" value="5" />
    <property name="firstname" value="1234567890" />
    <property name="lastname" value="The BFG" />
</Person>

需要轉換使用

<xs:element name="Person">
    <xs:complexType>
        <xs:sequence>
            <xs:element name="firstname" type="xs:string"/>
            <xs:element name="lastname" type="xs:string"/>
            <xs:element name="address" type="xs:string"/>
        </xs:sequence>
    </xs:complexType>
</xs:element>

xml可以有任何順序的屬性，有10多個屬性元素的upwars。我已經嘗試使用xsl：for-each來嘗試和處理xml但是我很難理解如何讓xslt將xml轉換為序列定義的正確順序

任何幫助，將不勝感激

Answer 1

這可能不是最好的方法，但似乎工作正常。 我不確定是否可以保證處理xs:element的順序。 此外，這是使用Saxon-HE 9.3.0.5在oXygen中測試的XSLT 2.0答案。

XML輸入（修改Person的情況以匹配模式）：

<person>
  <property name="address" value="5" />
  <property name="firstname" value="1234567890" />
  <property name="lastname" value="The BFG" />
</person>

外部XSD架構文件（schema.xsd）：

<xs:schema xmlns:xs="http://www.w3.org/2001/XMLSchema" elementFormDefault="qualified">
  <xs:element name="person">
    <xs:complexType>
      <xs:sequence>
        <xs:element name="firstname" type="xs:string"/>
        <xs:element name="lastname" type="xs:string"/>
        <xs:element name="address" type="xs:string"/>
      </xs:sequence>
    </xs:complexType>
  </xs:element>
</xs:schema>

XSLT 2.0樣式表：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="#all">
  <xsl:output indent="yes"/>
  <xsl:strip-space elements="*"/>

  <xsl:variable name="input">
    <xsl:copy-of select="/"/>
  </xsl:variable>

  <xsl:template match="/*">
    <xsl:variable name="firstContext" select="name()"/>
    <xsl:variable name="xsdElems" select="document('schema.xsd')/xs:schema/xs:element[@name=$firstContext]/xs:complexType/xs:sequence/xs:element/@name"/>
    <xsl:element name="{$firstContext}">
      <xsl:for-each select="$xsdElems">
        <xsl:variable name="secondContext" select="."/>
        <xsl:element name="{$secondContext}">
          <xsl:value-of select="$input/*/*[@name=$secondContext]/@value"/>
        </xsl:element>
      </xsl:for-each>      
    </xsl:element>
  </xsl:template>

</xsl:stylesheet>

XML輸出：

<person>
   <firstname>1234567890</firstname>
   <lastname>The BFG</lastname>
   <address>5</address>
</person>

希望這可以幫助。

Answer 2

這是一個XSLT 1.0解決方案 ：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:xs="http://www.w3.org/2001/XMLSchema">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kxsElemByName" match="xs:element" use="@name"/>

 <xsl:variable name="vSchema" select=
  "document('file:///c:/temp/delete/schema.xsd')"/>

 <xsl:variable name="vDoc" select="/"/>

 <xsl:template match="/*">
  <xsl:variable name="vElem" select="."/>

  <xsl:for-each select="$vSchema">
   <xsl:apply-templates select=
     "key('kxsElemByName', name($vElem))">
    <xsl:with-param name="pElement" select="$vElem"/>
   </xsl:apply-templates>
  </xsl:for-each>
 </xsl:template>

 <xsl:template match="xs:element">
  <xsl:param name="pElement"/>

  <xsl:element name="{name($pElement)}">
   <xsl:apply-templates mode="generate"
        select="xs:complexType/xs:sequence/*">
     <xsl:with-param name="pParent" select="$pElement"/>
   </xsl:apply-templates>
  </xsl:element>
 </xsl:template>

 <xsl:template match="xs:element" mode="generate">
  <xsl:param name="pParent"/>
  <xsl:variable name="vProp" select=
   "$pParent/property[@name = current()/@name]"/>

  <xsl:element name="{$vProp/@name}">
   <xsl:value-of select="$vProp/@value"/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

當此轉換應用於提供的XML文檔時 （ Person重命名為person以匹配架構）：

<person>
    <property name="address" value="5" />
    <property name="firstname" value="1234567890" />
    <property name="lastname" value="The BFG" />
</person>

如果提供的XML模式位於文件c:\\temp\\delete\\schema.xsd ：

<xs:schema xmlns:xs="http://www.w3.org/2001/XMLSchema" elementFormDefault="qualified">
  <xs:element name="person">
    <xs:complexType>
      <xs:sequence>
        <xs:element name="firstname" type="xs:string"/>
        <xs:element name="lastname" type="xs:string"/>
        <xs:element name="address" type="xs:string"/>
      </xs:sequence>
    </xs:complexType>
  </xs:element>
</xs:schema>

然后產生想要的，正確的結果 ：

<person>
   <firstname>1234567890</firstname>
   <lastname>The BFG</lastname>
   <address>5</address>
</person>