使用if命令计算状态差异

Question

I want to calculate something like

by group: egen x if y==1 - x if y==2

Of course this is not a real stata code but I'm kind of lost. In R this is simply passed by a "[]" behind the variable of intrest but I'm not sure about stata

R would be

x[y==1] - x[y==2]

Answer 1

I would use reshape .

clear
version 11.2
set seed 2001

* generate data
set obs 100
generate y = 1 + mod(_n - 1, 2)
generate x = rnormal()
generate group = 1 + floor((_n - 1) / 2)
list in 1/10

* reshape to wide and difference
reshape wide x, i(group) j(y)
generate x_diff = x1 - x2
list in 1/5

I would use reshape in R, also. Otherwise can you be sure that everything is properly ordered to give you the difference you want?

There is likely a neat Mata solution, but I know very little Mata. You may find preserve and restore helpful if you're averse to reshape ing.

Answer 2

Richard Herron makes a good point that a reshape to a different structure might be worthwhile. Here I focus on how to do it with the existing structure.

Assuming that there are precisely two observations for each group of group , one with y == 1 and one with y == 2 , then

bysort group (y) : gen diff = x[1] - x[2] 

gives the difference between values of x , necessarily repeated for each observation of two in a group. An assumption-free method is

bysort group: egen mean_1 = mean(x / (y == 1)) 
by group: egen mean_2 = mean(x / (y == 2)) 
gen diff = mean_1 - mean_2 

Consider expressions such as x / (y == 1) . Here the denominator y == 1 is 1 when y is indeed 1 and 0 otherwise. Division by 0 yields missing in Stata, but the egen command here ignores those. So the first command of the three commands above yields the mean of x for observations for which y == 1 and the second the mean of x for observations for which y == 2 . Other values of y (even missings) will be ignored. This method should agree with the first method when the first method is valid.

For a review of similar problems, see http://stata-journal.com/article.html?article=dm0055

In Stata the if referred to here is a qualifier (not a command).