VBA-从Word运行宏以将值粘贴到Excel中

Question

我对VBA相对较新，对为什么无法从Word粘贴到Excel感到困惑。 下面的宏最终将值粘贴到Word中，即使我认为我正在激活Excel文档。
该宏应从Word运行； 然后需要将来自各种FormField的值粘贴到现有Excel文件中的单元格中。 我搜索了一个类似的问题，尽管返回的内容似乎是我所遇到的变化，并且我无法修改这些答案。 任何帮助，将不胜感激。

Sub Transfer()

Dim WD As Object
Dim ED As Excel.Application
Dim EDS As Excel.Workbook

Set WD = ActiveDocument
Set ED = CreateObject("excel.application")
ED.Visible = True 
Workbooks.Open FileName:= _
"C:\Users\Documents\AppealData.xlsx"
ActiveWorkbook.Activate
Set EDS = ActiveWorkbook

WD.FormFields("AppNum").Copy
EDS.Activate
EDS.Sheets("Sheet1").Range("A1").Select
Selection.Paste

End Sub

Answer 1

您的Selection是指当前应用程序。 要引用Excel应用程序，您需要使用ED.Selection 。 但是无论如何都要依靠Activate和Select是一个坏主意。

我建议您将代码更改为：

Sub Transfer()

    Dim WD As Document
    Dim ED As Excel.Application
    Dim EDS As Excel.Workbook

    Set WD = ActiveDocument
    Set ED = CreateObject("excel.application")
    ED.Visible = True 
    'Avoid "Activate"
    Set EDS = ED.Workbooks.Open(FileName:= _
             "C:\Users\Documents\AppealData.xlsx")

    WD.FormFields("AppNum").Copy
    'Avoid "Activate" and "Select" and "Selection"
    '"Paste" is a worksheet Method, use "PasteSpecial" for a Range
    'Use "xlPasteValues" to avoid formatting issues
    EDS.Sheets("Sheet1").Range("A1").PasteSpecial Excel.xlPasteValues
End Sub

Answer 2

这在这里应该为您工作。

Sub Transfer()
   Dim oExcel As Excel.Application
   Dim oWB As Workbook

   Set oExcel = New Excel.Application
   Set oWB = oExcel.Workbooks.Open("C:\Users\Documents\AppealData.xlsx")

   oExcel.Visible = True

   Workbooks("Book1").Worksheets("Sheet1").Cells(1, 1).Value = _ 
      CStr(Documents("Document1").FormFields("AppNum").Result)
End Sub