使用AppleScript根据名称将文件夹中的文件排序到子文件夹

Question

I have several thousand files I want to sort into subfolders...

FILENAMES: (several different extensions)

• DK10xxx
• DK11xxx
• DK12xxx

Using AppleScript:

repeat with i from 10 to 99
  tell application "Finder"
  set the_folder1 to folder "Sorting" of folder "Temp" of disk "HDD"
  set the_folder2 to folder ("DK" & i) of folder "Sorting" of folder "Temp" of disk "HDD"
  move (every item of the_folder1 whose name starts with ("DK" & i)) to the_folder2
  end tell
end repeat
end run

RESULT:

• error "Finder got an error: AppleEvent timed out." number -1712
• and I have to restart Finder

Answer 1

Try this, it checks all files of the source folder in a repeat loop.

If a file starts with DK it creates a folder if necessary named by the first 4 characters of the file name and moves the current file to the subfolder.

property sourceFolder : "HDD:Temp:Sorting"

tell application "Finder"
    repeat with aFile in (get files of folder sourceFolder) as alias list
        set fileName to name of aFile
        if fileName starts with "DK" then
            set prefix to text 1 thru 4 of fileName
            if not (exists folder prefix of folder sourceFolder) then
                make new folder at folder sourceFolder with properties {name:prefix}
            end if
            move aFile to folder prefix of folder sourceFolder
        end if
    end repeat
end tell

The error you got is a time out error. It occurs if a single Apple Event takes longer than 2 minutes. The code above tries to avoid this error by using shorter Apple Events.

If the error still occurs (in the repeat line) wrap the repeat loop into a with timeout block

with timeout of 1000000 seconds
  repeat with aFile in (get files of folder sourceFolder) as alias list
  ...
  end repeat
end timeout