SAS循环：基于条件垂直汇总观测值

Question

I have a dataset that looks like:

Zip Codes Total Cars

• 11111 3
• 11111 4
• 23232 1
• 44331 0
• 44331 10
• 18860 6
• 18860 6
• 18860 6
• 18860 8

Ther are 3 million+ rows just like this, with varying zips. I need to sum total cars for each zip code, such that the resulting table looks like

Zip Codes Total Cars

• 11111 7
• 23232 1
• 44331 10
• 18860 26 . . .

Manually inputting zips into the code is not an option considering the size of the dataset. Thoughts?

Answer 1

Both answers so far are OK, but here is a more detailed explanation of both possible methods:

PROC SQL METHOD

PROC SQL;
  CREATE TABLE output_table AS
  SELECT ZipCodes,
  SUM(Total_Cars) as Total_Cars
  FROM input_table
  GROUP BY ZipCodes;
QUIT;

The GROUP BY clause can also be written GROUP BY 1 , omitting ZipCodes , as this refers to the 1st column in the SELECT clause.

PROC SUMMARY METHOD

PROC SUMMARY DATA=input_table NWAY;
             CLASS ZipCodes;
             VAR Total_Cars;
             OUTPUT OUT=output_table (DROP=_TYPE_ _FREQ_) SUM()=;
RUN;

The method is similar to another answer to this question, but I've added:

• NWAY - gives only the maximum level of summarisation, here it's not as important because you have only one CLASS variable, meaning there is only one level of summarisation. However, without NWAY you get an extra row showing the total value of Total_Cars across the whole dataset, which is not something you asked for in your question.

• DROP=_TYPE_ _FREQ_ - This removes the automatic variables:

  • _TYPE_ - which shows the level of summarisation (see comment above), which would just be a column containing the value 1 .
  • _FREQ_ - gives a frequency count of the ZipCodes , which although useful, isn't something you wanted in your question.

DATA STEP METHOD

PROC SORT DATA=input_table (RENAME=(Total_Cars = tc)) OUT=_temp;
  BY ZipCodes;
RUN;

DATA output_table (DROP=TC);
  SET _temp;
  BY ZipCodes;
  IF first.ZipCodes THEN Total_Cars = 0;
  Total_Cars+tc;
  IF last.ZipCodes THEN OUTPUT;
RUN;

This is just included for completeness, it's not as efficient as it requires pre-sorting.

Answer 2

To supplement @mjsqu's answer, for (more) completeness:

data testin;
    input Zip Cars;
    datalines;
11111 3
11111 4
23232 1
44331 0
44331 10
18860 6
18860 6
18860 6
18860 8
;

PROC TABULATE METHOD

proc tabulate data=testin out=testout

    /*drop extra created vars and rename as needed*/
    (drop=_type_ _page_ _table_ rename=(Zip='Zip Codes'n Cars_Sum='Total Cars'n));

    /*grouping variable, also used to sort output in ascending order*/
    class Zip;

    /* variable to be analyzed*/
    var Cars;

    /*sum cars by zip code*/
    table Zip, Cars*(sum);
run;

If using Enterprise Guide, this produces a dataset and a results table. To suppress the results and only output a dataset, include this line before "proc tabulate":

ods select none; /*suppress ods output*/

and this after "run":

ods select all; /*restore ods output*/

Answer 3

1. The variable upon which you want to sum is "ZipCodes" so that will go into "Class" section.
2. You want to sum Total_cars , so that will go into "var" section.
3. Input_table and Output_table is self explanatory.

/ *Code /

   proc summary data=Input_table;
               class ZipCodes;
               var Total_cars;
        output out=Output_table
        sum()=;
        run;

Answer 4

You can use proc sql. this is a very simple step

proc sql;

create table new as

select Zipcodes, sum(Total Cars) as total_cars from table_have group by Zipcodes

;

quit;