如何在 Windows 的命令提示符下删除特定目录中的文件/子文件夹

Question

比如说，有一个名为%pathtofolder%的变量，因为它清楚地表明它是文件夹的完整路径。

我想删除此目录中的每个文件和子文件夹，而不是目录本身。

但是，可能会出现“此文件/文件夹已在使用中”之类的错误……发生这种情况时，它应该继续并跳过该文件/文件夹。

有什么命令吗？

Answer 1

rmdir是我一直以来最喜欢的工作命令。 它适用于删除带有子文件夹的大文件和文件夹。 未创建备份，因此请确保在运行此命令之前已安全复制文件。

RMDIR "FOLDERNAME" /S /Q

这会静默删除文件夹以及所有文件和子文件夹。

Answer 2

您可以使用此 shell 脚本来清理C:\Temp source中的文件夹和文件：

del /q "C:\Temp\*"
FOR /D %%p IN ("C:\Temp\*.*") DO rmdir "%%p" /s /q

创建一个包含上述命令的批处理文件（例如，delete.bat）。 进入delete.bat文件所在的位置，然后运行命令：delete.bat

Answer 3

我能想到的最简单的解决方案是删除整个目录

RD /S /Q folderPath

然后再次创建此目录：

MD folderPath

Answer 4

这将删除文件夹和文件并留下文件夹。

pushd "%pathtofolder%" && (rd /s /q "%pathtofolder%" 2>nul & popd)

Answer 5

@ECHO OFF

SET THEDIR=path-to-folder

Echo Deleting all files from %THEDIR%
DEL "%THEDIR%\*" /F /Q /A

Echo Deleting all folders from %THEDIR%
FOR /F "eol=| delims=" %%I in ('dir "%THEDIR%\*" /AD /B 2^>nul') do rd /Q /S "%THEDIR%\%%I"
@ECHO Folder deleted.

EXIT

...删除给定目录下的所有文件和文件夹，但不删除目录本身。

Answer 6

CD [Your_Folder]
RMDIR /S /Q .

您将收到一条错误消息，告诉您 RMDIR 命令无法访问当前文件夹，因此无法删除它。

更新：

从这个有用的评论中（感谢Moritz Both ），您可以在两者之间添加&& ，因此如果CD命令失败（例如，输入错误的目录名称）， RMDIR将不会运行：

CD [Your_Folder] && RMDIR /S /Q .

从Windows 命令行参考：

/S：删除目录树（指定目录及其所有子目录，包括所有文件）。

/Q：指定安静模式。 删除目录树时不提示确认。 （注意 /q 仅在指定 /s 时有效。）

Answer 7

我使用 Powershell

Remove-Item c:\scripts\* -recurse

它将删除文件夹的内容，而不是文件夹本身。

Answer 8

RD 代表删除目录。

/S ：除文件夹本身外，删除所有文件和子文件夹。 使用它来删除整个文件夹树。

/Q : 安静 - 不显示 YN 确认

例子 ：

RD /S /Q C:/folder_path/here

Answer 9

除了foxidrive 发布的单个命令行之外， 2018-06-01上发布的所有答案都没有真正删除%PathToFolder%中的所有文件和所有文件夹/目录。 这就是使用非常简单的单个命令行发布另一个答案以删除文件夹的所有文件和子文件夹以及具有更复杂解决方案的批处理文件的原因，该解决方案解释了为什么使用DEL于 2018 年 6 月 1 日发布的所有其他答案使用RD的FOR无法完全清理文件夹。

---

简单的单命令行解决方案，当然也可以在批处理文件中使用：

pushd "%PathToFolder%" 2>nul && ( rd /Q /S "%PathToFolder%" 2>nul & popd )

该命令行包含三个依次执行的命令。

第一个命令PUSHD将当前目录路径推送到堆栈上，然后使%PathToFolder%成为运行命令进程的当前目录。

这也适用于默认情况下的UNC路径，因为默认情况下会启用命令扩展，在这种情况下， PUSHD创建一个指向该指定网络资源的临时驱动器号，然后使用新定义的驱动器号更改当前驱动器和目录。

如果指定的目录根本不存在， PUSHD会输出以下错误消息来处理STDERR ：

该系统找不到指定的路径。

通过使用2>nul将其重定向到设备NUL来抑制此错误消息。

只有当当前命令进程的当前目录切换到指定目录成功，即指定目录完全存在时，才会执行下一条命令RD 。

带有选项/Q和/S的命令RD会悄悄地删除一个包含所有子目录的目录，即使指定的目录包含具有隐藏属性或只读属性集的文件或文件夹。 系统属性永远不会阻止删除文件或文件夹。

未删除的是：

1. 用作任何正在运行的进程的当前目录的文件夹。 如果文件夹用作任何正在运行的进程的当前目录，则无法删除此类文件夹的整个文件夹树。

2. 当前由任何正在运行的进程打开的文件，在文件打开时设置了文件访问权限，以防止在正在运行的应用程序/进程打开时删除文件。 这种打开的文件还可以防止将整个文件夹树删除到打开的文件中。

3. 当前用户没有删除文件/文件夹所需的 (NTFS) 权限的文件/文件夹，这也阻止了删除该文件/文件夹的文件夹树。

此命令行使用不删除文件夹的第一个原因来删除指定文件夹的所有文件和子文件夹，但不删除文件夹本身。 该文件夹临时成为运行命令进程的当前目录，以防止删除文件夹本身。 当然，这会导致命令RD输出错误消息：

该进程无法访问该文件，因为它正被另一个进程使用。

File在这里是错误的术语，因为实际上该文件夹正在被另一个进程使用，即执行命令RD的当前命令进程。 好吧，实际上文件夹是文件系统的一个特殊文件，具有文件属性目录，它解释了这个错误消息。 但我不想深入研究文件系统管理。

此错误消息与所有其他错误消息一样，可能由于上述三个原因而发生，通过使用2>nul从句柄STDERR重定向到设备NUL来抑制。

第三个命令POPD独立于命令RD的退出值执行。

POPD从堆栈中弹出PUSHD推送的目录路径，并将运行命令进程的当前目录更改为该目录，即恢复初始当前目录。 如果是 UNC 文件夹路径， POPD会删除PUSHD创建的临时驱动器号。

注意：如果初始当前目录是要清理的目录的子目录且不再存在，则POPD可以静默地无法恢复初始当前目录。 在这种特殊情况下， %PathToFolder%仍然是当前目录。 因此，建议不要从%PathToFolder%的子目录运行上面的命令行。

一个更有趣的事实：我尝试了命令行也使用 UNC 路径，通过共享本地目录C:\Temp与共享名称Temp并使用 UNC 路径\\%COMPUTERNAME%\Temp\CleanTest CleanTest 在 Windows 7 上分配给环境变量PathToFolder 。如果运行命令行的当前目录是使用 UNC 路径访问的共享本地文件夹的子目录，即C:\Temp\CleanTest\Subfolder1 ， Subfolder1被RD删除，下一个POPD在制作C:\Temp\CleanTest\Subfolder1默默失败C:\Temp\CleanTest\Subfolder1再次是当前目录，导致Z:\CleanTest保留为正在运行的命令进程的当前目录。 因此，在这种非常非常特殊的情况下，临时驱动器号会一直保留，直到当前目录被更改，例如使用cd /D %SystemRoot%更改为真正存在的本地目录。 不幸的是，如果 POPD 无法恢复初始当前目录，则POPD不会以大于 0 的值退出，因此仅使用POPD的退出代码就无法检测到这种非常特殊的错误情况。 但是，可以假设没有人遇到过这种非常特殊的错误情况，因为 UNC 路径通常不用于访问本地文件和文件夹。

为了更好地理解所使用的命令，请打开命令提示符窗口，在其中执行以下命令，并仔细阅读每个命令显示的帮助。

• pushd /?
• popd /?
• rd /?

使用 Windows 批处理文件的带有多个命令的单行解释了此处使用的运算符&&和& 。

---

接下来让我们看看使用命令DEL删除%PathToFolder%中的文件以及FOR和RD删除%PathToFolder%中的子文件夹的批处理文件解决方案。

@echo off
setlocal EnableExtensions DisableDelayedExpansion

rem Clean the folder for temporary files if environment variable
rem PathToFolder is not defined already outside this batch file.
if not defined PathToFolder set "PathToFolder=%TEMP%"

rem Remove all double quotes from folder path.
set "PathToFolder=%PathToFolder:"=%"

rem Did the folder path consist only of double quotes?
if not defined PathToFolder goto EndCleanFolder

rem Remove a backslash at end of folder path.
if "%PathToFolder:~-1%" == "\" set "PathToFolder=%PathToFolder:~0,-1%"

rem Did the folder path consist only of a backslash (with one or more double quotes)?
if not defined PathToFolder goto EndCleanFolder

rem Delete all files in specified folder including files with hidden
rem or read-only attribute set, except the files currently opened by
rem a running process which prevents deletion of the file while being
rem opened by the application, or on which the current user has not
rem the required permissions to delete the file.
del /A /F /Q "%PathToFolder%\*" >nul 2>nul

rem Delete all subfolders in specified folder including those with hidden
rem attribute set recursive with all files and subfolders, except folders
rem being the current directory of any running process which prevents the
rem deletion of the folder and all folders above, folders containing a file
rem opened by the application which prevents deletion of the file and the
rem entire folder structure to this file, or on which the current user has
rem not the required permissions to delete a folder or file in folder tree
rem to delete.
for /F "eol=| delims=" %%I in ('dir "%PathToFolder%\*" /AD /B 2^>nul') do rd /Q /S "%PathToFolder%\%%I" 2>nul

:EndCleanFolder
endlocal

批处理文件首先确保环境变量PathToFolder真正定义为使用不带双引号且末尾不带反斜杠的文件夹路径。 最后的反斜杠不会有问题，但文件夹路径中的双引号可能会出现问题，因为PathToFolder的值在批处理文件执行期间与其他字符串连接。

重要的是两行：

del /A /F /Q "%PathToFolder%\*" >nul 2>nul
for /F "eol=| delims=" %%I in ('dir "%PathToFolder%\*" /AD /B 2^>nul') do rd /Q /S "%PathToFolder%\%%I" 2>nul

DEL命令用于删除指定目录下的所有文件。

• 选项/A是处理所有文件所必需的，包括具有隐藏属性的文件， DEL在不使用选项/A情况下会忽略这些文件。
• 选项/F是强制删除带有只读属性集的文件所必需的。
• 选项/Q是运行多个文件的安静删除而不提示用户是否应该真正删除多个文件所必需的。
• >nul需要将写入处理STDOUT的文件名的输出重定向到由于当前打开文件或用户无权删除文件而无法删除的设备NUL 。
• 2>nul必须将每个无法从句柄STDERR删除的文件的错误消息输出重定向到设备NUL 。

FOR和RD命令用于删除指定目录中的所有子目录。 但是for /D没有被使用，因为在这种情况下FOR忽略了具有隐藏属性集的子目录。 因此for /F用于在后台使用%ComSpec% /c启动的单独命令进程中运行以下命令行：

dir "%PathToFolder%\*" /AD /B 2>nul

DIR以裸格式输出，因为/B具有属性D的目录条目，即指定目录中所有子目录的名称独立于其他属性，例如没有路径的隐藏属性。 2>nul用于将DIR在找不到从句柄STDERR找到的目录上的错误消息输出重定向到设备NUL 。

重定向运算符>必须在FOR命令行上使用脱字符^进行转义，以便在 Windows 命令解释器在执行命令FOR之前处理此命令行时将其解释为文字字符，该命令以单独的方式执行嵌入的dir命令行命令进程在后台启动。

FOR处理为处理已启动命令进程的STDOUT而写入的捕获输出，这些输出是没有路径的子目录的名称，并且从不包含在双引号中。

带有选项/F的FOR忽略此处不出现的空行，因为带有选项/B的DIR不输出空行。

FOR也会忽略以分号开头的行，这是默认的行尾字符。 目录名称可以以分号开头。 因此， eol=| 用于将竖线字符定义为任何目录或文件的名称中都不能包含的行尾字符。

FOR将使用空格和水平制表符作为分隔符将行拆分为子字符串，并将仅将第一个空格/制表符分隔的字符串分配给指定的循环变量I 。 此处不需要这种拆分行为，因为目录名称可以包含一个或多个空格。 因此delims=用于定义一个空的分隔符列表以禁用行拆分行为并分配给循环变量I ，始终是完整的目录名称。

命令FOR为每个没有路径的目录名称运行命令RD ，这就是为什么在RD命令行上必须再次指定与子文件夹名称连接的文件夹路径的原因。

要了解使用的命令及其工作原理，请打开命令提示符窗口，在其中执行以下命令，并仔细阅读每个命令显示的所有帮助页面。

• del /?
• dir /?
• echo /?
• endlocal /?
• for /?
• goto /?
• if /?
• rd /?
• rem /?
• set /?
• setlocal /?

Answer 10

使用记事本创建文本文档并复制/粘贴：

rmdir /s/q "%temp%"
mkdir "%temp%"

选择另存为和文件名：

delete_temp.bat

保存类型：所有文件，然后单击保存按钮。

它适用于任何类型的帐户（管理员或标准用户）。 运行它！

我在这个例子中使用了一个临时变量，但是你可以使用任何其他的！ PS：仅适用于 Windows 操作系统！

Answer 11

您可以使用以下命令删除所有内容和父文件夹本身：

RMDIR [/S] [/Q] [drive:]path            

Answer 12

要删除文件：

del PATH_TO_FILE

要删除包含所有文件的文件夹：

rmdir /s /q PATH_TO_FOLDER

从特定文件夹中删除所有文件（不删除文件夹本身）有点复杂。 del /s *.*不能删除文件夹，但会从所有子文件夹中删除文件。 所以需要两个命令：

del /q PATH_TO_FOLDER\*.*
for /d %i in (PATH_TO_FOLDER\*.*) do @rmdir /s /q "%i"

Answer 13

@ECHO OFF
rem next line removes all files in temp folder
DEL /A /F /Q /S "%temp%\*.*"
rem next line cleans up the folder's content
FOR /D %%p IN ("%temp%\*.*") DO RD "%%p" /S /Q

Answer 14

我尝试了其中几种方法，但没有一个能正常工作。

我在网站Windows 命令行上找到了这种两步方法：

forfiles /P %pathtofolder% /M * /C "cmd /c if @isdir==FALSE del @file"

forfiles /P %pathtofolder%  /M * /C "cmd /c if @isdir==TRUE rmdir /S /Q @file"

它完全按照我的需要和 OP 的规定工作。

Answer 15

我有以下对我有用的解决方案：

for /R /D %A in (*node_modules*) do rmdir "%A" /S /Q

它从当前目录及其子文件夹中删除所有节点模块文件夹。

这类似于上面发布的解决方案，但我仍然在这里发布，以防有​​人发现它有用

Answer 16

利用：

del %pathtofolder%\*.*   /s /f  /q

这会删除%pathtofolder%中的所有文件和子文件夹，包括只读文件，并且不会提示确认。