通过Clojure中的键值过滤地图列表的简便方法

Question

我在Clojure中找不到内置功能，无法通过键值过滤地图列表。 例如，我们有以下列表：

user=> (def animals (list {:name "Charlie" :weight 350 :specie :elephant}
                          {:name "Vasya" :weight 250 :specie :bear}
                          {:name "John" :weight 200 :specie :elephant}
                          {:name "Monk" :weight 200 :specie :monkey}))
#'user/animals

例如，我想选择所有带有值:elephant的:specie 。 我怎样才能做到这一点？ 我发现的最好方法是：

user=> (defn filter-data [data m]
         (let [k (keys m) v (vals m)]
           (filter #(= (map % k) v) data)))
#'user/filter-data

user=> (clojure.pprint/print-table (filter-data animals {:specie :elephant}))

|   :name | :weight |   :specie |
|---------+---------+-----------|
| Charlie |     350 | :elephant |
|    John |     200 | :elephant |
nil

有更好的方法吗？

Answer 1

使用过滤器可以轻松实现

(clojure.pprint/print-table 
  (filter #(= (:specie %) :elephant) animals))

您始终可以将过滤器包装在函数中以获取不同的“语法”，例如：

(defn cool-filter [[k v] l]
  (filter #(= (k %) v) l))

(clojure.pprint/print-table 
  (cool-filter [:specie :elephant] animals))

Answer 2

您还可以使用函数组合：

(filter (comp (partial = :elephant) :specie) animals)

要么...

(filter (comp #{:elephant} :specie) animals)

Answer 3

虽然filter解决方案显然是最简单的方法，但是我想添加一个替代方案，以防您需要查找多个物种：

(def grouped-animals (group-by :specie animals))
(:elephant grouped-animals)
; [{:name "Charlie", :weight 350, :specie :elephant} {:name "John", :weight 200, :specie :elephant}]