XSLT - get data from two objects in for-each loop

Question

I have a problem with xsl transformation. This is fragment of my code. input.xml

<models>
    <model>
        <contact>
            <city>Tokyo</city>
            <telephone>555-888-999</telephone>
        </contact>
        <person>
            <name>Anna</name>
            <surname>Smith</surname>
            <age>33</age>
        </person>
        <person>
            <name>Melissa</name>
            <surname>MacBeth</surname>
            <age>26</age>
        </person>
    </model>
    <model>
        <contact>
            <city>New York</city>
            <telephone>987-254-845</telephone>
        </contact>
        <person>
            <name>Michael</name>
            <surname>Affronti</surname>
            <age>49</age>
        </person>
        <person>
            <name>Arthur</name>
            <surname>Bertrand</surname>
            <age>38</age>
        </person>
        <person>
            <name>Simon</name>
            <surname>Morris</surname>
            <age>22</age>
        </person>
    </model>
</models>

I need apply template for <contact> into for-each loop. This is required. xsl_template.xsl

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/">

        <xsl:for-each select="/models/model">
            <xsl:apply-templates select="." />
        </xsl:for-each>
    </xsl:template>

    <xsl:template match="contact">
        <phoneNo>
            <xsl:value-of select="city" />
        </phoneNo>
    </xsl:template>

    <xsl:template match="model">
        <xsl:for-each select="person">
            <responsible>
                <xsl:apply-templates select="contact" />
                <xsl:apply-templates select="." />
            </responsible>

        </xsl:for-each>
    </xsl:template>

    <xsl:template match="person">
        <person>
            <xsl:value-of select="name" />
            <xsl:text>, </xsl:text>
            <xsl:value-of select="surname" />
        </person>
    </xsl:template>
</xsl:stylesheet>

output.xml

<?xml version="1.0" encoding="UTF-8"?>
<responsible>
    <person>Anna, Smith</person>
</responsible>
<responsible>
    <person>Melissa, MacBeth</person>
</responsible>
<responsible>
    <person>Michael, Affronti</person>
</responsible>
<responsible>
    <person>Arthur, Bertrand</person>
</responsible>
<responsible>
    <person>Simon, Morris</person>
</responsible>

Template for <contact> is missing. I tried also use <xsl:variable> , but it doesnt work. How can I get it?

Answer 1

If you need to show contact for person (same for all persons inside model), then this:

<xsl:template match="model">
    <xsl:for-each select="person">
        <responsible>
            <xsl:apply-templates select="preceding-sibling::contact" />
            <xsl:apply-templates select="." />
        </responsible>

    </xsl:for-each>
</xsl:template>

Answer 2

you need to adjust two things,

<xsl:template match="contact">
    <phoneNo>
        <xsl:value-of select="city" />
    </phoneNo>
</xsl:template>

s/b

<xsl:template match="contact">
    <phoneNo>
        <xsl:value-of select="telephone" />
    </phoneNo>
</xsl:template>

and

<xsl:template match="model">
    <xsl:for-each select="person">
        <responsible>
            <xsl:apply-templates select="contact" />
            <xsl:apply-templates select="." />
        </responsible>
    </xsl:for-each>
</xsl:template>

s/b

<xsl:template match="model">
    <xsl:for-each select="person">
        <responsible>
            <xsl:apply-templates select="../contact" />
            <xsl:apply-templates select="." />
        </responsible>
    </xsl:for-each>
</xsl:template>

under the xsl:for-each loop, you are under the context node person , so you must use the dot notation (..) to refer to the parent node.