在 Prolog 中实现顶点覆盖

Question

I am trying to implement vertex covering in prolog. I was thinking of doing following:

Use graph in following format [(VertexSouce/VertexDest), ...] and pass a number of total vertices in the graph. So the predicate would look like this vertexCover(NodeCount, Graph, MaxNodesInResult, Result) . Result should be less than MaxNodesInResult`

I was given following example output:

?- vertexCover(6,[(1/2),(1/3),(2/3),(2/4),(3/5),(4/5),(4/6)],3,L).
L = [1,3,4] ;
L = [2,3,4] ;
false.
?- vertexCover(6,[(1/2),(1/3),(2/3),(2/4),(3/5),(4/5),(4/6)],2,L).
false.

Any help appreciated!

Answer 1

This should really be a comment on the correct solution by Dartuso, but it won't fit. So here it is as an alternative answer. Using Dartuso's code, you get duplicate answers:

?- vertexCover(6,[(1/2),(1/3),(2/3),(2/4),(3/5),(4/5),(4/6)],3,L).
L = [1, 3, 4] ;
L = [1, 3, 4] ;
L = [2, 3, 4] ;
L = [2, 3, 4] ;
L = [2, 3, 4] ;
L = [2, 3, 4] ;
false.

There is nothing wrong with getting dupicate answers. But sometimes we would like to avoid them for reasons of performance or simply to get nicer output.

In this case the duplication comes from the fact that a single edge can occur in a cover in several ways:

?- isIn([1, 3], (1/3)).
true ;
true ;
false.

This is because the clauses of isIn/2 as given by Dartuso are not mutually exclusive. Both the first and the second clause match this query, which is why you get two successes.

There are several ways to "fix" this. The cleanest one is to add conditions to exclude cases already covered by previous clauses:

isIn([A|_],(X/_)) :-
    A = X.
isIn([A|_],(X/Y)) :-
    dif(A, X),
    A = Y.
isIn([A|T],(X/Y)) :-
    dif(A, X),
    dif(A, Y),
    isIn(T,(X/Y)).

Here the dif/2 predicate expresses disequality. So the second clause can no longer succeed in cases already covered by the equality in the first clause, and this eliminates the duplicate success and the duplicate answer:

?- isIn([1, 3], (1/3)).
true ;
false.

?- vertexCover(6,[(1/2),(1/3),(2/3),(2/4),(3/5),(4/5),(4/6)],3,L).
L = [1, 3, 4] ;
L = [2, 3, 4] ;
false.

A somewhat less nice solution uses the "if-then-else" construct Condition -> TrueBranch ; FalseBranch Condition -> TrueBranch ; FalseBranch which is not unproblematic (but so very practical!):

isIn([A|T],(X/Y)) :-
    (   A = X
    ->  true
    ;   A = Y
    ->  true
    ;   isIn(T, (X/Y)) ).

Or, as I might write this in practice:

isIn([A|T],(X/Y)) :-
    (   ( A = X ; A = Y )
    ->  true
    ;   isIn(T, (X/Y)) ).

With this latter solution the query above only succeeds once and doesn't even leave a choice point:

?- isIn([1, 3], (1/3)).
true.

And with this the overall predicate no longer has duplicate answers either:

?- vertexCover(6,[(1/2),(1/3),(2/3),(2/4),(3/5),(4/5),(4/6)],3,L).
L = [1, 3, 4] ;
L = [2, 3, 4] ;
false.

In this particular case the if-then-else only cuts away unwanted duplicate solutions, but in general it can eliminate solutions you did want. Use with care.

(Others might tell you to use the cut operator !/0 because it's shorter than some of these solutions. Do not give in. Shorter code is not automatically better code, and the cut makes your code especially complicated and hard to understand and to modify.)

Answer 2

Here is a working solution, thanks to Isabelle for the fix! As she mentioned another solution I found was to add a cut on the second line of covers/2 but her solution is much more clear.

vertexCover(N,L1,M,L2) :- numlist(1, N, L), comb(M,L,L2), covers(L2,L1).

covers(_,[]).
covers(L,[H|T]) :- isIn(L,H), covers(L,T).

isIn([A|T],(X/Y)) :-  (( A = X ; A = Y ) -> true
                       ;   isIn(T, (X/Y)) ).

comb(0,_,[]).
comb(N,[X|T],[X|Comb]):-    N>0,N1 is N-1,comb(N1,T,Comb).
comb(N,[_|T],Comb):-        N>0,comb(N,T,Comb).