如何引用資源以保存在設置中-Visual Basic 2008 .net

Question

我正在嘗試保存一個設置，以保留我當前正在使用的背景圖像。

如果是外部文件，沒有問題，我可以獲取.location並將其設置為String設置以存儲它。

但是，如果我想將圖像資源存儲為設置，該怎么辦？

我知道我可以存儲原始數據（例如位圖信息），但是然后我無法將該數據類型設置為my.background。

我不知道問題是否應該是：“我如何引用資源”，但是my.resources.resource.methodsList不包含任何似乎有用的東西。

Answer 1

您可以使用My.Resources.ResourceManager.GetObject("resource name")來按字符串讀取資源。 這是一些示例代碼，向您展示如何從資源中獲取所有嵌入圖像的列表，其中包括它們的字符串名稱和圖像對象本身：

Public Class EmbeddedImage
    Public Sub New(ByVal name As String, ByVal image As Image)
        _name = name
        _image = image
    End Sub

    Public ReadOnly Property Name() As String
        Get
            Return _name
        End Get
    End Property
    Private _name As String

    Public ReadOnly Property Image() As Image
        Get
            Return _image
        End Get
    End Property
    Private _image As Image
End Class

Private Function getEmbeddedImages() As List(Of EmbeddedImage)
    Dim images As List(Of EmbeddedImage) = New List(Of EmbeddedImage)()
    Dim resources As ResourceSet = My.Resources.ResourceManager.GetResourceSet(CultureInfo.CurrentCulture, True, True)
    For Each resource As DictionaryEntry In resources
        If TypeOf resource.Value Is Image Then
            images.Add(New EmbeddedImage(resource.Key.ToString(), CType(resource.Value, Image)))
        End If
    Next
    Return images
End Function