8086 ASM - Output String to screen

Question

I am trying to get an input from the keyboard, and then output it to the screen.

My code;

    BITS 16                 ;Set code generation to 16 bit mode
ORG 0x0100;
SECTION .text;



MAIN:
    mov SI, MyArray

    call GetString
    call Putln
    call PutString

    jmp Exit;

GetString:

    call Getch ; get the character stored in DL

    cmp dl, 0dh ; if Enter is pressed Exit the subroutine
    je Return

;    call Putch ;*commeted out to see if putsring works* ; output the character on screen

    stosb ; store the character in al to [di] and increment di by 1
    jmp GetString ; loop back to GetString  

Return:
    mov al, 0 ; terminate array with a 0
    stosb
    ret

PutString:
    cld
    lodsb ; load the character in [si] to al and increment si by 1

    cmp al, 0
    jz Return2

    mov dl, al
    call Putch

    jmp PutString ; loop back to PutString

Return2:
    Ret


Getch:
    push di

    mov ah, 7 ; keyboard input subprogram without echo
    int 21h ; read the character into al
    mov dl, al
    pop di

    RET ; return

Putch:
    push di

    mov ah, 2h ; display subprogram
    INT 21H ;read the characters from al
    pop di

    RET ; Return

Putln: ;new line
    mov ah, 2
    mov dl, 0DH ;Carriage return
    int 21h
    mov dl, 0AH  ;Line feed
    int 21H
    RET ; return


Exit:
    MOV AH,04Ch ; Select exit function
    MOV AL,00   ; Return 0
    INT 21h     ; Call the interrupt to exit


SECTION .bss
MyArray resb 256

However I cannot get PutString to work properly. It is printing the same ASCII characters no matter what is typed on the keyboard.

Any help would be appreciated!

Answer 1

I don't see you initializing DI anywhere. It should probably be set to point to MyArray just like SI , otherwise your STOSB will just write to some random location.

Answer 2

These are the only changes you need to make:

...
;;;;    mov SI, MyArray
    mov DI, MyArray ;;;; stosb uses DI

    call GetString
    call Putln

    mov SI, MyArray ;;;; lodsb uses SI
...