Read from all text files in folder, check for matches and insert text file value into Excel sheet

Question

I am attempting to work on a code which will allow me to check two lines of all my text files in a folder.

Each text file will be structured like so:

NS1234        <--- A random reference number on the first line
Approve       < Reject or Approve on the second line

At the moment the code only reads one text file which I specify the name of, however I want it to scan all .txt files.

Next, When I open my spread sheet I will have the following set-up:

Column A     Column
NS1234 

I want my code to scan all text files to check for any matching reference number from column A against all the text files.

And then where a match is found insert either 'Approve' or 'Reject', where this is written on the second line of the text file, into the corresponding row in column s

Code:

Public Sub test()
    Dim fn As Integer
    fn = FreeFile
    Open "Z:\NS\Approval\NS32D1QR.txt" For Input As fn

    Dim wholeFile As String
    wholeFile = Input(LOF(fn), #fn)

    Close #fn

    Dim splitArray
    splitArray = Split(wholeFile, vbCrLf)

    Dim lineNum As Integer
    lineNum = 2


    Dim i As Integer, intValueToFind As Integer
    intValueToFind = NS32D1QR
    For i = 1 To 500    ' Revise the 500 to include all of your values
        If Cells(i, 1).Value = intValueToFind And splitArray(lineNum - 1) = "Approve" Then
    Range("S" & ActiveCell.Row).Value = "Approve"
    End If

    Next i



End Sub

Answer 1

i 'm not sure about the test that you made in your loop but it seems to me that the info where on the 2 first lines so no use to loop or to use special variables there. Let me know if this work properly or not! ;)

Here is a sub to test, as it is a function you can either loop on it or use it in Excel workbook.

Sub test()

With Sheets("Sheet1")
    For i = 2 To .Rows(.Rows.Count).End(xlUp).Row
        .Cells(i, "S") = Get_AorP(.Cells(i, "A"))
    Next i
End With

End Sub

Here is what you wanted to do, converted to a function :

    Public Function Get_AorP(ByVal Value_to_Find As String) As String
        Dim fn As Integer, _
            Txts_Folder_Path As String, _
            File_Name As String, _
            wholeFile As String, _
            splitArray() As String, _
            i As Integer

    On Error GoTo ErrHandler
    Txts_Folder_Path = "Z:\NS\Approval\"
    File_Name = Dir(Txts_Folder_Path & "*.txt")

    While File_Name <> vbNullString
        fn = FreeFile
        Open Txts_Folder_Path & File_Name For Input As fn
            wholeFile = Input(LOF(fn), #fn)
        Close #fn
        MsgBox File_Name
        splitArray = Split(wholeFile, vbCrLf)

        If UBound(splitArray) < 2 Or LBound(splitArray) > 1 Then
            'avoid empty text files
        Else
            If InStr(1, splitArray(0), Value_to_Find) <> 0 Then
                If InStr(1, splitArray(1), "Approve") Then
                    Get_AorP = "Approve"
                    Exit Function
                Else
                    If InStr(1, splitArray(1), "Reject") Then
                        Get_AorP = "Reject"
                        Exit Function
                    Else
                        'Nothing to do
                    End If
                End If
            Else
                'not the good value
            End If
        End If
        File_Name = Dir()
    Wend

    Get_AorP = "No matches found"
    Exit Function
ErrHandler:
        Get_AorP = "Error during the import." & vbCrLf & Err.Number & " : " & Err.Description
    End Function