Apps are reviewed on an IPv6 network. Please ensure that your app supports IPv6 networks, as IPv6 compatibility is required

Question

I have received the following rejection from Apple for my app the last couple of days. My app communicates with UDP and the remote server is always IPv4. I have used BSD sockets. Please guide me how can I solve this problem.

I have tried to create a NAT64 hotspot using an IPv4 network but I was unable to send any packets to the server. Moreover, we don't have IPv6 available at my place now.

From Apple:

2.2 Details

We discovered one or more bugs in your app when reviewed on an iPad running iOS 9.3.2 and iPhone running iOS 9.3.2 on both Wi-Fi and cellular networks.

Specifically, during review we were unable to bypass the Initializing page. We encountered an error while waiting for the app to load. We've attached a screenshot for your reference.

Next Steps

Please run your app on a device to identify the issue(s), then revise and resubmit your app for review.

Apps are reviewed on an IPv6 network. Please ensure that your app supports IPv6 networks, as IPv6 compatibility is required.

For additional information about supporting IPv6 Networks, please refer to Supporting iPv6 DNS64/NAT64 Networks.

Source Code Bellow:

UdpSocketManager.h >>

#ifndef UDP_SOCKET_MANAGER_H__
#define UDP_SOCKET_MANAGER_H__

#import "TInetAddr.h"

class UdpSocketManager
{
public:
    UdpSocketManager();
    ~UdpSocketManager();

    void getLocalAddress();
    void initializeSocket();
    void start();
    void stop();

    void sendSignal(int p_type, TInetAddr *p_destAddress, unsigned char *p_data, int p_length); 
    void receiveSignal();

    int localPort;    
    int signalingSocket;
    int signalSocketRecvLength;
    int socketFamily;

    int isIPV4Available;
    int isIPV6Available;

    char wifiIP[INET_ADDRSTRLEN];
    char cellularIP[INET_ADDRSTRLEN];

    char wifiIP_v6[INET6_ADDRSTRLEN];
    char cellularIP_v6[INET6_ADDRSTRLEN];    

    long returnLength;
    struct sockaddr_in remoteAddrForRecv;

    struct sockaddr_in  srcAddrV4;
    struct sockaddr_in6 srcAddrV6;    

    struct sockaddr_in  sendAddr4;
    struct sockaddr_in6 sendAddr6;

    bool running;
    pthread_t thread;
};

#endif

UdpSocketManager.m >>

#include <string.h>
#include <pthread.h>
#include <ifaddrs.h>
#include <arpa/inet.h>
#include <sys/socket.h>

#include "UdpSocketManager.h"
#import <Foundation/Foundation.h>

unsigned int ipAddressToUnsignedInt(char *ipAddress)
{
    unsigned int ipAddressLongValue = 0L;
    int byteSegment = 0;

    for(int i = 0; i < strlen(ipAddress); i++)
    {
        char ch = ipAddress[i];
        if(ch == '.')
        {
            ipAddressLongValue <<= 8;
            ipAddressLongValue |= byteSegment;
            byteSegment = 0;
        }
        else
        {
            byteSegment = byteSegment * 10 + (ch - 48);
        }
    }

    ipAddressLongValue <<= 8;
    ipAddressLongValue |= byteSegment;
    return ipAddressLongValue;
}

int custom_random(int max=65535)
{
    int randomValue;
    randomValue = arc4random_uniform(65535)%max;
    return randomValue;
}

int custom_random(int min, int max)
{
    int randomValue;
    randomValue = arc4random_uniform(max);
    if(randomValue<min)
        randomValue=(min+custom_random(max-min));
    return randomValue;
}



void* runUdpSocketManager(void *objRef)
{
    UdpSocketManager *THIS = (UdpSocketManager *) objRef;
    THIS->running=true;

    while (THIS->running) 
    {
        THIS->receiveSignal();
    }

    pthread_exit(NULL);
    return 0;
}


UdpSocketManager::UdpSocketManager()
{
    socketFamily=AF_INET;
    signalingSocket=-1;
    running=false;
    initializeSocket();
}

UdpSocketManager::~UdpSocketManager()
{

}

void UdpSocketManager::getLocalAddress()
{
    //Read local address
    getLocalAddress();

    struct ifaddrs *interfaces = NULL;
    struct ifaddrs *temp_addr = NULL;
    int success=0;

    isIPV4Available=FALSE;
    isIPV6Available=FALSE;
    success = getifaddrs(&interfaces);

    if (success == 0)
    {
        // Loop through linked list of interfaces
        temp_addr = interfaces;
        while(temp_addr != NULL)
        {
            if(temp_addr->ifa_addr->sa_family==AF_INET)
            {
                if([[NSString stringWithUTF8String:temp_addr->ifa_name] hasPrefix:@"en"])
                {
                    isIPV4Available=TRUE;
                    strcpy(wifiIP, inet_ntoa(((struct sockaddr_in *)temp_addr->ifa_addr)->sin_addr));
                    printf("IP Address: %s\n",inet_ntoa(((struct sockaddr_in *)temp_addr->ifa_addr)->sin_addr));
                }
                else if([[NSString stringWithUTF8String:temp_addr->ifa_name] hasPrefix:@"pdp_ip0"])
                {
                    isIPV4Available=TRUE;
                    strcpy(cellularIP, inet_ntoa(((struct sockaddr_in *)temp_addr->ifa_addr)->sin_addr));
                    printf("IP Address: %s\n",inet_ntoa(((struct sockaddr_in *)temp_addr->ifa_addr)->sin_addr));
                }
            }
            else if(temp_addr->ifa_addr->sa_family==AF_INET6)
            {
                if([[NSString stringWithUTF8String:temp_addr->ifa_name] hasPrefix:@"en"])
                {
                    isIPV6Available=TRUE;
                    inet_ntop(AF_INET6, &(((struct sockaddr_in6 *)temp_addr->ifa_addr)->sin6_addr), (char*)wifiIP_v6, INET6_ADDRSTRLEN);
                    printf("Interface: %s IPV6: %s\n",temp_addr->ifa_name,wifiIP_v6);
                }
                else if([[NSString stringWithUTF8String:temp_addr->ifa_name] hasPrefix:@"pdp_ip0"])
                {
                    isIPV6Available=TRUE;
                    inet_ntop(AF_INET6, &(((struct sockaddr_in6 *)temp_addr->ifa_addr)->sin6_addr), (char*)cellularIP_v6, INET6_ADDRSTRLEN);
                    printf("Interface: %s IPV6: %s\n",temp_addr->ifa_name,cellularIP_v6);
                }
            }
            temp_addr = temp_addr->ifa_next;
        }
    }
    freeifaddrs(interfaces);
}

void UdpSocketManager::initializeSocket()
{
    if(signalingSocket!=-1)
        close(signalingSocket);

    if (isIPV4Available)
    {
        if((signalingSocket=socket(AF_INET, SOCK_DGRAM, 0))==-1)
        {
            NSLog(@"Unable to create signaling socket of AF_INET");
        }
        else
        {
            socketFamily=AF_INET;
            NSLog(@"Socket created successfully. [AF_INET]");
        }
    }
    else if(!isIPV4Available && isIPV6Available)
    {
        if((signalingSocket=socket(AF_INET6, SOCK_DGRAM, 0))==-1)
        {
            NSLog(@"Unable to create signaling socket of AF_INET6");
        }
        else
        {
            socketFamily=AF_INET6;
            NSLog(@"Socket created successfully. [AF_INET6]");
        }
    }
    else
    {
        if((signalingSocket=socket(AF_INET, SOCK_DGRAM, 0))==-1)
        {
            NSLog(@"Unable to create signaling socket of AF_INET");
        }
        else
        {
            socketFamily=AF_INET;
            NSLog(@"Socket created successfully. [AF_INET]");
        }
    }

    int count=0;
    while(true)
    {
        count++;
        if(socketFamily==AF_INET)
        {
            srcAddrV4.sin_len = sizeof(srcAddrV4);
            srcAddrV4.sin_family = socketFamily;
            srcAddrV4.sin_addr.s_addr = INADDR_ANY;
            srcAddrV4.sin_port = htons(localPort);

            if (bind(signalingSocket, (struct sockaddr *) &srcAddrV4, sizeof(srcAddrV4)) < 0)
            {
                NSLog(@"[AF_INET] ERROR occured creating signaling port at attempt (%d) Port: %d", count, localPort);
                localPort=(int)custom_random(1024, 65535);
            }
            else
            {
                int on=1;
                setsockopt(signalingSocket, SOL_SOCKET, SO_NOSIGPIPE, (void *)&on, sizeof(on));
                setsockopt(signalingSocket, SOL_SOCKET, SO_REUSEADDR, (char *)&on, sizeof(on));

                NSLog(@"[AF_INET] SignalingSocket Created Successfully at attempt (%d) Port: %d\n", count, localPort);
                break;
            }
        }
        else
        {
            srcAddrV6.sin6_len = sizeof(srcAddrV6);
            srcAddrV6.sin6_family = socketFamily;
            srcAddrV6.sin6_addr = in6addr_any;
            srcAddrV6.sin6_port = htons(localPort);

            if (bind(signalingSocket, (struct sockaddr *) &srcAddrV6, sizeof(srcAddrV6)) < 0)
            {
                NSLog(@"[AF_INET] ERROR occured creating signaling port at attempt (%d) Port: %d", count, localPort);
                localPort=(int)custom_random(1024, 65535);
            }
            else
            {
                int on=1;
                setsockopt(signalingSocket, SOL_SOCKET, SO_NOSIGPIPE, (void *)&on, sizeof(on));
                setsockopt(signalingSocket, SOL_SOCKET, SO_REUSEADDR, (char *)&on, sizeof(on));
                NSLog(@"[AF_INET6] SignalingSocket Created Successfully at attempt (%d) Port: %d\n", count, localPort);
                break;
            }
        }
    }
}

void UdpSocketManager::start()
{
    pthread_create(&thread, NULL, runUdpSocketManager, (void *) this);
}

void UdpSocketManager::stop()
{
    running=false;
}

void UdpSocketManager::receiveSignal()
{
    int port;
    char ipAddress[16];

    socklen_t fromlen;
    unsigned char udpSignalRecvBuffer[1600];

    fromlen = sizeof(remoteAddrForRecv);
    signalSocketRecvLength = (int)recvfrom(signalingSocket, (char *)udpSignalRecvBuffer,1600,0,(struct sockaddr *)&remoteAddrForRecv,&fromlen);

    if(signalSocketRecvLength>0)
    {
        strcpy(ipAddress, inet_ntoa(remoteAddrForRecv.sin_addr));
        port = ntohs(remoteAddrForRecv.sin_port);
        NSLog(@"RECEIVED %d bytes from %s:%d", signalSocketRecvLength, ipAddress, port);
    }
    else
    {
        usleep(10000);// 10 ms
    }
}


void UdpSocketManager::sendSignal(int p_type, TInetAddr *p_destAddress, unsigned char *p_data, int p_length)
{
    if(socketFamily==AF_INET6)
    {
        // Convert IPv4 address to IPv4-mapped-into-IPv6 address.        
        sendAddr6.sin6_family = AF_INET6;
        sendAddr6.sin6_port = p_destAddress->m_port;

        sendAddr6.sin6_addr.__u6_addr.__u6_addr32[0] = 0;
        sendAddr6.sin6_addr.__u6_addr.__u6_addr32[1] = 0;
        sendAddr6.sin6_addr.__u6_addr.__u6_addr32[2] = htonl(0xffff);
        sendAddr6.sin6_addr.__u6_addr.__u6_addr32[3] = ntohl(ipAddressToUnsignedInt(p_destAddress->m_address));

        sendAddr6.sin6_addr.__u6_addr.__u6_addr16[4] = 0;
        sendAddr6.sin6_addr.__u6_addr.__u6_addr16[5] = 0xffff;

        char ipV6Address[INET6_ADDRSTRLEN];
        inet_ntop(AF_INET6, &sendAddr6.sin6_addr, ipV6Address, INET6_ADDRSTRLEN);
        NSLog(@"ipV6Address: %s\n", ipV6Address);

        sendAddr6.sin6_flowinfo = 0;
        sendAddr6.sin6_scope_id = 0;
    }
    else
    {
        sendAddr4.sin_family = AF_INET;
        sendAddr4.sin_port   = htons(p_destAddress->m_port);

        if(inet_aton((char *) p_destAddress->m_address, &sendAddr4.sin_addr)==0)
        {
            NSLog(@"signal message - inet_aton() failed, %s", p_destAddress->m_address);
        }
    }


    if(socketFamily==AF_INET)
        returnLength=sendto(signalingSocket, p_data, p_length, 0, (struct sockaddr *)&sendAddr4, sizeof(sendAddr4));
    else
        returnLength=sendto(signalingSocket, p_data, p_length, 0, (struct sockaddr *)&sendAddr6, sizeof(sendAddr6));

    NSLog(@"SENT %ld bytes to %s:%d\n", returnLength,p_destAddress->m_address,p_destAddress->m_port);
}

Answer 1

I don't think your "Convert IPv4 address to IPv4-mapped-into-IPv6 address" is correct. Rather than trying to construct an address yourself, you should call getaddrinfo() with a string of the thing you want to connect to (which could be either a hostname or an IPv4 address literal), and it will return to you a list of sockaddr s; you should use the first one from there to pass to sendto . It will give you the appropriate IP address family to use, and if you give an IPv4 address and it is an IPv6-only network (without you having to test anything), it will automatically give you the correct IPv6 address to use for that NAT64 router (without you needing to figure this out yourself). (If you wanted to manually construct an IPv6 address from IPv4 using NAT64/DNS64 without using getaddrinfo() , you would have to follow the complicated procedure in RFC 7050 .)

Also, all the things you are doing in getLocalAddress() is unnecessary and potentially leads to more problems. You don't need isIPV4Available or isIPV6Available -- you shouldn't care at that point. Just create and bind both an IPv4 and an IPv6 socket in the beginning (not needing to care which one works), and each time you need to send, you get the right sockaddr to use using getaddrinfo() as above, and then send to the socket whose address family corresponds to the sockaddr you are using. And when you want to receive, you call recvfrom on both sockets.

Answer 2

I see several problems with the code you have shown:

1. UdpSocketManager does not call getLocalAddress() before calling initializeSocket() , so the binding socket is always IPv4, never IPv6. You are also not initializing localPort before calling initializeSocket() , either.

2. getLocalAddress() (if ever called) calls itself, so you have an endless recursion loop.

3. The use of custom_random() in a loop to pick a random binding port is just plain wrong, unnecessary, and potentially unending. To pick a random port when your configured port fails, just call bind() one time with the port set to 0. The OS knows which ports are available and will pick an available random port for you. Your entire initializeSocket() is overly complicated for what it attempts to do. It can be greatly simplified.

4. When enabling SO_REUSEADDR , it must be enabled before calling bind() , not after. Also look at SO_REUSEPORT .

5. Your remoteAddrForRecv variable is declared as sockaddr_in , which is only large enough to hold an IPv4 address and will cause recvfrom() to fail if called on an IPv6 socket. Use sockaddr_storage instead. In fact. All of your sockaddr_in and sockaddr_in6 variables should be replaced with sockaddr_storage .

6. inet_ntoa() is likewise also IPv4-only. Use inet_ntop() instead to handle both IPv4 and IPv6 addresses.

Try something more like this instead:

UdpSocketManager.h

#ifndef UDP_SOCKET_MANAGER_H__
#define UDP_SOCKET_MANAGER_H__

#import "TInetAddr.h"

class UdpSocketManager
{
public:
    UdpSocketManager();
    ~UdpSocketManager();

    void getLocalAddresses();
    void initializeSocket();
    void start();
    void stop();

    void sendSignal(int p_type, TInetAddr *p_destAddress, unsigned char *p_data, int p_length);    
    void receiveSignal();

    int localPort;    
    int signalingSocket;
    int socketFamily;

    int isIPV4Available;
    int isIPV6Available;

    char wifiIP_v4[INET_ADDRSTRLEN];
    char cellularIP_v4[INET_ADDRSTRLEN];

    char wifiIP_v6[INET6_ADDRSTRLEN];
    char cellularIP_v6[INET6_ADDRSTRLEN];    

    bool running;
    pthread_t thread;
};

#endif

UdpSocketManager.m

#include <string.h>
#include <pthread.h>
#include <ifaddrs.h>
#include <arpa/inet.h>
#include <sys/socket.h>

#include "UdpSocketManager.h"
#import <Foundation/Foundation.h>

void* runUdpSocketManager(void *objRef)
{
    UdpSocketManager *THIS = (UdpSocketManager *) objRef;

    while (THIS->running) 
    {
        THIS->receiveSignal();
    }

    pthread_exit(NULL);
    return 0;
}

UdpSocketManager::UdpSocketManager()
{
    socketFamily = AF_INET;
    signalingSocket = -1;
    localPort = 0; // or whatever port you actual want
    srcAddrLen = 0;
    sendAddrLen = 0;
    running = false;
    initializeSocket();
}

UdpSocketManager::~UdpSocketManager()
{
    if(signalingSocket != -1)
    {
        close(signalingSocket);
        signalingSocket = -1;
    }
}

void UdpSocketManager::getLocalAddresses()
{
    //Read local addresses

    struct ifaddrs *interfaces = NULL;
    struct ifaddrs *temp_addr = NULL;

    isIPV4Available = FALSE;
    isIPV6Available = FALSE;

    memset(&wifiIP_v4, 0, sizeof(wifiIP_v4));
    memset(&cellularIP_v4, 0, sizeof(cellularIP_v4));

    memset(&wifiIP_v6, 0, sizeof(wifiIP_v6));
    memset(&cellularIP_v6, 0, sizeof(cellularIP_v6));

    if(getifaddrs(&interfaces) == 0)
    {
        // Loop through linked list of interfaces
        temp_addr = interfaces;
        while(temp_addr != NULL)
        {
            if ([[NSString stringWithUTF8String:temp_addr->ifa_name] hasPrefix:@"en"])
            {
                if(temp_addr->ifa_addr->sa_family == AF_INET)
                {
                    isIPV4Available = TRUE;
                    inet_ntop(AF_INET, &(((struct sockaddr_in *)temp_addr->ifa_addr)->sin_addr), wifiIP_v4, sizeof(wifiIP_v4));
                    printf("Interface: %s IPv4: %s\n", temp_addr->ifa_name, wifiIP_v4);
                }
                else if(temp_addr->ifa_addr->sa_family == AF_INET6)
                {
                    isIPV6Available = TRUE;
                    inet_ntop(AF_INET6, &(((struct sockaddr_in6 *)temp_addr->ifa_addr)->sin6_addr), wifiIP_v6, sizeof(wifiIP_v6));
                    printf("Interface: %s IPv6: %s\n", temp_addr->ifa_name, wifiIP_v6);
                }
            }
            else if([[NSString stringWithUTF8String:temp_addr->ifa_name] hasPrefix:@"pdp_ip0"])
            {
                if(temp_addr->ifa_addr->sa_family == AF_INET)
                {
                    isIPV4Available = TRUE;
                    inet_ntop(AF_INET, &(((struct sockaddr_in *)temp_addr->ifa_addr)->sin_addr), cellularIP_v4, sizeof(cellularIP_v4));
                    printf("Interface: %s IPv6: %s\n", temp_addr->ifa_name, cellularIP_v4);
                }
                else if(temp_addr->ifa_addr->sa_family == AF_INET6)
                {
                    isIPV6Available = TRUE;
                    inet_ntop(AF_INET6, &(((struct sockaddr_in6 *)temp_addr->ifa_addr)->sin6_addr), cellularIP_v6, sizeof(cellularIP_v6));
                    printf("Interface: %s IPv6: %s\n", temp_addr->ifa_name, cellularIP_v6);
                }
            }
            temp_addr = temp_addr->ifa_next;
        }

        freeifaddrs(interfaces);
    }
}

void UdpSocketManager::initializeSocket()
{
    struct sockaddr_storage srcAddr;
    struct sockaddr_in6 *srcAddr6;
    struct sockaddr_in *srcAddr4;
    socklen_t srcAddrLen;

    if(signalingSocket != -1)
    {
        close(signalingSocket);
        signalingSocket = -1;
    }

    getLocalAddresses();

    if(isIPV6Available)
    {
        signalingSocket = socket(AF_INET6, SOCK_DGRAM, 0);
        if(signalingSocket == -1)
        {
            NSLog(@"Unable to create IPv6 signaling socket");
            return;
        }

        socketFamily = AF_INET6;
        NSLog(@"IPv6 Socket created successfully");
    }
    else
    {
        signalingSocket = socket(AF_INET, SOCK_DGRAM, 0);
        if(signalingSocket == -1)
        {
            NSLog(@"Unable to create IPv4 signaling socket");
            return;
        }

        socketFamily = AF_INET;
        NSLog(@"IPv4 Socket created successfully");
    }

    int on = 1;
    setsockopt(signalingSocket, SOL_SOCKET, SO_NOSIGPIPE, &on, sizeof(on));
    setsockopt(signalingSocket, SOL_SOCKET, SO_REUSEADDR, &on, sizeof(on));

    if(socketFamily == AF_INET6)
    {
        on = 0;
        setsockopt(signalingSocket, IPPROTO_IPV6, IPV6_V6ONLY, &on, sizeof(on));

        srcAddr6 = (struct sockaddr_in6 *) &srcAddr;
        srcAddrLen = sizeof(sockaddr_in6);

        srcAddr6->sin6_len = srcAddrLen;
        srcAddr6->sin6_family = socketFamily;
        srcAddr6->sin6_addr = in6addr_any;
        srcAddr6->sin6_port = htons(localPort);
    }
    else
    {
        srcAddr4 = (struct sockaddr_in *) &srcAddr;
        srcAddrLen = sizeof(sockaddr_in);

        srcAddr4->sin_len = srcAddrLen;
        srcAddr4->sin_family = socketFamily;
        srcAddr4->sin_addr.s_addr = INADDR_ANY;
        srcAddr4->sin_port = htons(localPort);
    }

    if (bind(signalingSocket, (struct sockaddr *) &srcAddr, srcAddrLen) < 0)
    {
        if (localPort == 0)
        {
            NSLog(@"ERROR occured binding random signaling port");
            close(signalingSocket);
            signalingSocket = -1;
            return;
        }

        NSLog(@"ERROR occured binding signaling port: %d", localPort);

        if(socketFamily == AF_INET6)
            srcAddr6->sin6_port = 0;
        else
            srcAddr4->sin_port = 0;

        if (bind(signalingSocket, (struct sockaddr *) &srcAddr, srcAddrLen) < 0)
        {
            NSLog(@"ERROR occured binding random signaling port");
            close(signalingSocket);
            signalingSocket = -1;
            return;
        }

        getsockname(signalingSocket, (struct sockaddr *) &srcAddr, &srcAddrLen);

        if(socketFamily == AF_INET6)
            localPort = ntohs(srcAddr6->sin6_port);
        else
            localPort = ntohs(srcAddr4->sin_port);
    }

    NSLog(@"SignalingSocket bound successfully on Port: %d\n", localPort);
}

void UdpSocketManager::start()
{
    if(signalingSocket != -1)
    {
        running = true;
        pthread_create(&thread, NULL, runUdpSocketManager, this);
    }
}

void UdpSocketManager::stop()
{
    running = false;
}

void UdpSocketManager::receiveSignal()
{
    int port;
    char ipAddress[INET6_ADDRSTRLEN];

    unsigned char udpSignalRecvBuffer[1600];
    ssize_t signalRecvLength;

    struct sockaddr_storage remoteAddr;
    socklen_t fromlen;

    fromlen = sizeof(remoteAddr);
    signalRecvLength = recvfrom(signalingSocket, udpSignalRecvBuffer, sizeof(udpSignalRecvBuffer), 0, (struct sockaddr *) &remoteAddr, &fromlen);

    if(signalRecvLength >= 0)
    {
        if(remoteAddrForRecv.ss_family == AF_INET6)
        {
            struct sockaddr_in6 *remoteAddr6 = (struct sockaddr_in6 *) &remoteAddr;
            inet_ntop(AF_INET6, &(remoteAddr6->sin6_addr), ipAddress, sizeof(ipAddress));
            port = ntohs(remoteAddr6->sin6_port);
        }
        else
        {
            struct sockaddr_in *remoteAddr4 = (struct sockaddr_in4 *) &remoteAddr;
            inet_ntop(AF_INET, &(remoteAddr4->sin_addr), ipAddress, sizeof(ipAddress));
            port = ntohs(remoteAddr4->sin_port);
        }

        NSLog(@"RECEIVED %d bytes from %s:%d", signalRecvLength, ipAddress, port);
    }
    else
    {
        usleep(10000);// 10 ms
    }
}


void UdpSocketManager::sendSignal(int p_type, TInetAddr *p_destAddress, unsigned char *p_data, int p_length)
{
    struct sockaddr_storage sendAddr;
    socklen_t sendAddrLen;

    ssize_t returnLength;

    char ipAddress[INET6_ADDRSTRLEN];

    if(socketFamily == AF_INET6)
    {
        struct sockaddr_in6 *sendAddr6 = (struct sockaddr_in6 *) &sendAddr;
        sendAddrLen = sizeof(sockaddr_in6);

        sendAddr6->sin6_family = AF_INET6;
        sendAddr6->sin6_port = htons(p_destAddress->m_port);

        // Convert IPv4 address to IPv4-mapped IPv6 address.        
        sendAddr6->sin6_addr.__u6_addr.__u6_addr32[0] = 0;
        sendAddr6->sin6_addr.__u6_addr.__u6_addr32[1] = 0;
        sendAddr6->sin6_addr.__u6_addr.__u6_addr16[4] = 0;
        sendAddr6->sin6_addr.__u6_addr.__u6_addr16[5] = 0xffff;
        sendAddr6->sin6_addr.__u6_addr.__u6_addr32[3] = inet_addr(p_destAddress->m_address);            

        sendAddr6->sin6_flowinfo = 0;
        sendAddr6->sin6_scope_id = 0;

        inet_ntop(AF_INET6, &(sendAddr6->sin6_addr), ipAddress, sizeof(ipAddress));
    }
    else
    {
        struct sockaddr_in *sendAddr4 = (struct sockaddr_in *) &sendAddr;
        sendAddrLen = sizeof(sockaddr_in);

        sendAddr4->sin_family = AF_INET;
        sendAddr4->sin_port = htons(p_destAddress->m_port);

        if(inet_aton((char *) p_destAddress->m_address, &(sendAddr4->sin_addr)) == 0)
        {
            NSLog(@"signal message - inet_aton() failed, %s", p_destAddress->m_address);
            return;
        }

        inet_ntop(AF_INET, &(sendAddr4->sin_addr), ipAddress, sizeof(ipAddress));
    }

    returnLength = sendto(signalingSocket, p_data, p_length, 0, (struct sockaddr *) &sendAddr, sendAddrLen);
    if(returnLength >= 0)
        NSLog(@"SENT %ld bytes to %s:%d\n", returnLength, ipAddress, p_destAddress->m_port);
}

Answer 3

Solution for AFNetworking for reachability in IPv6 and IPv4

change the following code in class AFNetworkReachabilityManager

 + (instancetype)sharedManager {
    static AFNetworkReachabilityManager *_sharedManager = nil;
    static dispatch_once_t onceToken;
    dispatch_once(&onceToken, ^{
        struct sockaddr_in6 address;
        bzero(&address, sizeof(address));
        address.sin6_len = sizeof(address);
        address.sin6_family = AF_INET6;
        _sharedManager = [self managerForAddress:&address];
    });
    return _sharedManager;
}