How can I convert a bitmap to pure black and white with OpenCL

Question

I've got a WPF - C# project and I'm trying to speed up the image processing I'm doing in there; by doing it using OpenCL and Cloo.

I did manage to get a kernel working that can change a bitmap to grayscale, but for some reason the black and white kernel I've made only outputs a completely black image.

Here's my kernel .cl code:

kernel void ConvertToBlackAndWhite(read_only image2d_t sourceImage, write_only image2d_t outputImage, float threshold)
{
    const sampler_t mainSampler = CLK_NORMALIZED_COORDS_FALSE | CLK_ADDRESS_CLAMP_TO_EDGE | CLK_FILTER_LINEAR;

    int2 position = (int2)(get_global_id(0), get_global_id(1));
    float4 pixel = read_imagef(sourceImage, mainSampler, position);

    float grayValue = (0.299 * pixel.z) + (0.587 * pixel.y) + (0.114 * pixel.x); // Get Grayscale Value

    const float thresholdValue = threshold * 255.0;

    if (grayValue > thresholdValue)
    {
        const float4 white = (float4){ 255.0, 255.0, 255.0, 255.0 }; // #FFFFFF
        write_imagef(outputImage, position, white);
    }
    else
    {
        const float4 black = (float4){ 0.0, 0.0, 0.0, 255.0 }; // #000000
        write_imagef(outputImage, position, black);
    }
}

Where am I going wrong?

Any help or tips will be appreciated.

I've updated my kernel code based on @ProjectPhysX's helpful advice:

kernel void ConvertToBlackAndWhite(read_only image2d_t sourceImage, write_only image2d_t outputImage, float threshold)
{
    const sampler_t mainSampler = CLK_NORMALIZED_COORDS_FALSE | CLK_ADDRESS_CLAMP_TO_EDGE | CLK_FILTER_LINEAR;

    int2 position = (int2)(get_global_id(0), get_global_id(1));
    float4 pixel = read_imagef(sourceImage, mainSampler, position);

    float grayValue = (0.299f * pixel.z) + (0.587f * pixel.y) + (0.114f * pixel.x); // Get Grayscale Value
    if (grayValue > threshold)
    {
        const float4 white = (float4){ 1.0f, 1.0f, 1.0f, 1.0f }; // #FFFFFF
        write_imagef(outputImage, position, white);
    }
    else
    {
        const float4 black = (float4){ 0.0f, 0.0f, 0.0f, 1.0f }; // #000000
        write_imagef(outputImage, position, black);
    }
}

Here's the C# that adds the images into OpenCL image memory buffers:

...

// Allocate OpenCL Image Memory Buffer
inputImage2DBuffer = Cl.CreateImage2D(GPUManipulation.OpenCLContext, MemFlags.CopyHostPtr | MemFlags.ReadOnly, imageFormat,
                                     (IntPtr)width, (IntPtr)height,
                                     (IntPtr)ConstantsMain.Int0, inputByteArray, out error);

...

// Allocate OpenCL image memory buffer
IMem outputImage2DBuffer = Cl.CreateImage2D(GPUManipulation.OpenCLContext, MemFlags.CopyHostPtr | MemFlags.WriteOnly, imageFormat,
                                            (IntPtr)width, (IntPtr)height, (IntPtr)ConstantsMain.Int0, outputByteArray, out error);

...

Answer 1

read_imagef returns color/alpha values in the range [0.0f, 1.0f] and not [0.0f, 255.0f] . This means you have to set:

const float thresholdValue = threshold; // do not multiply by 255.0f here
const float4 white = (float4){ 1.0f, 1.0f, 1.0f, 1.0f }; // #FFFFFF
const float4 black = (float4){ 0.0f, 0.0f, 0.0f, 1.0f }; // #000000

The reason everything was black before was that no grayValue (in the range [0.0f, 1.0f] ) could possibly be larger than thresholdValue (in the order of 0.5f*255.0f ).