Haskell: Syntax for manipulating a list of lists

Question

I am having trouble finding the correct syntax for manipulating a list of lists.

Here's what I have

> sumLsts :: [[a]] -> [[a]] -> [[a]]
> sumLsts [[]] [[]] = [[]]
> sumLsts [(x:xs):tx] [(y:ys):ty] = [((+) x y) : sumLsts xs ys] : sumLsts tx ty

Here's sample input and output

> sumLsts [[1,1,1], [1,10,20], [-3, -4, -2]] [[3,5,6],[2,3,4],[2,3,2]]
> [[4,6,7],[3,13,24],[-1,-1,0]]

I was thinking that [(x:xs):tx] would have (x:xs) be seen as a single list and tx be seen as the following list. Haskell doesn't seem to agree.

Here is the error message

Couldn't match expected type 'a' with actual type '[[a0]]'
'a' is a rigid type variable bound by
   the type signature for:
      sumLsts :: forall a. [[a]] -> [[a]] -> [[a]]
In the pattern: x : xs
In the pattern: (x : xs) : tx
In the pattern [(x : xs) : tx]
Relevant bindings include
   sumLsts :: [[a]] -> [[a]] -> [[a]]

Answer 1

As is pointed out in the comments on the question, (x:xs) is the pattern for an object of type [a] , whether the a there is Int , String , Bool , or even [a] itself like [Int] .

In this case your pattern match should be:

sumLsts ((x:xs):tx) ((y:ys):ty) = ...
{- to [[1, 3, 6], [2, 4, 7], [3, 5, 8]], ((x:xs): tx) matches:
   x  = 1
   xs = [3, 6]
   tx = [[2, 4, 7], [3, 5, 8]]
-}

However do note that your function is just:

sumLsts = zipWith (zipWith (+))

zipWith pairs two lists together with a joining function, such that

zipWith f [x1, x2, ..., xn] [y1, y2, ..., yn] =
  [ f x1 y1
  , f x2 y2
  , ...
  , f xn yn ]

In this case, your outer two lists get paired together so each sublist is an x and y . You're trying to pair those together with addition, so f is another zipWith , this time zipWith (+)

zipWith (zipWith (+)) [[1,1,1], [1,10,20], [-3, -4, -2]] [[3,5,6],[2,3,4],[2,3,2]]

= [ [ 1,  1,  1] `zipWith (+)` [3, 5, 6]
  , [ 1, 10, 20] `zipWith (+)` [2, 3, 4]
  , [-3, -4, -2] `zipWith (+)` [2, 3, 2]]

= [ [  1 + 3
    ,  1 + 5
    ,  1 + 6]
  , [  1 + 2
    , 10 + 3
    , 20 + 4]
  , [ -3 + 2
    , -4 + 3
    , -2 + 2] ]