How can I round a date to nearest 15 minute interval in Perl?

Question

I want to round current time to the nearest 15 minute interval.
So if it is currently 6:07 , it would read 6:15 as the start time.

How can I do that?

Answer 1

You can split the time into hours and minutes and then use the ceil function as:

use POSIX;

my ($hr,$min) = split/:/,$time;    
my $rounded_min = ceil($min/15) * 15;

if($rounded_min == 60) {
   $rounded_min = 0;
   $hr++;
   $hr = 0 if($hr == 24); 
}

Answer 2

The nearest 15 minute interval to 6:07 is 6:00, not 6:15. Do you want the nearest 15 minute interval or the next 15 minute interval?

Assuming it's the nearest, something like this does what you want.

#!/usr/bin/perl

use strict;
use warnings;

use constant FIFTEEN => (15 * 60);

my $now = time;

if (my $diff = $now % FIFTEEN) {
  if ($diff < FIFTEEN / 2) {
    $now -= $diff;
  } else {
    $now += (15*60) - $diff;
  }
}

print scalar localtime $now, "\n";

Answer 3

An easy solution is to use Math::Round from CPAN.

use strict;
use warnings;
use 5.010;

use Math::Round qw(nearest);

my $current_quarter = nearest(15*60, time());
say scalar localtime($current_quarter);

Answer 4

Minor variation on first answer using sprintf instead of ceil and POSIX. Also does not use any additional CPAN modules. This rounds up or down so 6:07 = 6:00, 6:08 = 6:15, 6:22 = 6:15 and 6:23 = 6:30. Note that a hour is added if the rounded minutes equal 60. However to do this properly, you would have to use a timelocal and localtime functions to add the hour. ie adding an hour may add a day, month or year.

  #!/usr/bin/perl  

  my ($hr,$min) = split/:/,$time;   

  my $interimval = ($min/15);

  my $rounded_min = sprintf "%.0f", $interimval;

  $rounded_min = $rounded_min * 15;

  if($rounded_min == 60) 

  {

     $rounded_min = 0;

     $hr++;

     $hr = 0 if($hr == 24); 

  }