Emacs的align在plsql模式下失败

Question

I've been using a PL/SQL mode available on EmacsWiki and I have been a rather happy with it.

But when I try to align or align-current I just get an error:

align: Wrong type argument: sequencep, plsql-align-rules-list

Example code that I'm trying to align:

declare
  foo number;
  x number;
  y number;
begin
  foo :=     5;
  x := 123;
  y:=123;
end;

The expected outcome is:

declare
  foo number;
  x number;
  y number;
begin
  foo := 5;
  x   := 123;
  y   := 123;
end;

Here is the relevant (I hope) part of the plsql-mode's code:

;;;_  + Align

;; Should I make so that anything that is highlighted will line up?
;; Should we make a block anything inside ()?

(eval-and-compile

  (defcustom plsql-align-rules-list '()  ""
    :group 'plsql
    :type  'align-rules-list-type)

  ;; Should I make so that anything that is highlighted will line up?
  ;; Should we make a block anything inside ()?

  (when (condition-case nil
            (require 'align)
          (error nil))

    ;; these are way too slow to use with indent before aligning
    (unless (and  plsql-align-rules-list plsql-debug)
      (setq plsql-align-rules-list
            '(
              (plsql-assignment
               (regexp . "\\(\\s-*\\):=\\(\\s-*\\)")
               (group  . (1 2))
               (modes  . '(plsql-mode))
               (repeat t)
               (tab-stop  .  nil))

              (plsql-arrorw
               (regexp . "\\(\\s-*\\)=>\\(\\s-*\\)")
               (group  . (1 2))
               (modes  . '(plsql-mode))
               (repeat t)
               (tab-stop  .  nil))

              (plsql-equals ;; exclude the previous two cases
               (regexp . "\\(\\s-*[^:]\\)=\\([^>]\\s-*\\)")
               (group  . (1 2))
               (repeat t)
               (tab-stop . nil)
               (modes    . '(plsql-mode)))

              (plsql-operator ;; watch out for comments
               (regexp . "\\(\\s-*\\)[-+/]{1}\\(\\s-*\\)")
               (group  . (1 2))
               (repeat t)
               (tab-stop . nil)
               (modes    . '(plsql-mode)))

              (plsql-keywords
               (regexp . "\\(\\s-+\\)\\(in\\|default\\|number\\|varchar2\\|blob\\|raw\\)\\b")
               (group 1)
               (repeat t)
               (case-fold t)
               (tab-stop . nil)
               (modes    . '(plsql-mode)))
              )
            ))

    (put 'plsql-align-rules-list 'risky-local-variable t)
    (add-to-list 'align-c++-modes 'plsql-mode) ;; eg expression functions ...
    (add-to-list 'align-sq-string-modes 'plsql-mode)
    (add-to-list 'align-open-comment-modes 'plsql-mode)

    ;; Should we re-bind new-line-and-indent to align the current
    ;; region? That sounds expensive.
    ))

And later in defun plsql-mode () :

(set (make-local-variable 'align-mode-rules-list) 'plsql-align-rules-list)

How the plsql-mode should be modified to get align working ? My best work-around so far is to use align-regexp (inspired by this answer ):

(defun my-align ()
  ""
  (interactive)
  (align-regexp
   (region-beginning) (region-end)
   "\\(\\s-*\\):=" 1 1 nil))

This is fine except it doesn't modify the right-hand side.

The author doesn't use the mode anymore. I'm using emacs 23.2.1.

Answer 1

As far as I can understand it, the function plsql-mode should contain:

(set (make-local-variable 'indent-line-function) 'plsql-indent)
(set (make-local-variable 'indent-region-function) 'plsql-indent-region)
(set (make-local-variable 'align-mode-rules-list) plsql-align-rules-list)

Since the first two buffer local variables are indeed references to functions, their argument should be a quoted symbol. Since the third one should use the value contained in the variable plsql-align-rules-list, this variable should NOT be quoted.

HTH )jack(