为什么我的MIPS程序没有从内存中加载值？

Question

我正在开发一个将字符串位置反转的程序。

但是我遇到了一些麻烦。

该程序通过循环遍历字符串一次来获得字符串的长度。

一旦找到另一个循环，就通过将值保存在临时寄存器中来前后交换字符，然后将另一个值所在的字节存储到字节中。

然后，字符串开头的地址递增，结尾的地址递减。 完成此操作，直到在循环中也增加的临时寄存器等于字符串长度的一半。

但是由于某种原因，当我逐步执行程序时，它不会在第二个循环中将字符的值存储到寄存器中。

有人会为什么会这样吗？我该如何解决？

谢谢。

.data
msg:    .asciiz "Hello World"
nline: .asciiz "\n"
.globl main


.text
#t0 address location
#t1 address location used to increment and find \0
#t2 value stored in addres location of t1
#t3 stores length of string
main: 
    la $t0,msg  #load address location

    add $t1,$t0,$zero #loads address location for use in loop
    lb $t2,0($t1)   #loads value found at address in t1 

    add $t3,$zero,$zero #set length to 0


    len: #increments value that determines length and memory location of current character
    addi $t3,$t3,1
    add $t0,$t0,1
    #add $a0,$zero,$t3
    #li $v0,1
    #syscall
    lb $t2,0($t0)

    bne $t2,$zero,len   #loops back to  len if null character is not found


    srl $t4,$t3,1


    add $t5,$t0,$zero
    add $t6,$t3,$t0

    add $t9,$zero,$zero


    swap:
    lb $t7,0($t5)
    lb $t8,0($t6)

    sb $t8,0($t6)
    sb $t7,0($t5)

    addi $t5,$t5,1
    sub $t6,$t6,1
    addi $t9,$t9,1

    bne $t4,$t9,swap


    li $v0,10
    syscall

Answer 1

逐步执行程序时，应验证所有假设，尤其是在发现一些问题（例如字母值未正确加载）的情况下。

在您的情况下（我确实在MARS中运行过它），就在标签swap:寄存器包含：

t0  0x1001000b
t1  0x10010000
t2  0
t3  11
t4  5
t5  0x1001000b
t6  0x10010016

而msg符号值为0x10010000 。 那只是在t1 ，但是您使用t5, t6来加载字符串的值， t5指向msg的零终止符， t6已经消失了。 因此， “某些原因”是您没有读取想要的内存，而是超出了内存。

从代码中的注释来看，您在“ strlen”中使用了t0而不是t1 ，并且您希望t0保留原始msg地址（但是t1保留了它， t0指向msg的零终止符）。

同样，您的代码对于空字符串也将失败，因为您执行了一些初始lb但未对其进行测试，然后从字符串的第二个字节开始检查零。

总的来说，您可能经常会尝试清理一下第一个想法，并简化一些想法，在此特定任务中，您只需使用指向字符串的指针即可完成所有操作，而无需将length / half_length计算为整数：

.data
msg:    .asciiz "Hello World"

.text
.globl main
main: 
    la   $t0,msg        # t0 = string address
    add  $t1,$t0,$zero  # t1 = string address for "strlen"

len: # find zero terminator of string
    lb   $t2,($t1)      # t2 = letter from string 
    addi $t1,$t1,1      # advance string pointer
    bne  $t2,$zero,len  # loop back to len if null character is not found

  # t0 = string address, t1 = points 1 byte after the zero terminator
    addi $t1,$t1,-2     # adjust t1 to point to last character
    # validate that t0 < t1 (will not for empty or one letter strings)
    bgeu $t0,$t1,too_short_to_reverse  # sltu+beq

swap:
    lb   $t2,0($t0)     # swap letters at t0/t1 positions
    lb   $t3,0($t1)
    sb   $t2,0($t1)
    sb   $t3,0($t0)
    addi $t0,$t0,1      # adjust pointers
    addi $t1,$t1,-1
    blt  $t0,$t1,swap   # while t0 < t1 keep swapping letters
too_short_to_reverse:
    # done, string is reversed

    # debug output of string to see it reversed
    li   $v0,4
    la   $a0,msg
    syscall

    li   $v0,10         # exit syscall
    syscall

（使用了很少的伪指令，虽然您的原始源代码看起来像您在尝试避免使用它们，但是您仍然有一些不准确的伪指令，这些伪指令必须通过汇编程序进行任何调整，例如add $t0,$t0,1 -> addi ）