在 CMake 中使用预编译的头文件

Question

我在网上看到了一些（旧的）帖子，关于在 CMake 中对预编译头的一些支持进行黑客攻击。 他们似乎都有点无处不在，每个人都有自己的做法。 目前最好的方法是什么？

Answer 1

有一个名为“Cotire”的第三方 CMake 模块，它可以为基于 CMake 的构建系统自动使用预编译头文件，并且还支持统一构建。

Answer 2

我使用以下宏来生成和使用预编译头：

MACRO(ADD_MSVC_PRECOMPILED_HEADER PrecompiledHeader PrecompiledSource SourcesVar)
  IF(MSVC)
    GET_FILENAME_COMPONENT(PrecompiledBasename ${PrecompiledHeader} NAME_WE)
    SET(PrecompiledBinary "${CMAKE_CURRENT_BINARY_DIR}/${PrecompiledBasename}.pch")
    SET(Sources ${${SourcesVar}})

    SET_SOURCE_FILES_PROPERTIES(${PrecompiledSource}
                                PROPERTIES COMPILE_FLAGS "/Yc\"${PrecompiledHeader}\" /Fp\"${PrecompiledBinary}\""
                                           OBJECT_OUTPUTS "${PrecompiledBinary}")
    SET_SOURCE_FILES_PROPERTIES(${Sources}
                                PROPERTIES COMPILE_FLAGS "/Yu\"${PrecompiledHeader}\" /FI\"${PrecompiledHeader}\" /Fp\"${PrecompiledBinary}\""
                                           OBJECT_DEPENDS "${PrecompiledBinary}")  
    # Add precompiled header to SourcesVar
    LIST(APPEND ${SourcesVar} ${PrecompiledSource})
  ENDIF(MSVC)
ENDMACRO(ADD_MSVC_PRECOMPILED_HEADER)

假设您有一个包含所有源文件的变量 ${MySources}，您想要使用的代码就是

ADD_MSVC_PRECOMPILED_HEADER("precompiled.h" "precompiled.cpp" MySources)
ADD_LIBRARY(MyLibrary ${MySources})

该代码在非 MSVC 平台上仍然可以正常运行。 漂亮整齐 ：）

Answer 3

CMake 刚刚获得了对 PCH（预编译头）的支持，它应该会在即将到来的 3.16 版本中可用，由于 2019-10-01：

https://gitlab.kitware.com/cmake/cmake/merge_requests/3553

  target_precompile_headers(<target>
    <INTERFACE|PUBLIC|PRIVATE> [header1...]
    [<INTERFACE|PUBLIC|PRIVATE> [header2...] ...])

正在讨论支持在目标之间共享 PCH： https ://gitlab.kitware.com/cmake/cmake/issues/19659

https://blog.qt.io/blog/2019/08/01/precompiled-headers-and-unity-jumbo-builds-in-upcoming-cmake/提供了一些额外的上下文（动机、数字）

Answer 4

这是一个代码片段，允许您为您的项目使用预编译头。 将以下内容添加到 CMakeLists.txt 中，根据需要替换myprecompiledheaders和myproject_SOURCE_FILES ：

if (MSVC)

    set_source_files_properties(myprecompiledheaders.cpp
        PROPERTIES
        COMPILE_FLAGS "/Ycmyprecompiledheaders.h"
        )
    foreach( src_file ${myproject_SOURCE_FILES} )
        set_source_files_properties(
            ${src_file}
            PROPERTIES
            COMPILE_FLAGS "/Yumyprecompiledheaders.h"
            )
    endforeach( src_file ${myproject_SOURCE_FILES} )
    list(APPEND myproject_SOURCE_FILES myprecompiledheaders.cpp)
endif (MSVC)

Answer 5

我最终使用了 larsm 宏的改编版本。 对 pch 路径使用 $(IntDir) 可以将用于调试和发布版本的预编译头分开。

MACRO(ADD_MSVC_PRECOMPILED_HEADER PrecompiledHeader PrecompiledSource SourcesVar)
  IF(MSVC)
    GET_FILENAME_COMPONENT(PrecompiledBasename ${PrecompiledHeader} NAME_WE)
    SET(PrecompiledBinary "$(IntDir)/${PrecompiledBasename}.pch")
    SET(Sources ${${SourcesVar}})

    SET_SOURCE_FILES_PROPERTIES(${PrecompiledSource}
                                PROPERTIES COMPILE_FLAGS "/Yc\"${PrecompiledHeader}\" /Fp\"${PrecompiledBinary}\""
                                           OBJECT_OUTPUTS "${PrecompiledBinary}")
    SET_SOURCE_FILES_PROPERTIES(${Sources}
                                PROPERTIES COMPILE_FLAGS "/Yu\"${PrecompiledHeader}\" /FI\"${PrecompiledHeader}\" /Fp\"${PrecompiledBinary}\""
                                           OBJECT_DEPENDS "${PrecompiledBinary}")  
    # Add precompiled header to SourcesVar
    LIST(APPEND ${SourcesVar} ${PrecompiledSource})
  ENDIF(MSVC)
ENDMACRO(ADD_MSVC_PRECOMPILED_HEADER)

ADD_MSVC_PRECOMPILED_HEADER("stdafx.h" "stdafx.cpp" MY_SRCS)
ADD_EXECUTABLE(MyApp ${MY_SRCS})

Answer 6

改编自 Dave，但效率更高（设置目标属性，而不是针对每个文件）：

if (MSVC)
   set_target_properties(abc PROPERTIES COMPILE_FLAGS "/Yustd.h")
   set_source_files_properties(std.cpp PROPERTIES COMPILE_FLAGS "/Ycstd.h")
endif(MSVC)

Answer 7

如果您不想重新发明轮子，只需使用 Cotire 作为最佳答案建议或更简单的一个 - cmake-precompiled-header here 。 要使用它，只需包含模块并调用：

include( cmake-precompiled-header/PrecompiledHeader.cmake )
add_precompiled_header( targetName StdAfx.h FORCEINCLUDE SOURCE_CXX StdAfx.cpp )

Answer 8

我在网上看到一些（旧的）帖子，内容涉及一起破解CMake中对预编译标头的一些支持。 他们似乎遍地都是，每个人都有自己的做事方式。 目前最好的方法是什么？

Answer 9

使用 cmake 和 Visual Studio 2015 预编译头的示例

"stdafx.h", "stdafx.cpp" - 预编译的头文件名。

将以下内容放在根 cmake 文件中。

if (MSVC)
    # For precompiled header.
    # Set 
    # "Precompiled Header" to "Use (/Yu)"
    # "Precompiled Header File" to "stdafx.h"
    set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /Yustdafx.h /FIstdafx.h")
endif()

---

将以下内容放入项目 cmake 文件中。

“src” - 包含源文件的文件夹。

set_source_files_properties(src/stdafx.cpp
    PROPERTIES
    COMPILE_FLAGS "/Ycstdafx.h"
)

Answer 10

恕我直言，最好的方法是为整个项目设置 PCH，正如 martjno 建议的那样，并结合在需要时忽略某些源（例如生成的源）的 PCH 的能力：

# set PCH for VS project
function(SET_TARGET_PRECOMPILED_HEADER Target PrecompiledHeader PrecompiledSource)
  if(MSVC)
     SET_TARGET_PROPERTIES(${Target} PROPERTIES COMPILE_FLAGS "/Yu${PrecompiledHeader}")
     set_source_files_properties(${PrecompiledSource} PROPERTIES COMPILE_FLAGS "/Yc${PrecompiledHeader}")
  endif(MSVC)
endfunction(SET_TARGET_PRECOMPILED_HEADER)

# ignore PCH for a specified list of files
function(IGNORE_PRECOMPILED_HEADER SourcesVar)
  if(MSVC)  
    set_source_files_properties(${${SourcesVar}} PROPERTIES COMPILE_FLAGS "/Y-")
  endif(MSVC)
endfunction(IGNORE_PRECOMPILED_HEADER)

因此，如果您有一些目标 MY_TARGET 和生成的源列表 IGNORE_PCH_SRC_LIST，您只需执行以下操作：

SET_TARGET_PRECOMPILED_HEADER(MY_TARGET stdafx.h stdafx.cpp)
IGNORE_PRECOMPILED_HEADER(IGNORE_PCH_SRC_LIST)

这种方法已经过测试并且运行良好。

Answer 11

最干净的方法是将预编译选项添加为全局选项。 在 vcxproj 文件中，这将显示为<PrecompiledHeader>Use</PrecompiledHeader>而不是对每个单独的文件都这样做。

然后您需要将Create选项添加到 StdAfx.cpp。 以下是我如何使用它：

MACRO(ADD_MSVC_PRECOMPILED_HEADER SourcesVar)
    SET(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /YuStdAfx.h")
    set_source_files_properties(StdAfx.cpp
        PROPERTIES
        COMPILE_FLAGS "/YcStdAfx.h"
        )
    list(APPEND ${${SourcesVar}} StdAfx.cpp)
ENDMACRO(ADD_MSVC_PRECOMPILED_HEADER)

file(GLOB_RECURSE MYDLL_SRC
    "*.h"
    "*.cpp"
    "*.rc")

ADD_MSVC_PRECOMPILED_HEADER(MYDLL_SRC)
add_library(MyDll SHARED ${MYDLL_SRC})

这已经过测试并适用于 MSVC 2010 并将创建一个 MyDll.pch 文件，我不关心使用什么文件名，所以我没有努力指定它。

Answer 12

由于预编译头选项不适用于 rc 文件，我需要调整 jari 提供的宏。

#######################################################################
# Makro for precompiled header
#######################################################################
MACRO(ADD_MSVC_PRECOMPILED_HEADER PrecompiledHeader PrecompiledSource SourcesVar)
  IF(MSVC)
    GET_FILENAME_COMPONENT(PrecompiledBasename ${PrecompiledHeader} NAME_WE)
    SET(PrecompiledBinary "$(IntDir)/${PrecompiledBasename}.pch")
    SET(Sources ${${SourcesVar}})

    # generate the precompiled header
    SET_SOURCE_FILES_PROPERTIES(${PrecompiledSource}
                                PROPERTIES COMPILE_FLAGS "/Zm500 /Yc\"${PrecompiledHeader}\" /Fp\"${PrecompiledBinary}\""
                                            OBJECT_OUTPUTS "${PrecompiledBinary}")

    # set the usage of this header only to the other files than rc
    FOREACH(fname ${Sources})
        IF ( NOT ${fname} MATCHES ".*rc$" )
            SET_SOURCE_FILES_PROPERTIES(${fname}
                                        PROPERTIES COMPILE_FLAGS "/Zm500 /Yu\"${PrecompiledHeader}\" /FI\"${PrecompiledHeader}\" /Fp\"${PrecompiledBinary}\""
                                                    OBJECT_DEPENDS "${PrecompiledBinary}")
        ENDIF( NOT ${fname} MATCHES ".*rc$" )
    ENDFOREACH(fname)

    # Add precompiled header to SourcesVar
    LIST(APPEND ${SourcesVar} ${PrecompiledSource})
  ENDIF(MSVC)
ENDMACRO(ADD_MSVC_PRECOMPILED_HEADER)

编辑：使用这个预编译头文件将我的主项目的总体构建时间从 4 分 30 秒减少到 1 分 40 秒。 这对我来说真的是一件好事。 在预编译头文件中只有像 boost/stl/Windows/mfc 这样的头文件。

Answer 13

好吧，当您每次更改任何项目文件中的一行时，在四核机器上构建需要 10 分钟以上时，它会告诉您是时候为 Windows 添加预编译头文件了。 在 *nux 上，我只会使用 ccache 而不必担心。

我已经在我的主应用程序和它使用的一些库中实现了。 在这一点上它工作得很好。 还需要做的一件事是您必须创建 pch 源文件和头文件，并在源文件中包含所有要预编译的头文件。 我用 MFC 这样做了 12 年，但我花了几分钟才回忆起来。

Answer 14

甚至不要去那里。 预编译头意味着只要其中一个头发生变化，您就必须重建所有内容。 如果你有一个实现这一点的构建系统，你就很幸运了。 通常情况下，您的构建会失败，直到您意识到您更改了正在预编译的内容，因此您需要进行完整的重建。 您可以通过预编译您绝对肯定不会改变的标头来避免这种情况，但是您也放弃了大部分速度增益。

另一个问题是，在许多使用预编译头文件的地方，您的命名空间被各种您不知道或不关心的符号所污染。