如图所示，在swi prolog中将字符串列表转换为整数

Question

How to convert a string list to integers? Eg: if the list is ['i','am','fine'], the result should be [9,14,34] (i=9,am=1+13=14,fine=6+9+14+5=34)

How do I do this in SWI Prolog?

Answer 1

If you have module lambda ( http://www.complang.tuwien.ac.at/ulrich/Prolog-inedit/lambda.pl ) you can write

:- use_module(library(lambda)).

convert(Lst, Val) :-
    maplist(\X^Y^(atom_codes(X, Ch),
              foldl(\Z^T^U^(U is T + Z-96),Ch, 0, Y)), Lst, Val).

Answer 2

convert(Atoms, Values) :-
    maplist(a2n, Atoms, Values).

a2n(Atom, Num) :-
    atom_codes(Atom, Cs),
    [A] = "a",
    maplist(sub(A), Cs, L),
    sumlist(L, Num).

sub(A, C, N) :- N is C - A + 1.

Answer 3

The program can be built with a single built-in predicate, atom_codes and the standard recursion facilities of the language.

You need two rules - one to transform a list item-by-item to another list, and another one to total up the codes from which an atom is composed.

Each rule would have two parts - one to process the base case (ie an empty list), and one to reduce the incoming list by one item.

Here is a sample implementation with a demo on ideone :

sum_atoms([], []).
sum_atoms([H|T], [HeadSum|RT]) :-
    atom_codes(H, Codes),
    sum_letters(Codes, HeadSum),
    sum_atoms(T, RT).

sum_letters([], 0).
sum_letters([H|T], Res) :-
    sum_letters(T, TailSum),
    Res is (H-96) + TailSum.

If you would like to use maplist/3 and sumlist/2 , built-in predicates for list processing, you can shorten your program like this:

sum_atoms(In, Out) :-
    maplist(sum_letters, In, Out).

sum_letters(Atom, Sum) :-
    atom_codes(Atom, Codes),
    maplist(plus(-96), Codes, LetterNumbers),
    sumlist(LetterNumbers, Sum).

Link to a demo on ideone .