將VB6代碼片段轉換為VB.NET

Question

我很難將這個代碼段轉換為VB.NET

Function DecryptPassword(ByVal s As String) As String
    Dim i As Integer
    Dim sPass As String = s.Trim()

    For i = 1 To Len(sPass)
        If Asc(Mid$(sPass, i, 1)) - 5 < 124 Then

            'this line throws "type char $ does not match declared data type char"
            Mid$(sPass, i, 1) = Chr$(Asc(Mid$(sPass, i, 1)) - 5) 

        Else
            Mid$(sPass, i, 1) = Mid$(sPass, i, 1)
        End If
    Next
    DecryptPassword = UCase(sPass)  ' Convert UserPassword to UpperCase
End Function

它在VB6中運行良好但在VB.Net時拋出錯誤..

Answer 1

試試這個版本：

Function DecryptPassword(ByVal s As String) As String

    If String.IsNullOrEmpty(s) Then
        Return String.Empty
    End If

    Dim sbPass As New System.Text.StringBuilder(s.Length)

    For Each oCharacter As Char In s.Trim
        If Asc(oCharacter) - 5 < 124 Then
            sbPass.Append(Convert.ToChar(Asc(oCharacter) - 5))
        Else
            sbPass.Append(oCharacter)
        End If
    Next
    Return sbPass.ToString.ToUpper
End Function

Answer 2

這似乎工作（剛剛刪除像Booji Boy寫的“$”）。

Function DecryptPassword(ByVal s As String) As String
    Dim i As Integer
    Dim sPass As String = s.Trim()

    For i = 1 To Len(sPass)
        If Asc(Mid(sPass, i, 1)) - 5 < 124 Then
            Mid(sPass, i, 1) = Chr(Asc(Mid(sPass, i, 1)) - 5)
        Else
            Mid(sPass, i, 1) = Mid(sPass, i, 1)
        End If
    Next
    DecryptPassword = UCase(sPass)  ' Convert UserPassword to UpperCase 
End Function

Answer 3

只是為了它，一個linq方法。

Function DecryptPassword(ByVal s As String) As String
    Return s.Aggregate(Of String)(String.Empty, Function(acc, c) acc & Char.ToUpper(If(Asc(c) - 5 < 124, Convert.ToChar(Asc(c) - 5), c)))
End Function

要么

Function DecryptPassword(ByVal s As String) As String
    Return New String((From c In s Select Char.ToUpper(If(Asc(c) - 5 < 124, Convert.ToChar(Asc(c) - 5), c))).ToArray)
End Function