How to specify supported architectures for android app in build.gradle?

Question

My Android app supports only arm64-v8a and armeabi-v7a. However, due to one of the dependencies, I see the following in my lib folder of the apk:

arm64-v8a
armeabi
armeabi-v7a
mips
x86
x86_64

Here is my build.gradle:

buildscript {
    repositories {
        maven { url 'https://maven.fabric.io/public' }
    }

    dependencies {
        classpath 'io.fabric.tools:gradle:1.+'
    }
}
apply plugin: 'com.android.application'
apply plugin: 'io.fabric'

repositories {
    maven { url 'https://maven.fabric.io/public' }
}


android {
    compileSdkVersion Integer.parseInt(project.ANDROID_BUILD_SDK_VERSION)
    buildToolsVersion project.ANDROID_BUILD_TOOLS_VERSION

    defaultConfig {
        applicationId "com.mycompany.myapp"
        minSdkVersion Integer.parseInt(project.ANDROID_BUILD_MIN_SDK_VERSION)
        targetSdkVersion Integer.parseInt(project.ANDROID_BUILD_TARGET_SDK_VERSION)
        versionCode Integer.parseInt(project.VERSION_CODE)
        versionName project.VERSION_NAME
        multiDexEnabled true
    }

    dexOptions {
        javaMaxHeapSize "4g"
    }

    buildTypes {
        release {
            minifyEnabled true
            shrinkResources true // https://developer.android.com/topic/performance/reduce-apk-size.html
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

dependencies {
    compile fileTree(include: ['*.jar'], dir: 'libs')
    testCompile 'junit:junit:4.12'
    compile 'com.android.support:appcompat-v7:24.0.0'
    compile 'com.android.support:design:24.0.0'
    compile 'com.android.support:support-v4:24.0.0'
}


// Must follow the above play-services compile directives
apply plugin: 'com.google.gms.google-services'

How to specify the supported architectures in build.gradle with Android Studio?

Answer 1

Add this to your build types in your build.gradle

ndk {
  abiFilters "armeabi-v7a", "arm64-v8a"
}

Answer 2

To add a bit more detail, you have two options: 1. In your app build.gradle file, specify the abiFilters for a buildType:

buildTypes {
  debug { 
     ndk {
       abiFilters "x86", "armeabi-v7a", "armeabi"
       //abiFilters ABI_FILTERS
     }
   }
}

2. Specify the abiFilters in the gradle.settings file and reference them in your app build.gradle for a build type:

gradle.settings:

ABI_FILTERS=armeabi-v7a;x86

app build.gradle:

buildTypes{
ndk {
  abiFilters = []
    abiFilters.addAll(ABI_FILTERS.split(';').collect{it as String})
  }
}