使用readMaybe读取自然数列表

Question

我正在使用此函数以以下格式从字符串中读取自然数列表： [1, 2, 3] ：

readMaybeIntList :: String -> Maybe [Int]
readMaybeIntList line = case readMaybe line of
                          Just l -> return l
                          Nothing -> Nothing

现在，它仅适用于整数-检查数字是否自然的正确方法是什么？ 我是否应该修改Just l子句以检查所有数字是否均>=0 ？ 从嵌套的Just子句中返回Nothing是个好主意吗？

Answer 1

你可以用do -notation和guard从Control.Monad避免过度模式匹配：

import Text.Read
import Control.Monad


readMaybeNatural :: String -> Maybe Int
readMaybeNatural str = do
  n <- readMaybe str
  guard $ n >= 0
  return n


readMaybeNaturals :: String -> Maybe [Int]
readMaybeNaturals =
  sequence . map readMaybeNatural . words

Answer 2

好吧，如果您仍然要使用return来为Maybe调用monad实例，那么我想我可能会写：

import Text.Read
import Control.Monad

readMaybeNatList :: String -> Maybe [Int]
readMaybeNatList line = do
  ns <- readMaybe line
  guard $ all (>=0) ns
  return ns

这是Maybe monad的惯用用法。 是否比显式模式匹配（和无monad）更清晰：

readMaybeNatList' :: String -> Maybe [Int]
readMaybeNatList' line =
  case readMaybe line of
    Just ns | all (>=0) ns -> Just ns
    _ -> Nothing

可能是意见和目标受众的问题。