YAWs embedded with appmod not working for me

Question

Alright, what am I doing wrong here. I'm trying the simple example of embedded YAWs from http://yaws.hyber.org/embed.yaws but with an appmod. I've added the my_app.erl file and compiled it. It works if not in embedded YAWs so I think it is specific to embedded.

-module(ybed).
-compile(export_all).

start() ->
    {ok, spawn(?MODULE, run, [])}.

run() ->
    Id = "embedded",
    GconfList = [{ebin_dir, ["/Users/someuser/yawsembedded/ebin"]}],
    Docroot = "/Users/someuser/yawstest",
    SconfList = [{port, 8888},
                 {listen, {0,0,0,0}},
                 {docroot, Docroot},
                 {appmods, [{"/", my_app}]}
                ],
    {ok, SCList, GC, ChildSpecs} =
        yaws_api:embedded_start_conf(Docroot, SconfList, GconfList),
    [supervisor:start_child(ybed_sup, Ch) || Ch <- ChildSpecs],
    yaws_api:setconf(GC, SCList),
    {ok, self()}.

Getting this Error:

ERROR erlang code threw an uncaught exception:
 File: appmod:0
Class: error
Exception: undef
Req: {http_request,'GET',{abs_path,"/demo"},{1,1}}
Stack: [{my_app,out,
            [{arg,#Port<0.2721>,
                 {{127,0,0,1},63720},
                 {headers,"keep-alive",
                     "text/html,application/xhtml+xml,application/xml;q=0.9,*/*;q=0.8",
                     "0.0.0.0:8888",undefined,undefined,undefined,undefined,
                     undefined,undefined,undefined,
                     "Mozilla/5.0 (Macintosh; Intel Mac OS X 10.10; rv:40.0) Gecko/20100101 Firefox/40.0",
                     undefined,[],undefined,undefined,undefined,undefined,
                     undefined,undefined,undefined,undefined,
                     [{http_header,0,"Dnt",undefined,"1"},
                      {http_header,10,'Accept-Encoding',undefined,
                          "gzip, deflate"},
                      {http_header,11,'Accept-Language',undefined,"null"}]},
                 {http_request,'GET',{abs_path,"/demo"},{1,1}},
                 {http_request,'GET',{abs_path,"/demo"},{1,1}},
                 undefined,"/demo",undefined,undefined,
                 "/Users/someuser/yawstest","/",
                 "/Users/someuser/yawstest/demo",undefined,undefined,
                 <0.63.0>,[],"/","/",undefined}],
            []},
        {yaws_server,deliver_dyn_part,8,
            [{file,"yaws_server.erl"},{line,2818}]},
        {yaws_server,aloop,4,[{file,"yaws_server.erl"},{line,1232}]},
        {yaws_server,acceptor0,2,[{file,"yaws_server.erl"},{line,1068}]},
        {proc_lib,init_p_do_apply,3,[{file,"proc_lib.erl"},{line,239}]}]

Answer 1

The stack trace shows that your my_app:out/1 function is getting called, but you're getting an undef exception. This is occurring because the runtime can't find the my_app:out/1 function, which means either it can't find the module or the module exists but does not export an out/1 function. For example, I was able to duplicate the error using the example code by not providing a my_app module.

First, make sure your my_app.erl file exports an out/1 function. Here's a trivial one that just returns a 405 error for all requests:

-module(my_app).
-export([out/1]).

out(_Arg) ->
    {status, 405}.

Compile your my_app.erl file and put the compiled my_app.beam file either in a load path already known to the Erlang runtime, or in a directory you add to the load path. In your code it appears you're trying the latter approach, since you're specifically adding an ebin_dir with this Yaws global configuration directive:

GconfList = [{ebin_dir, ["/Users/someuser/yawsembedded/ebin"]}],

You need to verify that the /Users/someuser/yawsembedded/ebin directory exists, and that the compiled my_app.beam file is located there.