XML消息的转换不会更改架构

Question

I am working on a project that requires me to transform a message and replace the old namespaces with new namespaces. I have that component working correctly. I do not have the schema attribute changing. I can do it separately but I cannot change the schema namespace and the element namespaces. What am I missing here?

Here is the message:

<ns1:SupportNotificationMsg xsi:schemaLocation="http://namespace1.com:8081/Organization/SupportServices SupportServices.xsd" 
          xmlns:ns3="http://namespace3.com/Common" 
          xmlns:ns1="http://namespace1.com:8081/Organization/SupportServices" 
          xmlns:ns2="http://namespace2.com:8081/Organization/" 
          xmlns:wsa="http://schemas.xmlsoap.org/ws/2004/08/addressing" 
          xmlns:j="http://www.it.ojp.gov/jxdm/3.0.3" 
          xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
         <ns2:SupportNotification>
          <ns3:MessageHeader>
           <ns3:MessageSender>
            <ns3:OrganizationName>ORG</ns3:OrganizationName>
            <ns3:ApplicationName>SEARCH</ns3:ApplicationName>
            <ns3:ContactName>Support</ns3:ContactName>
            <ns3:ContactPhoneNumber>111-222-3333</ns3:ContactPhoneNumber>
           </ns3:MessageSender>
           <ns3:MessageSentDateTime>2017-03-17T12:14:33</ns3:MessageSentDateTime>
          </ns3:MessageHeader>
          <ns2:SupportID>11243</ns2:SupportID>
          <ns2:IdSetting idKey="123456">
           <ns2:IdName ns2:code="APP1">ApplicationName</ns2:IdName>
           <ns2:IdTypeText ns2:code="HLP">HelpDesk</ns2:IdTypeText>
           <ns2:Setting settingKey="3091062">
            <ns2:SupportDateTimes>2017-03-17T08:30:00-05:00</ns2:SupportDateTimes>
            <ns2:SupportSettingStatus>Open</ns2:SupportSettingStatus>
           </ns2:Setting>
          </ns2:IdSetting>
     </ns2:SupportNotification>
</ns1:SupportNotificationMsg >

Here is the transform:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:NS1="http://namespace1.com:8081/Organization/SupportServices" 
    xmlns:NS2="http://namespace2.com:8081/Organization/" 
    xmlns:NS3="http://namespace3.com/Common" 
    xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
    version="1.0">
    <xsl:output method="xml" indent="yes"/>
    <xsl:strip-space elements="*"/>
    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="NS1:*">
        <xsl:element name="{local-name()}"
            namespace="http://newnamespace1.com/Organization/SupportServices">
            <xsl:attribute name="xsi:schemaLocation">http://newnamespace1.com/Organization/SupportServices SupportServices.xsd</xsl:attribute>
            <xsl:copy-of select="@*" />
            <xsl:apply-templates />
        </xsl:element>
    </xsl:template>

    <xsl:template match="NS2:*">
        <xsl:element name="{local-name()}"
            namespace="http://newnamespace2.com/Organization/">
            <xsl:copy-of select="@*" />
            <xsl:apply-templates />
        </xsl:element>
    </xsl:template>

    <xsl:template match="NS3:*">
        <xsl:element name="{local-name()}"
            namespace="http://newnamespace3.com/Common">
            <xsl:copy-of select="@*" />
            <xsl:apply-templates />
        </xsl:element>
    </xsl:template>


</xsl:stylesheet>

I have added

<xsl:template match="/attribute::xsi:schemaLocation"/>

or

<xsl:template match="/@xsi:schemaLocation[. =  'http://namespace1.com:8081/Organization/SupportServices SupportServices.xsd']">
    <xsl:attribute name="xsi:schemaLocation">http://newnamespace1.com/Organization/SupportServices SupportServices.xsd</xsl:attribute>
</xsl:template>

It will validate even with the old schema but I'd really like to change it for my own best practice.

Any insight is greatly appreciated.

Thank you,

Dave

Answer 1

You can use the following XSLT to transform your structure as requested. I have added some comments to the stylesheet to hopefully help explain the transformations. Let me know if this isn't clear or still misses the mark in some way.

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:NS1="http://namespace1.com:8081/Organization/SupportServices" 
  xmlns:NS2="http://namespace2.com:8081/Organization/" 
  xmlns:NS3="http://namespace3.com/Common" 
  xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
  version="1.0"
>

<xsl:output method="xml" indent="yes"/>
<xsl:strip-space elements="*"/>  

<xsl:template match="@* | node()">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
</xsl:template>


<xsl:template match="NS1:*">
    <!-- Add element with namespace -->
    <xsl:element name="ns1:{local-name()}"
        namespace="http://newnamespace1.com/Organization/SupportServices">
            <!-- Copy all of the namespaces from the source xml but exclude
                 the ns1, ns2, ns3 original namespaces from the source xml
                 document -->
            <xsl:copy-of select="namespace::*[not(name()='ns2')
              and
               not(name()='ns3')
              and
               not(name()='ns1')]"/>  
        <xsl:apply-templates select="@* | node()"/>

    </xsl:element>
</xsl:template>    

<xsl:template match="NS2:*">
    <xsl:element name="ns2:{local-name()}"
        namespace="http://newnamespace2.com/Organization/">
        <xsl:apply-templates />
    </xsl:element>
</xsl:template>

<xsl:template match="NS3:*">
    <xsl:element name="ns3:{local-name()}"
        namespace="http://newnamespace3.com/Common">
        <xsl:apply-templates />
    </xsl:element>
</xsl:template>

<!-- replace xsi:schemaLocation attribute -->
<xsl:template match="@xsi:schemaLocation">
  <xsl:attribute name="xsi:schemaLocation">http://newnamespace1.com/Organization/SupportServices SupportServices.xsd</xsl:attribute>
</xsl:template>        
</xsl:stylesheet>