Batch to check if process exists

Question

I'd like a batch that will check if the process firefox.exe exists (after it has been started by the start command). If the process exists, it will go to the label :fullscreen, else the batch will go the the label :timeout. Then, it will check again if the process firefox.exe exists and if not, it will go again to the label :fullscreen until the process exists.

Here is my batch:

@echo off
start "C:\Program Files (x86)\Mozilla Firefox\firefox.exe"
:timeout
timeout /t 5
:fullscreen
nircmd sendkeypress F11
exit

How can I do this check ?

Answer 1

I suggest for this task the batch file:

@echo off
start "" /max firefox.exe
if errorlevel 1 goto :EOF
set LoopCount=0

:WaitLoop
%SystemRoot%\System32\timeout.exe /T 5
%SystemRoot%\System32\tasklist.exe /FI "IMAGENAME eq firefox.exe" 2>nul | %SystemRoot%\System32\find.exe /I "firefox.exe" >nul
if not errorlevel 1 nircmd.exe sendkeypress F11 & goto :EOF
set /A LoopCount+=1
if not %LoopCount% == 6 goto WaitLoop

Let me explain the few command lines used here.

---

1. Starting Firefox

The command START being an internal command of cmd.exe interprets the first double quoted string as optional title for the console window. Therefore the command line

start "C:\Program Files (x86)\Mozilla Firefox\firefox.exe"

results just in opening a new console window with the window title:
C:\\Program Files (x86)\\Mozilla Firefox\\firefox.exe

For that reason "" is specified as first START argument to define an empty title. Firefox is a GUI application. So no console window is opened which means an empty window title is really enough.

The parameter /max would not be really necessary, but the goal is to get Firefox into full screen mode after starting. So why not starting it already maximized?

32-bit version of Firefox is by default installed in directory %ProgramFiles% on 32-bit Windows and in %ProgramFiles(x86)% on 64-bit Windows. But it is possible during the installation to install Firefox into any other folder. But Firefox installer is well coded and registers firefox.exe in Windows registry under key:

HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\App Paths

This is recommended by Microsoft as written in MSDN article Application Registration .

The command START searches also in Windows registry under this key for an executable specified as argument without path as explained in answer on Where is “START” searching for executables?

This is the reason for using just firefox.exe on START command line because that starts an installed Firefox independent on installation location.

START displays an appropriate message box if firefox.exe could not be started and exits in this case with a return code greater 0 (9059 in my test on one computer).

The help output on running if /? in a command prompt window explains how to evaluate the exit code of a previous command or application without usage of immediate or delayed environment variable expansion and therefore working anywhere in a batch file from MS-DOS (really!) to currently latest Windows 10.

The command line if errorlevel 1 goto :EOF means IF start failed to start firefox.exe indicated by an exit code greater or equal 1 THEN exit execution of this batch file. For details on exiting batch file execution see answer on Where does GOTO :EOF return to?

---

2. Checking for running Firefox

The command TASKLIST being an external command, ie a console application in system directory of Windows, outputs a list of running processes. This list can be already filtered by TASKLIST itself for a specific process as done in batch file with /FI "IMAGENAME eq firefox.exe" .

But TASKLIST is designed for just printing a list of processes. It is not designed for checking if a specific process is running and returning the result to the calling process via exit code. TASKLIST always exits with 0.

But an error message is output to handle STDERR on using a filter and no process can be found in process list matching this filter. For that reason 2>nul is used to suppress this error message by redirecting it to device NUL. Read the Microsoft article about Using Command Redirection Operators for more information about redirection.

A simple method to get a simple false/true respectively 0/1 result on checking for running Firefox is filtering output of TASKLIST with external command FIND which exits with 0 if the string to find was indeed found or with 1 if the searched string could not be found in the text read in this case from STDIN . The output of FIND is of no interest and therefore suppressed with redirection to device NUL using >nul .

Instead of using TASKLIST and FIND it is also possible to use QPROCESS :

%SystemRoot%\System32\qprocess.exe firefox.exe >nul 2>&1

QPROCESS exits with exit code 1 if firefox.exe could not be found in list of running processes. Otherwise the exit code is 0 on firefox.exe is running.

---

3. Evaluating Firefox process checking result

if not errorlevel 1 nircmd.exe sendkeypress F11 & goto :EOF

The IF command checks if exit code of FIND is NOT greater or equal 1 which means if exit code is lower than 1 . Command FIND exits never with a negative value. So if this condition is true then it is time to execute nircmd.exe to send key press F11 to application in foreground hopefully being Firefox (not guaranteed by this code) and exit batch file processing.

Otherwise the batch file should wait once again 5 seconds and then do the check again. This can very easily result in an endless running batch file in case of started Firefox is immediately closed by the user before the 5 seconds wait timed out. For that reason it is counted how often the wait loop is already executed. After 6 loop runs, or 30 seconds, it is really time to no longer wait for Firefox and exit the batch file.

---

4. Getting more information about used commands

For understanding the used commands and how they work, open a command prompt window, execute there the following commands, and read entirely all help pages displayed for each command very carefully.

• echo /?
• find /?
• if /?
• qprocess /?
• set /?
• start /?
• tasklist /?
• timeout /?

And Single line with multiple commands using Windows batch file should be also read explaining operator & in addition to all other web pages referenced already above.

Answer 2

You can show a list of opened programs like this:

tasklist

To check if firefox exists:

EDIT: Code edited to show a fully working example

@echo off
start "C:\Program Files (x86)\Mozilla Firefox\firefox.exe"
goto :checkloop

:checkloop
tasklist|find "firefox.exe" > NUL
if %ERRORLEVEL% == 0 ( 
    call :fullscreen 
    exit
) else ( 
     call :timeout
     goto :checkloop
)


:fullscreen
nircmd sendkeypress F11
goto :EOF

:timeout
timeout /t 5
goto :EOF

Answer 3

You can also use QUERY PROCESS:

@Echo Off
If Not Exist "%ProgramFiles(x86)%\Mozilla Firefox\firefox.exe" Exit/B
Start "" "%ProgramFiles(x86)%\Mozilla Firefox\firefox.exe"
:Loop
Timeout 5 /NoBreak>Nul
QProcess firefox.exe>Nul 2>&1||GoTo :Loop
NirCmd SendKeyPress F11