Is there an equivalent to creating a C# implicit operator in F#?

Question

In C# I can add implicit operators to a class as follows:

public class MyClass
{
    private int data;

    public static implicit operator MyClass(int i)
    {
        return new MyClass { data = i };
    }

    public static implicit operator MyClass(string s)
    {
        int result;

        if (int.TryParse(s, out result))
        {
            return new MyClass { data = result };
        }
        else
        {
            return new MyClass { data = 999 };
        }
    }

    public override string ToString()
    {
        return data.ToString();
    }
}

Then I can pass any function that is expecting a MyClass object a string or an int. eg

public static string Get(MyClass c)
{
    return c.ToString();
}

static void Main(string[] args)
{
    string s1 = Get(21);
    string s2 = Get("hello");
    string s3 = Get("23");
}

Is there a way of doing this in F#?

Answer 1

As others have pointed out, there is no way to do implicit conversion in F#. However, you could always create your own operator to make it a bit easier to explicitly convert things (and to reuse any op_Implicit definitions that existing classes have defined):

let inline (!>) (x:^a) : ^b = ((^a or ^b) : (static member op_Implicit : ^a -> ^b) x)

Then you can use it like this:

type A() = class end
type B() = static member op_Implicit(a:A) = B()

let myfn (b : B) = "result"

(* apply the implicit conversion to an A using our operator, then call the function *)
myfn (!> A())

Answer 2

隐式转换在类型安全和类型推断方面相当成问题，所以答案是：不，它实际上是一个有问题的特性。

Answer 3

不，那里没有。

Answer 4

On a related note, it is possible to add implicit or explicit static members so C# can use them.

type Country =
| NotSpecified
| England
| Wales
| Scotland
| NorthernIreland
 with static member op_Implicit(c:Country) = 
   match c with | NotSpecified    -> 0
                | England         -> 1
                | Wales           -> 2
                | Scotland        -> 3
                | NorthernIreland -> 4

This allows ac# user to use (int) Wales for example

Answer 5

As of F#6, there is now support for op_Implicit as long as the resolution is type-directed and clear eg

let x : System.Nullable<int> = 10 // valid in F#6

let doStuff (x:System.Nullable<int>) = ()
doStuff 10 // valid in F#6

type Foo() =
    static member X (x:System.Nullable<int>) = ()
Foo.X 10 // valid in F#6

Note that the first two example will give a warning (FS3391) which can be turned off.

Answer 6

您可以像这样调用操作员：

let casted = TargetClass.op_Implicit sourceObject

Answer 7

Thanks to @isaac-abraham and @kvb. I condensed their answers and built my typesafe ids, using implicit constructors that the op asked for:

type UserId =
  { id: string } // underlying, could be int or so as well
  static member op_Implicit(id:string) = { id = id }
  override r.ToString() = r.id

type ProductId =
  { id: string }
  static member op_Implicit(id:string) = { id = id }
  override r.ToString() = r.id

let id1 : UserId = "p1"
let id2 : UserId = "p1"
let id3 : UserId = "p2"
id1 = id2 // true
id1 = id3 // false
let pid1 : ProductId = "p1"
id1 = pid1 // type error, not comparable -> excellent, thats what this is for

Using records gives structural equality and even comparison works:

id3 > id1 // true
id3 < id1 // false