Delphi iOS IPv6 trouble. Please ensure that your app is compatible with IPv6 networks

Question

I can't to publish my iOS app to AppStore.

Delphi 10.1.2 Berlin, iOS64, Win 8.1.

I received the next info from apple:

Thank you for your response.

Please ensure that your app is compatible with IPv6 networks.

The easiest way to test your app for IPv6 compatibility is to set up a local IPv6 network on your Mac. You can then connect to the network from your iOS devices to test IPv6 compatibility.

Please follow the step-by-step instructions provided in Supporting IPv6 DNS64/NAT64 Networks.

For additional information about supporting IPv6 networks, please review Supporting IPv6-only Networks.

---

It's connection code.

     if (FSocket<>nil) then
     begin
          if not FSocket.Connected then
          begin
               SetState(mwtrstDisConnected);
               FSocket.Free;
               FSocket:=nil;
          end
          else
              exit;
     end;

     FSocket:=TIdTCPClient.Create(nil);
     FSocket.Host:=FHost;
     FSocket.Port:=FPort;

//CheckCode


{$ifdef KBMMW_USING_INDY_9_OR_NEWER}
     FSocket.BoundPortMin:=FMinClientPort;
     FSocket.BoundPortMax:=FMaxClientPort;
{$endif}

{$IFDEF KBMMW_USING_INDY_10}
     FSocket.ReadTimeout:=RequestTimeout*1000;
     FSocket.ConnectTimeout:=ConnectTimeout*1000;
{$ENDIF}
{$IFDEF KBMMW_USING_INDY_8_00_23}
     FSocket.Connect;
{$ELSE}
 {$IFDEF KBMMW_USING_INDY_9}
     FSocket.Connect(ConnectTimeout*1000);
 {$ELSE}
     FSocket.Connect;
 {$ENDIF}
{$ENDIF}
     DoConnected(Info);

In my opinion I have to insert the next code in //CheckCode place.

  TIdStack.IncUsage;
  IdURI := TIdURI.Create('195.34.x.x');
  try
    try
      ss := GStack.ResolveHost(IdURI.Host, TIdIPVersion.Id_IPv6);
      IdURI.IPVersion := TIdIPVersion.Id_IPv6;
    except
      IdURI.IPVersion := TIdIPVersion.Id_IPv4; // Just in case.
    end;

    //ShowMessage(ss);
  finally
    FreeAndNil(IdURI);
    TIdStack.DecUsage;
  end;

But this code (GStack.ResolveHost) doesn't work on iOS.

How to solve it?

Answer 1

Try something more like this instead:

FSocket := TIdTCPClient.Create(nil);
FSocket.Host := FHost;
FSocket.Port := FPort;

{$IFDEF KBMMW_USING_INDY_9_OR_NEWER}
FSocket.BoundPortMin := FMinClientPort;
FSocket.BoundPortMax := FMaxClientPort;
{$ENDIF}

{$IFDEF KBMMW_USING_INDY_10}
FSocket.ReadTimeout := RequestTimeout*1000;
FSocket.ConnectTimeout := ConnectTimeout*1000;

// check if connecting to an IPv4/IPv6 address directly...
if GStack.IsIP(FHost) then // only checks for IPv4 right now
begin
  FSocket.IPVersion := Id_IPv4;
  FSocket.Connect;
end
else if MakeCanonicalIPv6Address(FHost) <> '' then
begin
  FSocket.IPVersion := Id_IPv6;
  FSocket.Connect;
end
else begin
  // connecting to a hostname, try IPv6 first, then fallback to IPv4...
  try
    FSocket.IPVersion := Id_IPv6;
    FSocket.Connect;
  except
    FSocket.IPVersion := Id_IPv4;
    FSocket.Connect;
  end;
end;
{$ELSE}
  // only IPv4 is supported...
  {$IFDEF KBMMW_USING_INDY_9}
FSocket.Connect(ConnectTimeout*1000);
  {$ELSE}
FSocket.Connect;
  {$ENDIF}
{$ENDIF}

DoConnected(Info);

Alternatively:

var
  LIPAddress: TIdIPAddress;
  LLocalIPs: TIdStackLocalAddressList;
  TryIPv4, TryIPv6: Boolean;
  I: Integer;

...

FSocket := TIdTCPClient.Create(nil);
FSocket.Host := FHost;
FSocket.Port := FPort;

{$IFDEF KBMMW_USING_INDY_9_OR_NEWER}
FSocket.BoundPortMin := FMinClientPort;
FSocket.BoundPortMax := FMaxClientPort;
{$ENDIF}

{$IFDEF KBMMW_USING_INDY_10}
FSocket.ReadTimeout := RequestTimeout*1000;
FSocket.ConnectTimeout := ConnectTimeout*1000;

LIPAddress := TIdIPAddress.MakeAddressObject(FHost);
if LIPAddress <> nil then
begin
  // connecting to an IPv4/IPv6 address...
  FSocket.IPVersion := LIPAddress.AddrType;
  LIPAddress.Free;
  FSocket.Connect;
end else
begin
  // connecting to a hostname...

  TryIPv4 := False;
  TryIPv6 := False;

  LLocalIPs := TIdStackLocalAddressList.Create;
  try
    GStack.GetLocalAddressList(LLocalIPs);
    for I := 0 to LLocalIPs.Count-1 do
    begin
      case LLocalIPs[I].IPVersion of
        Id_IPv4: TryIPv4 := True;
        Id_IPv6: TryIPv6 := True;
      end;
    end;
  finally
    List.Free;
  end;

  if TryIPv6 then
  begin
    try
      FSocket.IPVersion := Id_IPv6;
      FSocket.Connect;
      TryIPv4 := False;
    except
      if not TryIPv4 then
        raise;
    end;
  end;

  if TryIPv4 then
  begin
    FSocket.IPVersion := Id_IPv4;
    FSocket.Connect;
  end;

  if not (TryIPv4 or TryIPv6) then
    raise Exception.Create('Not connected to an IPv4 or IPv6 network');
end;
{$ELSE}
  // only IPv4 is supported...
  {$IFDEF KBMMW_USING_INDY_9}
FSocket.Connect(ConnectTimeout*1000);
  {$ELSE}
FSocket.Connect;
  {$ENDIF}
{$ENDIF}

DoConnected(Info);

Note that this situation would become much simpler to handle once Indy implements the following feature, but that is a ways off, I think:

Support round-robin DNS (support connecting to IPv4/IPv6 hostnames)