STM32F1微控制器的链接和内存问题

Question

让我们看一下STM32F103链接描述文件：

/* Entry Point */
ENTRY(Reset_Handler)

/* Highest address of the user mode stack */
_estack = 0x20005000;    /* End of 20K RAM */

/* Generate a link error if heap and stack don't fit into RAM */
_Min_Heap_Size = 0;      /* Required amount of heap  */
_Min_Stack_Size = 0x100; /* Required amount of stack */

/* Specify the memory areas */
MEMORY
{
  FLASH (rx)      : ORIGIN = 0x08000000, LENGTH = 128K
  RAM (xrw)       : ORIGIN = 0x20000000, LENGTH = 20K
  MEMORY_B1 (rx)  : ORIGIN = 0x60000000, LENGTH = 0K
}

/* Define output sections */
SECTIONS
{
  /* The startup code goes first into FLASH */
  .isr_vector :
  {
    . = ALIGN(4);
    KEEP(*(.isr_vector)) /* Startup code */
    . = ALIGN(4);
  } >FLASH

  /* The program code and other data goes into FLASH */
  .text :
  {
    . = ALIGN(4);
    *(.text)           /* .text sections (code) */
    *(.text*)          /* .text* sections (code) */
    *(.rodata)         /* .rodata sections (constants, strings, etc.) */
    *(.rodata*)        /* .rodata* sections (constants, strings, etc.) */
    *(.glue_7)         /* Glue arm to thumb code */
    *(.glue_7t)        /* Glue thumb to arm code */

    KEEP (*(.init))
    KEEP (*(.fini))

    . = ALIGN(4);
    _etext = .;        /* Define a global symbols at end of code */
  } >FLASH


   .ARM.extab   : { *(.ARM.extab* .gnu.linkonce.armextab.*) } >FLASH
    .ARM : {
    __exidx_start = .;
      *(.ARM.exidx*)
      __exidx_end = .;
    } >FLASH

  .ARM.attributes : { *(.ARM.attributes) } > FLASH

  .preinit_array     :
  {
    PROVIDE_HIDDEN (__preinit_array_start = .);
    KEEP (*(.preinit_array*))
    PROVIDE_HIDDEN (__preinit_array_end = .);
  } >FLASH
  .init_array :
  {
    PROVIDE_HIDDEN (__init_array_start = .);
    KEEP (*(SORT(.init_array.*)))
    KEEP (*(.init_array*))
    PROVIDE_HIDDEN (__init_array_end = .);
  } >FLASH
  .fini_array :
  {
    PROVIDE_HIDDEN (__fini_array_start = .);
    KEEP (*(.fini_array*))
    KEEP (*(SORT(.fini_array.*)))
    PROVIDE_HIDDEN (__fini_array_end = .);
  } >FLASH

  /* Used by the startup to initialize data */
  _sidata = .;

  /* Initialized data sections goes into RAM, load LMA copy after code */
  .data : AT ( _sidata )
  {
    . = ALIGN(4);
    _sdata = .;        /* Create a global symbol at data start */
    *(.data)           /* .data sections */
    *(.data*)          /* .data* sections */

    . = ALIGN(4);
    _edata = .;        /* Define a global symbol at data end */
  } >RAM

  /* Uninitialized data section */
  . = ALIGN(4);
  .bss :
  {
    /* This is used by the startup in order to initialize the .bss secion */
    _sbss = .;         /* Define a global symbol at BSS start */
    __bss_start__ = _sbss;
    *(.bss)
    *(.bss*)
    *(COMMON)

    . = ALIGN(4);
    _ebss = .;         /* Define a global symbol at BSS end */
    __bss_end__ = _ebss;
  } >RAM

  PROVIDE ( end = _ebss );
  PROVIDE ( _end = _ebss );

  /* User_heap_stack section, used to check that there is enough RAM left */
  ._user_heap_stack :
  {
    . = ALIGN(4);
    . = . + _Min_Heap_Size;
    . = . + _Min_Stack_Size;
    . = ALIGN(4);
  } >RAM

  /* MEMORY_bank1 section, code must be located here explicitly            */
  /* Example: extern int foo(void) __attribute__ ((section (".mb1text"))); */
  .memory_b1_text :
  {
    *(.mb1text)        /* .mb1text sections (code) */
    *(.mb1text*)       /* .mb1text* sections (code)  */
    *(.mb1rodata)      /* read-only data (constants) */
    *(.mb1rodata*)
  } >MEMORY_B1

  /* Remove information from the standard libraries */
  /DISCARD/ :
  {
    libc.a ( * )
    libm.a ( * )
    libgcc.a ( * )
  }
}

我可以看到，ISR向量位于闪存中，因此，如果程序需要调用存储在某些向量中的地址，它将从闪存中读取。

第一个问题：硬件如何不影响从RAM和闪存读取数据？ 为什么我然后需要特殊的寄存器来以代码形式写入闪存或从闪存中读取数据，而不能仅仅显式地写入或读取其地址？

第二个问题是，从闪存读取比从RAM读取要慢多少？ 而且，如果我知道代码中使用最多的函数，那么是否可以将其移至RAM部分以显着加快执行速度？ 我相信此脚本中的MEMORY_B1专门用于此目的。

第三个问题：如何将长度为0的任何内容放入MEMORY_B1 ？

最后一个问题：如果我在闪存中创建一个附加部分，那么我可以创建虚拟内存的一些简单模拟吗？ 我认为这个问题的答案取决于第一个。

Answer 1

1. 硬件无关紧要，因为两个内存（以及其他所有内存）都映射在公共地址空间中。 但是，这并不意味着您可以轻松地编写闪存以将其视为RAM，因为这样做速度很慢并且会很快损坏该内存（它的典型写入耐久性为100k个周期）。 此外，它只能以整页擦除（对于某些STM32芯片，其擦除大小可能高达128 kB），这确实使它难以替代RAM。

2. 速度差异可忽略不计。 在ARM Cortex-M微控制器上从RAM运行代码的速度将比您预期的慢，因为RAM连接到不同的总线（用于数据），并且将其用于代码执行需要使用较慢的“互连”。

3. 你不能。 如果要在此处放置某些内容，则必须增加内存大小（“正常RAM”的大小-减小）。

4. 通常，您可以这样做，但是速度会非常慢，并且会很快损坏闪光灯。

Answer 2

1/2。 不在STM32F1上。 仅当核心速度超过100 Mhz时，闪存预取和缓存未命中才会使您付出代价。 即使该芯片也具有缓存和预取功能。 如果在某些特殊情况下将向量表放在RAM中，使用此内核可能会产生微不足道的微利。

但是，可能存在硬件限制，该限制适用于所使用的访问宽度 。 但是此闪光灯不受此影响。

3.是的，您当然可以。 您可以在其中放入文件系统。 但是您可以可靠地写入闪存的温度范围受到限制。 并且，由于只有一组闪存，所有活动都将停止，直到成功完成擦除/闪存。 除非代码从RAM运行。 另外两个警告是，闪存编程/擦除可能要花费毫秒，并且您必须考虑每个页面擦除2 kB的情况，但是所有闪存控制器都必须这样做。

如果您需要额外的RAM，请在板上放置一些SPI FRAM。