Common Lisp将类似Regex的模式应用于PLIST中的键

Question

I am wondering if it is possible to apply Regex-like pattern matching to keys in a plist.

That is, suppose we have a list like this (:input1 1 :input2 2 :input3 3 :output1 10 :output2 20 ... :expand "string here")

The code I need to write is something along the lines of:

"If there is :expand and ( :input* or :output* ) in the list's keys, then do something and also return the :expand and ( :output* or :input* )".

Obviously, this can be accomplished via cond but I do not see a clear way to write this elegantly. Hence, I thought of possibly using a Regex-like pattern on keys and basing the return on the results from that pattern search.

Any suggestions are appreciated.

Answer 1

Normalize your input

A possible first step for your algorithm that will simplify the rest of your problem is to normalize your input in a way that keep the same information in a structured way, instead of inside symbol's names. I am converting keys from symbols to either symbols or lists. You could also define your own class which represents inputs and outputs, and write generic functions that works for both.

(defun normalize-key (key)
  (or (cl-ppcre:register-groups-bind (symbol number)
          ("^(\\w+)(\\d+)$" (symbol-name key))
        (list (intern symbol "KEYWORD")
              (parse-integer number)))
      key))

(defun test-normalize ()
  (assert (eq (normalize-key :expand) :expand))
  (assert (equal (normalize-key :input1) '(:input 1))))

The above normalize-key deconstructs :inputN into a list (:input N) , with N parsed as a number. Using the above function, you can normalize the whole list (you could do that recursively too for values, if you need it):

(defun normalize-plist (plist)
  (loop
    for (key value) on plist by #'cddr
    collect (normalize-key key)
    collect value))

(normalize-plist
 '(:input1 1 :input2 2 :input3 3 :output1 10 :output2 20 :expand "string here"))

=> ((:INPUT 1) 1
    (:INPUT 2) 2
    (:INPUT 3) 3
    (:OUTPUT 1) 10
    (:OUTPUT 2) 20
    :EXPAND "string here")

From there, you should be able to implement your logic more easily.