Export from Access to Excel to an existing worksheet

Question

Example: I have the excel file test.xls and in it the sheet1, sheet2, sheet3, sheet4 with some information in it. I want to export the result of 4 queries to those sheets, but I want to add the result after the last row with data and not to overwrite it.

Answer 1

I worked on something similar recently. In Excel I used VBA.

Dim cn As Object
Dim rs As Object
Dim strFile As String
Dim strCon As String
Dim strSQL As String
Dim s As String
Dim i As Integer, j As Integer
Dim StartDate As Date, EndDate As Date, ModStartDate As Date, ModEndDate As Date


'Modify the Start date because Maint 24hr cycle is 930 - 930 not 12 - 12
ModStartDate = StartDate - 1


''Access database
strFile = "S:\IT\Databases\Main_BE.mdb"

''This is the Jet 4 connection string, you can get more
''here : http://www.connectionstrings.com/excel
strCon = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=" & strFile & ";"

''Late binding, so no reference is needed
Set cn = CreateObject("ADODB.Connection")
Set rs = CreateObject("ADODB.Recordset")
cn.Open strCon


'Get the info from Access
strSQL = "SELECT * FROM Work_Orders " _
    & "WHERE Repair_Start_Date >= #" & ModStartDate & "# " _
    & "AND Repair_Start_Date <= #" & EndDate & "# " _
    & "ORDER BY Repair_Start_Date, Repair_Start_Time"
rs.Open strSQL, cn

'Paste the SQL query at A10 Sheet3
Sheet3.Cells(10, 1).CopyFromRecordset rs

''Tidy up
rs.Close
Set rs = Nothing
cn.Close
Set cn = Nothing

You would just need to modify the SQL statement, and then to add a new row you could use a variable to count the number of existing rows with:

"=Counta(some range:some range)"

Then just add 1 to the variable for the next row.

Answer 2

Thanks everybody! I could solve it using :

    Private Sub Command0_Click()
Dim rstName As Recordset
Set rstName = CurrentDb.OpenRecordset("query1")

Dim objApp As Object, objMyWorkbook As Object, objMySheet As Object, objMyRange As   Object

Set objApp = CreateObject("Excel.Application")
Set objMyWorkbook = objApp.Workbooks.Open("c:/exportarexcell/teste.xls")
Set objMySheet = objMyWorkbook.Worksheets("FolhaTeste")
Set objMyRange = objMySheet.Cells(objApp.ActiveSheet.UsedRange.Rows.Count + 1, 1)

With objMyRange
 rstName.MoveFirst 'Rewind to the first record
 .Clear
 .CopyFromRecordset rstName
End With
End Sub