使用RTTS從內部表為字段創建范圍

Question

我想創建一個接受2個參數的函數/自定義類方法：

1）IM_ITAB類型ANY TABLE

2）IM_COMPONENT類型STRING

並返回1個參數：

1）EX_RANGE類型PIQ_SELOPT_T

所以，算法是這樣的：

• 首先，我們檢查一下組件名稱是否全部存在的列
• 然后，我們檢查內部表是否為空。
• 然后，我們遍歷內部表分配組件和填充范圍表。 代碼如下。

METHODS compose_range_from_itab
    IMPORTING 
      IM_ITAB      type ANY TABLE
      IM_COMPONENT type STRING
    EXPORTING
      EX_RANGE     type PIQ_SELOPT_T.
...
METHOD compose_range_from_itab.

  DATA: lo_obj   TYPE REF TO cl_abap_tabledescr,
        wa_range TYPE selopt,
        lt_range TYPE piq_selopt_t.

  FIELD-SYMBOLS: <fs_line> TYPE ANY,
                 <fs_component> TYPE ANY.

  lo_obj ?= cl_abap_typedescr=>describe_by_data( p_data = im_itab ).

  READ TABLE lo_obj->key TRANSPORTING NO FIELDS WITH KEY name = im_component.

  IF sy-subrc IS INITIAL.

    IF LINES( im_itab ) GT 0.

      LOOP AT im_itab ASSIGNING <fs_line>.

        ASSIGN COMPONENT im_component OF STRUCTURE <fs_line> TO <fs_component>.

        wa_range-sign = 'I'.
        wa_range-option = 'EQ'.
        wa_range-low = <fs_component>.

        APPEND wa_range TO lt_range.

      ENDLOOP.

      SORT lt_range BY low.
      DELETE ADJACENT DUPLICATES FROM lt_range COMPARING low.

      ex_range[] = lt_range[].

    ENDIF.

  ENDIF.

ENDMETHOD.

但我想進一步改進該方法。 如果導入的內部表有255列，則遍歷該表將花費更長的時間。 但是我只需要一列即可組成范圍。

因此，我想獲取內部表的組件，然后僅選擇一個組件，創建僅包含該組件的新線型，然后使用該線型創建內部表並進行復制。

這是與我想要實現的相對應的偽代碼：

append corresponding fields of im_itab into new_line_type_internal_table.

如何使用RTTS“裁剪”一個組件並創建新的線型？

Answer 1

您使所有事情變得過於復雜，不需要RTTS。

DEFINE make_range.
  ex_range = VALUE #( BASE ex_range ( sign = 'I' option = 'EQ' low = &1 ) ).
END-OF-DEFINITION.

LOOP AT im_itab ASSIGNING FIELD-SYMBOL(<fs_line>).
  ASSIGN COMPONENT im_component OF STRUCTURE <fs_line> TO FIELD-SYMBOL(<fs_field>).
  CHECK sy-subrc = 0 AND <fs_field> IS NOT INITIAL.
  make_range <fs_field>.
ENDLOOP.

是的，正如Sandra所說，使用RTTS不會獲得任何性能，相反。

Answer 2

令人驚訝的是，這種變體更快：

CLASS-METHODS make_range_variant_2
  IMPORTING
    sample        TYPE table_type
    column        TYPE string
  RETURNING
    VALUE(result) TYPE range_type.

METHOD make_range_variant_2.

  TYPES:
    BEGIN OF narrow_structure_type,
      content TYPE char32,
    END OF narrow_structure_type.

  TYPES narrow_table_type TYPE STANDARD TABLE OF narrow_structure_type WITH EMPTY KEY.

  DATA narrow_table TYPE narrow_table_type.

  DATA(mapping) =
    VALUE cl_abap_corresponding=>mapping_table_value(
      ( kind = cl_abap_corresponding=>mapping_component srcname = column dstname = 'CONTENT' ) ).

  DATA(mover) =
    cl_abap_corresponding=>create_with_value(
      source      = sample
      destination = narrow_table
      mapping     = mapping ).

  mover->execute(
    EXPORTING
      source      = sample
    CHANGING
      destination = narrow_table ).

  LOOP AT narrow_table ASSIGNING FIELD-SYMBOL(<row>).

    INSERT VALUE #(
        sign   = 'I'
        option = 'EQ'
        low    = <row>-content )
      INTO TABLE result.

  ENDLOOP.

ENDMETHOD.

CL_ABAP_CORRESPONDING委托一個內核函數來進行結構到結構的移動，這顯然快於ABAP原生的將結構ASSIGN COMPONENT [...] OF STRUCTURE [...] TO FIELD-SYMBOL [...] CL_ABAP_CORRESPONDING ASSIGN COMPONENT [...] OF STRUCTURE [...] TO FIELD-SYMBOL [...] 這樣，實際循環似乎會更快，因為它使用了固定名稱分配。

也許有人可以驗證。

Answer 3

我不會去Macro 。

Data:
      lr_data type ref to data.

FIELD-SYMBOLS:
      <lv_component> TYPE any,
      <ls_data> TYPE any.

CREATE DATA lr_data LIKE LINE OF im_itab.
ASSIGN lr_data->* TO <ls_data>.

"Check whether im_component exists
ASSIGN COMPONENT im_component OF STRUCTURE <ls_data> TO <lv_component>.

CHECK sy-subrc EQ 0.

LOOP AT im_itab INTO <ls_data>.
  APPEND VALUE #( sign = 'I' option = 'EQ' low = <lv_component> ) TO ex_range.
ENDLOOP.