將stdin / stdout從exec'ed進程重定向到Perl中的pipe

Question

我試圖讓一個exec的子進程的STDOUT / STDERR通過Perl中的管道返回到父進程。 我所看到的最接近我想做的是： http ： //forums.devshed.com/perl-programming-6/exec-and-redirecting-stdout-stderr-168501.html

以下是我想要做的事情的簡要示例。 我也試過上面鏈接的一個變種。 我看不出我做錯了什么......

#!/usr/bin/env perl

use strict ;
use warnings ;

my $cmd    = "/usr/bin/who -a" ;  # anything to stdout

pipe( READER, WRITER ) ;
my $child = fork() ;
if ( $child ) {
    print "I am the parent: My pid = $$ junior = $child\n" ;
    close( WRITER ) ;
    my @output = <READER> ;
    print @output ;
    print "parent is DONE\n" ;
} else {
    print "I am the child. My pid = $$\n" ;

    close( READER ) ;
    close( STDOUT );
    close( STDERR );
    *STDOUT = *WRITER ;
    *STDERR = *WRITER ;

    print WRITER "XXX ouput before exec....\n" ;

    exec( $cmd ) or exit(1) ;
}

Answer 1

僅使用賦值重定向文件描述符是不可能的。 而是一個需要使用open像中描述perldoc -f open 。 在您的情況下，子代碼將如下所示：

    print "I am the child. My pid = $$\n" ;

    close( READER ) ;

    open STDOUT, ">&", \*WRITER or die $!;
    open STDERR, ">&", \*WRITER or die $!;

    print WRITER "XXX ouput before exec....\n" ;

    exec( $cmd ) or exit(1) ;

Answer 2

Slaven Rezic對你的代碼無效的原因有正確的答案，但你也應該知道你可以使用的快捷方式。 特殊管+叉open READER, '-|' 幾乎所有的設置都適合你，創建一個子進程，其STDOUT寫入一個父可以用READER讀取的管道。 這只是讓STDERR重定向讓你手動完成。

縮短版本的代碼如下所示：

my $child = open READER, '-|';
defined $child or die "pipe/fork: $!\n";
if ( $child ) {
    print "I am the parent: My pid = $$ junior = $child\n" ;
    my @output = <READER> ;
    print @output ;
    print "parent is DONE\n" ;
} else {
    print "I am the child. My pid = $$\n" ;

    open STDERR, '>&STDOUT';

    print "XXX ouput before exec....\n" ;

    exec( $cmd ) or exit(1) ;
}

Answer 3

此代碼是從子進程管道STDOUT和STDERR的另一種方法。

 #!/usr/bin/env perl
 use strict ;
 use warnings;

 my $cmd    = "/usr/bin/who -a" ;  # anything to stdout

 pipe( READER, WRITER ) ;
 my $child = fork() ;
if ( $child ) {
    print "I am the parent: My pid = $$ junior = $child\n" ;
    close( WRITER ) ;
    my @output = <READER> ;
    print @output ;
    print "parent is DONE\n" ;
} else {
    print "I am the child. My pid = $$\n" ;
    close( READER ) ;
    open(STDERR,">&", WRITER) or die "Cannot duplicate STDERR;
    open(STDOUT,">&", WRITER) or die "cannot duplicate STDOUT";

    print WRITER "XXX ouput before exec....\n" ;

   exec( $cmd ) or exit(1) ;

}