Perl count the sum of one column aggregating by another

Question

I have a dataset will a lot of columns. What I need to do is to sum a aggregate a certain column in terms of another. As an example,

ID       Volume
A          20
D          60
B          10
A          50
K          30 
B          100
D          80 

So I want an aggregated sum of all the different IDs (A, B, C...) in terms of volumes and sorted by that sum

The result would be like

D           140
B           110
A           70
K           30

how would I accomplish this in perl?

Answer 1

  #!/usr/bin/perl

  use strict;
  use warnings;

  my %ids_and_sums;

  while (<>) {
     # The regex will only consider one single uppercase letter as
     # an ID; in case your IDs may look different, you could prepend
     # your 'ID  Volume' line with a character which will never be part
     # of an ID, and modify below regex to meet your needs
     my ($id, $volume) = m/^([A-Z])\s+(\d+)/;

     if ($id and $volume) {
        $ids_and_sums{$id} += $volume;
     }
  }

  foreach my $key (sort {$ids_and_sums{$b} <=> $ids_and_sums{$a}} keys %ids_and_sums) {
     print "$key: $ids_and_sums{$key}\n";
  }

This prints:

D: 140
B: 110
A: 70
K: 30

EDIT: I have modified the code so that the sorting will be in descending order of the sums.

Answer 2

You can do it as:

perl -lnae '$H{$F[0]} += $F[1];END { print $_." ".$H{$_} for(keys %H) }'

passing it all but the first line of your input file as standard input.

Ideone Link

You can make Perl discard the heading line as:

perl -lnae 'BEGIN{$i=1;}if($i){$i=0;next;}$H{$F[0]} += $F[1];END { print $_." ".$H{$_ } for(keys %H)  }' file

Ideone Link

Answer 3

$, = ' ';   # set output field separator
$\ = "\n";    # set output record separator

while (<>) {
    ($Fld1,$Fld2) = split(' ', $_, -1);
    $map{$Fld1} += $Fld2;
}

foreach $i (keys %map) {
    print $i, $map{$i};
}

something like this