Clojure：讀取數據庫的元數據

Question

我正在嘗試從sqlite數據庫獲取元數據。 此刻的主要目的是獲取表列表。

以下代碼（來自此處： 鏈接 ）：

(defn db-get-tables
"Demonstrate getting table info"
[]
(sql/with-connection db
   (into []
      (resultset-seq
       (-> (sql/connection)
           (.getMetaData)
           (.getTables nil nil nil (into-array ["TABLE" "VIEW"])))))))

這給了我一張包含有關數據庫表的元數據的地圖列表。 但是，如果我嘗試遍歷此列表（使用“ for”或“ first”），則會得到以下信息：

"Don't know how to create ISeq from proj00.operations.database$tables-list"

我相信必須有一個簡單的方法來做到這一點。 但是我只是無法在網絡上找到正確的信息。 另外，我無法理解該錯誤的來源。

Answer 1

可能是因為與數據庫的連接僅在“ sql / with connection db”的范圍內打開。 如果我使用Microsoft SQL遍歷這樣的集合，則會收到錯誤消息，指出連接已關閉。

如果將結果集序列包裝在doall中，則應修復此問題。 盡管這有助於您將所有結果都存儲到內存中並能夠關閉連接，但是這打破了延遲。 如果要保持惰性，則應將迭代置於“ with-connection”范圍內，但要保持連接打開直到完成。

同樣，您可以通過對此宏進行宏化（通過VerneriÅberg對我的問題的回答）來支持所有元數據方法：

(defmacro get-sql-metadata [db method & args] 
  `(with-connection 
    ~db 
    (doall 
      (resultset-seq 
        (~method 
          (.getMetaData (connection)) 
          ~@args)))))

因此，現在您可以使用元數據方法及其自身的參數來調用元數據，如下所示：

(get-sql-metadata db .getTables nil nil nil (into-array ["TABLE" "VIEW"]))
or
(get-sql-metadata db .getColumns nil nil nil nil)

后續：創建一個已連接的測試數據庫，一切應按以下方式進行。

Leiningen

  (defproject sqlitetest "1.0.0-SNAPSHOT"
    :description "FIXME: write description"
    :dependencies [[org.clojure/clojure "1.3.0"]
                   [org.xerial/sqlite-jdbc "3.6.16"]
                   [org.clojure/java.jdbc "0.1.0"]])

程序

(ns sqlitetest
  (:use [clojure.java.jdbc]))

(def db { :classname "org.sqlite.JDBC"
          :subprotocol "sqlite"
          :subname "E:/temp/chinook.db"})

(defmacro get-sql-metadata [db method & args]
  `(with-connection
    ~db
    (doall
      (resultset-seq
        (~method
          (.getMetaData (connection))
          ~@args)))))

(def tables-list
  (get-sql-metadata db .getTables nil nil nil (into-array ["TABLE" "VIEW"])))

REPL

sqlitetest=>(map :table_name tables-list)
("SQLITE_SEQUENCE" "ALBUM" "ARTIST" "CUSTOMER" "EMPLOYEE" "GENRE" "INVOICE" "INVOICELINE" "MEDIATYPE" "PLAYLIST" "PLAYLISTTRACK" "TRACK")

sqlitetest=>(first tables-list)   
{:self_referencing_col_name nil, :table_name "SQLITE_SEQUENCE", :type_schem nil, :ref_generation nil, :table_type "TABLE", :table_schem nil, :table_cat nil, :type_cat nil, :type_name nil, :remarks nil}

在您的評論上標記並回答問題該錯誤是由於在評論中對表列表執行defn而不是def而引起的。 如果使用defn，則會遇到相同的錯誤。