f＃中自定义时钟的更好解决方案

Question

我需要一个解决方案，将时间添加到忽略给定时间间隔的日期。 例如，如果给定日期是2015年1月1日19:00，则关闭间隔是20:00 - 8:00，因此将在2015年1月10日10:00添加3小时。 另一个例子是Date：01 jan 2015 03:00 AM，Interval 20:00 - 08:00将给出结果01 jan 2015 11:00 AM

我的解决方案是：

    let nextInterval (d:DateTime) (s:TimeSpan) (f:TimeSpan) =
       let next (d:DateTime) (ts:TimeSpan) 
                = if d.TimeOfDay < ts 
                      then d.Date.Add(ts)
                      else d.Date.AddDays(1.0).Add(ts)
       let ns = next d s
       let nf = next d f
       (ns,nf)

    let addTime (d:DateTime) (n:TimeSpan) (s:TimeSpan) (f:TimeSpan) = 
      let rec loop (d:DateTime) (n:TimeSpan) = 
        let dt = d.TimeOfDay
        let (ns,nf) = nextInterval d s f //next start interval and next finish interval
        let outOfInterval = ((dt < s || dt >= f) && f >= s) ||
                            ((dt < s && dt >=f) && f < s)
        if n = TimeSpan.Zero
            then if outOfInterval then d
                                  else nf
            else 
             if outOfInterval 
                then if (d+n < ns) 
                        // before next start
                        then loop (d+n) TimeSpan.Zero
                        // intersecting with interval
                        else if (d+n < nf)
                                    then loop (d+n) (n - (ns - d)) 
                                    else loop nf    (n - (ns - d))
                else //in interval
                    loop nf n
       loop d n

我的问题是：有没有人为此提供更短的解决方案？

Answer 1

我会使用某种形式的模运算，而不是循环。 换句话说，考虑日期的更简单方法是：

• 我在哪个时期？ （即，哪一天的当前时间没有被忽略的时间开始？）
• 本期内部已经过了多少时间？

如果要添加时间，请将其添加到当前时间段内的时间，然后使用除法和余数拆分整个句点。

let day = TimeSpan(1, 0, 0, 0).Ticks

let addTime (dayBegin : TimeSpan) (daySpan : TimeSpan) (d : DateTime) (dt : TimeSpan) =
    if dt.Ticks < 0L then invalidArg "dt" "Negative time-spans are not supported."
    let t0 = (d - dayBegin).Ticks
    let rawSlot, rawSpan = t0 / day * day, t0 % day
    let slot, span = if rawSpan > daySpan.Ticks then rawSlot + day, dt.Ticks
                     else rawSlot, rawSpan + dt.Ticks
    DateTime(slot + span / daySpan.Ticks * day + span % daySpan.Ticks) + dayBegin

测试 20:00 - 8:00作为忽略的间隔，日期从8:00开始，需要12h：

let test = addTime (TimeSpan(8, 0, 0)) (TimeSpan(12, 0, 0))

使用第一个示例作为输入：

test (DateTime(2015, 01, 01, 19, 0, 0)) (TimeSpan(3, 0, 0))
// result: 2015-01-02 10:00:00