使用本地消息传递通过 Delphi 从 Thunderbird 复制 email 时遇到编码问题

Question

我正在使用本机消息传递在 thunderbird 中编写插件（ 遵循 python 中的 ping pong 示例）调用 Delphi 程序以将电子邮件复制为本地“.eml”文件。 我面临的问题似乎是编码。 此外，生成的文件在文件的开头和结尾包含双引号 ("") 以及转义双引号 (\")。我只想拥有 1 对 1 的副本而不更改其内容。

邮件内容示例：

"test"
€‚ƒ„…†‡ˆ‰Š‹ŒŽ‘’“”•–—˜™š›œžŸ
éöàäèüâêû 

但是，在文件中，它看起来更像这样：

\"test\"
€‚ƒ„…†‡ˆ‰Š‹ŒŽ‘’“â€â€¢â€“—˜™š›œžŸ
éöà äèüâêû

我可能已经发现了问题，这在此处进行了解释：

https://www.i18nqa.com/debug/utf8-debug.html

但是，我真的不知道如何调整我的代码来解决这个问题。

谢谢您的帮助！

这是我的 background.js：

async function main() {
        messenger.menus.create({
            contexts : ["message_list"],
            id: "copy@mail.lu",
            onclick : passMsg,
            title: messenger.i18n.getMessage("lang.menuTitle")
        });
    }
    
    async function passMsg(OnClickData) {
        if (OnClickData.selectedMessages && OnClickData.selectedMessages.messages.length > 0) {
            let MessageHeader = OnClickData.selectedMessages.messages[0];
            let raw = await messenger.messages.getRaw(MessageHeader.id);
            let port=browser.runtime.connectNative("copymail");
    
            port.onMessage.addListener((message) => {
              port.disconnect();
            });
    
            port.postMessage(raw);
        } else {
            console.log("No message selected");
        }
    }
    main();

这是我的 Delphi 代码：

procedure WriteSTDInputToFile(const Filename: String);
    var
       Buffer:    array [0 .. 3] of Byte;
       msgLen:    LongInt;
       msg:       UTF8String;
       myFile:    TextFile;
       StdIn:     THandleStream;
       jsonValue: TJSONValue;
    begin
       StdIn  := THandleStream.Create(GetStdHandle(STD_INPUT_HANDLE));
    
       try
          msgLen    := 0;
          if StdIn.Read(Buffer, SizeOf(msgLen)) > 0 then
             msgLen := PLongInt(@Buffer)^;
    
          if msgLen > 0 then
          begin
             SetLength(msg, msgLen);
             StdIn.Read(PUTF8Char(msg)^, msgLen);
    
             if msg <> '' then
             begin
                AssignFile(myFile, Filename, CP_UTF8);
                ReWrite(myFile);
    
                jsonValue := TJSONObject.ParseJSONValue(msg);
    
                try
                   write(myFile, UTF8Encode(jsonValue.ToString));
                finally
                   jsonValue.Free;
                end;
    
                CloseFile(myFile);
    
             end;
          end;
    
       finally
          if Assigned(StdIn) then
             StdIn.Free;
       end;
    
    end;

结果文件内容：

"X-MDAV-Result: clean
X-MDAV-Processed: mail.test.lu, Wed, 28 Oct 2020 08:13:22 +0100
X-Spam-Processed: mail.test.lu, Wed, 28 Oct 2020 08:13:22 +0100
Return-path: <copy@mail.lu>
X-Spam-Checker-Version: SpamAssassin 3.4.2 (2018-09-13) on MAIL01E
X-Spam-Level: 
X-Spam-Status: No, score=0.7 required=10.0 tests=HTML_MESSAGE,MPART_ALT_DIFF
    shortcircuit=no autolearn=disabled version=3.4.2
Authentication-Results: test.lu;
    auth=pass (plain) smtp.auth=ascholtes@test.lu
Received: from [172.16.17.35] [(172.16.17.35)] by test.lu (172.31.3.6) with ESMTPSA id md50033234892.msg; 
    Wed, 28 Oct 2020 08:13:21 +0100
X-MDRemoteIP: 172.16.17.35
X-MDArrival-Date: Wed, 28 Oct 2020 08:13:21 +0100
X-Authenticated-Sender: ascholtes@test.lu
X-Rcpt-To: copy@mail.lu
X-MDRcpt-To: copy@mail.lu
X-Return-Path: copy@mail.lu
X-Envelope-From: copy@mail.lu
X-MDaemon-Deliver-To: ascholtes@test.lu
To: Ayuth Scholtes <copy@mail.lu>
From: Ayuth Scholtes <copy@mail.lu>
Subject: Test
Organization: CISS
Message-ID: <7eb36f7c-a7af-c272-c189-eded642c3e1c@test.lu>
Date: Wed, 28 Oct 2020 08:13:21 +0100
User-Agent: Mozilla/5.0 (Windows NT 10.0; Win64; x64; rv:68.0) Gecko/20100101
 Thunderbird/68.10.0
MIME-Version: 1.0
Content-Type: multipart/alternative;
 boundary=\"------------6068A746223BB2C9F1771938\"
Content-Language: lb-LU

This is a multi-part message in MIME format.
--------------6068A746223BB2C9F1771938
Content-Type: text/plain; charset=utf-8; format=flowed
Content-Transfer-Encoding: 8bit

|\"test\" â¬âÆââ¦â â¡Ëâ°Å â¹ÅŽâââââ¢ââËâ¢Å¡âºÅžŸ éöàäèüâêû|


--------------6068A746223BB2C9F1771938
Content-Type: text/html; charset=utf-8
Content-Transfer-Encoding: 8bit

<html>
  <head>

    <meta http-equiv=\"content-type\" content=\"text/html; charset=UTF-8\">
  </head>
  <body>
    <pre class=\"lang-pascal s-code-block hljs delphi\"><code>\"test\"
â¬âÆââ¦â â¡Ëâ°Å â¹ÅŽâââââ¢ââËâ¢Å¡âºÅžŸ
éöàäèüâêû</code></pre>
  </body>
</html>

--------------6068A746223BB2C9F1771938--
"

Answer 1

首先让我说你在 web 扩展（Thunderbird 附加组件）和使用本地消息传递的本地应用程序之间传输数据方面做得很好。 理解和设置它并不容易，但是您设法通过问题中描述的一些小故障传输了所需的数据。

...生成的文件在文件的开头和结尾包含双引号 ( " ) 以及转义双引号 ( \" )

在附加组件中，您获得原始 email 数据作为字符串 - console.log(typeof raw)提供string ，然后您将其传递给port.postMessage 。 虽然文档说它需要JSON object 表示要发送的消息，但它似乎接受根据某些标准有效的单个字符串值JSON 。 在 Delphi 代码中，您通过STDIN接收消息并使用TJSONObject.ParseJSONValue将其解析为TJSONValue 。 它实际上会创建TJSONString的实例。 您可以通过检查jsonValue.ClassName的值来验证这一点。 当您使用jsonValue.ToString时会出现引号问题，它会返回字符串的引用版本，该版本与解析前的字符串基本相同。 使用Value属性返回原始字符串值。

单独使用jsonValue.Value不会帮助您解决编码问题。 您从电子邮件客户端获取的原始消息数据采用EML 格式。 它符合RFC-822 ，这意味着它是 ASCII 编码的，但它可以包含任意编码的消息部分（请参阅您自己的示例 EML）。 由于您只想保存 EML 文件而不考虑任何编码，最好是传输 EML 的原始字节，但这不是 Javascript 和本机消息传递 API 开箱即用的支持。因此我建议您将 Base64 编码的数据字符串发送到本机应用程序，在本机应用程序中将其解码为可以直接写入磁盘的原始字节。

要在附加组件中将原始消息数据编码为 Base64 字符串，请使用 function btoa ：

port.postMessage(btoa(raw));

要在本机应用程序中接收消息，您可以执行以下操作：

uses
  System.SysUtils, System.Classes, System.IOUtils, System.JSON, System.NetEncoding, Winapi.Windows;

procedure WriteSTDInputToFile(const FileName: string);
var
  StdIn: THandleStream;
  MsgLen: Cardinal;
  Data: TBytes;
  JSONValue: TJSONValue;
begin
  StdIn := THandleStream.Create(GetStdHandle(STD_INPUT_HANDLE));
  try
    StdIn.ReadBuffer(MsgLen, SizeOf(MsgLen));
    SetLength(Data, MsgLen);
    StdIn.ReadBuffer(Data, MsgLen);
    JSONValue := TJSONObject.ParseJSONValue(Data, 0);
    Data := TNetEncoding.Base64.DecodeStringToBytes(JSONValue.Value);
    TFile.WriteAllBytes(FileName, Data);
  finally
    StdIn.Free;
  end;
end;

注意对原始代码的几处改进：

• MsgLen的Cardinal类型的使用。 该协议定义输入的前 4 个字节指示消息长度（以字节为单位，表示为 32 位无符号 integer） Cardinal是 Delphi 的此类值的本机类型，或者您也可以使用UInt32别名。
• 我使用ReadBuffer方法而不是Read从 STDIN 读取，这使得程序在遇到一些意外情况时崩溃。 理想情况下，您应该处理这种情况，通过 STDOUT 发送错误消息作为响应，并在附加组件中处理响应。
• 我不会将传统的 I/O 例程与流混合使用。 我什至没有使用 stream 在我的代码中写入 output 文件。 由于来自Syste.IOUtils的File.WriteAllBytes ，创建文件是单行的。
• 我不检查if Assigned(StdIn) then StdIn.Free; . 这就是Free已经为您做的。

知道传入的消息是带引号的 Base64 编码字符串，就可以省去 JSON 处理，这样代码就变成了：

procedure WriteSTDInputToFile(const FileName: string);
var
  StdIn: THandleStream;
  MsgLen: Cardinal;
  Msg: RawByteString;
  Data: TBytes;
begin
  StdIn := THandleStream.Create(GetStdHandle(STD_INPUT_HANDLE));
  try
    StdIn.ReadBuffer(MsgLen, SizeOf(MsgLen));
    StdIn.Seek(1, soFromCurrent); { skip double quote }
    SetLength(Msg, MsgLen - 2); { minus leading and trailing double quotes }
    StdIn.ReadBuffer(Msg[Low(Msg)], MsgLen);
    Data := TNetEncoding.Base64.DecodeStringToBytes(UTF8ToString(Msg));
    TFile.WriteAllBytes(FileName, Data);
  finally
    StdIn.Free;
  end;
end;