使用Cython包装LAPACKE函数

Question

我正在尝试使用Cython包装LAPACK函数dgtsv （方程的三对角线系统的求解器）。

我遇到了这个先前的答案 ，但是由于dgtsv不是dgtsv中包装的LAPACK函数之一， scipy.linalg我认为我不能使用这种特殊方法。 相反，我一直在尝试遵循此示例 。

这是我的lapacke.pxd文件的内容：

ctypedef int lapack_int

cdef extern from "lapacke.h" nogil:

    int LAPACK_ROW_MAJOR
    int LAPACK_COL_MAJOR

    lapack_int LAPACKE_dgtsv(int matrix_order,
                             lapack_int n,
                             lapack_int nrhs,
                             double * dl,
                             double * d,
                             double * du,
                             double * b,
                             lapack_int ldb)

......这里是我的薄用Cython包装_solvers.pyx ：

#!python

cimport cython
from lapacke cimport *

cpdef TDMA_lapacke(double[::1] DL, double[::1] D, double[::1] DU,
                   double[:, ::1] B):

    cdef:
        lapack_int n = D.shape[0]
        lapack_int nrhs = B.shape[1]
        lapack_int ldb = B.shape[0]
        double * dl = &DL[0]
        double * d = &D[0]
        double * du = &DU[0]
        double * b = &B[0, 0]
        lapack_int info

    info = LAPACKE_dgtsv(LAPACK_ROW_MAJOR, n, nrhs, dl, d, du, b, ldb)

    return info

...这是一个Python包装器和测试脚本：

import numpy as np
from scipy import sparse
from cymodules import _solvers


def trisolve_lapacke(dl, d, du, b, inplace=False):

    if (dl.shape[0] != du.shape[0] or dl.shape[0] != d.shape[0] - 1
            or b.shape != d.shape):
        raise ValueError('Invalid diagonal shapes')

    if b.ndim == 1:
        # b is (LDB, NRHS)
        b = b[:, None]

    # be sure to force a copy of d and b if we're not solving in place
    if not inplace:
        d = d.copy()
        b = b.copy()

    # this may also force copies if arrays are improperly typed/noncontiguous
    dl, d, du, b = (np.ascontiguousarray(v, dtype=np.float64)
                    for v in (dl, d, du, b))

    # b will now be modified in place to contain the solution
    info = _solvers.TDMA_lapacke(dl, d, du, b)
    print info

    return b.ravel()


def test_trisolve(n=20000):

    dl = np.random.randn(n - 1)
    d = np.random.randn(n)
    du = np.random.randn(n - 1)

    M = sparse.diags((dl, d, du), (-1, 0, 1), format='csc')
    x = np.random.randn(n)
    b = M.dot(x)

    x_hat = trisolve_lapacke(dl, d, du, b)

    print "||x - x_hat|| = ", np.linalg.norm(x - x_hat)

不幸的是， test_trisolve只是对_solvers.TDMA_lapacke的调用存在段_solvers.TDMA_lapacke 。 我很确定我的setup.py是正确的ldd _solvers.so显示_solvers.so在运行时被链接到正确的共享库。

我不太确定如何从这里开始-有什么想法吗？

---

简要更新 ：

对于较小的n值，我倾向于不会立即得到段错误，但我确实会得到无意义的结果（ || x-x_hat ||应该非常接近0）：

In [28]: test_trisolve2.test_trisolve(10)
0
||x - x_hat|| =  6.23202576396

In [29]: test_trisolve2.test_trisolve(10)
-7
||x - x_hat|| =  3.88623414288

In [30]: test_trisolve2.test_trisolve(10)
0
||x - x_hat|| =  2.60190676562

In [31]: test_trisolve2.test_trisolve(10)
0
||x - x_hat|| =  3.86631743386

In [32]: test_trisolve2.test_trisolve(10)
Segmentation fault

通常， LAPACKE_dgtsv返回的代码为0 （应该表示成功），但偶尔我会得到-7 ，这意味着参数7（ b ）具有非法值。 实际情况是，实际上只有b的第一个值被修改了。 如果我继续调用test_trisolve即使n很小，我最终也会遇到段错误。

Answer 1

好的，我最终弄清楚了-在这种情况下，我似乎误解了行和列的主要含义。

由于C-连续阵列遵循行优先次序，我认为我应该指定LAPACK_ROW_MAJOR作为第一个参数LAPACKE_dgtsv 。

事实上，如果我改变

info = LAPACKE_dgtsv(LAPACK_ROW_MAJOR, ...)

至

info = LAPACKE_dgtsv(LAPACK_COL_MAJOR, ...)

然后我的功能工作：

test_trisolve2.test_trisolve()
0
||x - x_hat|| =  6.67064747632e-12

这对我来说似乎很违反直觉-有人可以解释为什么会这样吗？

Answer 2

尽管这个问题很老了，但这个问题似乎仍然很重要。 观察到的行为是对参数LDB的错误解释的结果：

• Fortran数组是col major，并且数组B的前导维对应于N。因此LDB> = max（1，N）。
• 对于主行，LDB对应于NRHS，因此必须满足LDB> = max（1，NRHS）的条件。

注释＃b为（LDB，NRHS）不正确，因为b具有维度（LDB，N），在这种情况下LDB应该为1。

只要NRHS等于1，从LAPACK_ROW_MAJOR切换到LAPACK_COL_MAJOR即可解决此问题。col major（N，1）的内存布局与row major（1，N）相同。 但是，如果NRHS大于1，它将失败。