OpenGL，具有正交投影的几何着色器

Question

这是一个绘制抗锯齿线的简单程序。 该程序有效，如果我添加投影，我只会遇到问题。 我必须在另一个上下文中使用这个程序，我必须在那里使用正投影。 我想我必须替换几何着色器中的参数“win_scale”，但我不知道我必须如何缩放结果，或者如果我使用投影，我必须如何重写函数。 这是着色器。 顶点着色器：

#version 330 core
layout (location = 0) in vec2 position;
layout (location = 1) in vec3 color;

uniform mat4 model;
//uniform mat4 view;
uniform mat4 projection;

out VS_OUT {
    vec3 color;
} vs_out;

void main() {
    gl_Position = projection * vec4(position.x, position.y, 0.0f, 1.0f);
    vs_out.color = color;
}

几何着色器

#version 330 core
layout (points) in;
layout (triangle_strip, max_vertices = 4) out;

uniform vec2 target;

uniform float thickness;
uniform vec2 win_scale; //window width and height

in VS_OUT {
    vec3 color;
} gs_in[];

out vec3 fColor;

vec2 screen_space(vec4 vertex) {
    return vec2(vertex.xy/vertex.w) * win_scale;

}

void main() {
    fColor = gs_in[0].color;
    vec2 p0 = screen_space(gl_in[0].gl_Position); // gs_in[0] since there's only one input vertex
    vec2 p1 = target * win_scale;

    // determine the direction of each of the  segments
    vec2 v0 = normalize(p1-p0);
    // determine the normal of each of the segments
    vec2 n0 = vec2(-v0.y, v0.x);


    gl_Position = vec4((p0 - thickness * n0)/win_scale, 0.0, 1.0);
    EmitVertex();
    gl_Position = vec4((p0 + thickness * n0)/win_scale, 0.0, 1.0);
    EmitVertex();
    gl_Position = vec4((p1 - thickness * n0)/win_scale, 0.0, 1.0);
    EmitVertex();
    gl_Position = vec4((p1 + thickness * n0)/win_scale, 0.0, 1.0);
    EmitVertex();        

    EndPrimitive();
}

我主要通过以下方式传递投影值：

glm::mat4 proj = glm::ortho(0.f, (float)width, 0.f, (float)height, -1.f, 1.f);
glUniformMatrix4fv(glGetUniformLocation(shader.Program, "projection"), 1, GL_FALSE, glm::value_ptr(proj));

当然，如果有人对我如何实施更好的抗锯齿线有建议，欢迎提出这些建议。

Answer 1

您应该将顶点位置传递给几何着色器

out VS_OUT {
    vec2 pos;
    vec3 color;
} vs_out;

void main()
{
    vs.out.pos = position;

    .....
}

然后，您可以在几何着色器中进行计算，并使用与在顶点着色器中相同的方式在几何着色器中使用projection矩阵：

in VS_OUT {
    vec2 pos;
    vec3 color;
} gs_in[];


uniform mat4 projection;
uniform vec2 win_scale; // compensation for the view matrix 

void main()
{
    .....

    vec2 p0 = gs_in[0].pos
    vec2 p1 = target;

    // determine the direction of each of the  segments
    vec2 v0 = normalize(p1-p0);
    // determine the normal of each of the segments
    vec2 n0 = vec2(-v0.y, v0.x);

    ....

    gl_Position = projection * vec4((p0 - thickness*n0)/win_scale, 0.0, 1.0); EmitVertex();  
    gl_Position = projection * vec4((p0 + thickness*n0)/win_scale, 0.0, 1.0); EmitVertex();  
    gl_Position = projection * vec4((p1 - thickness*n0)/win_scale, 0.0, 1.0); EmitVertex();  
    gl_Position = projection * vec4((p1 + thickness*n0)/win_scale, 0.0, 1.0); EmitVertex();

    ....
}

请注意，常见的解决方案是绘制GL_LINES 、 GL_LINE_STRIP或GL_LINE_LIST并使用具有输入布局lines的几何着色器：

#version 330 core
layout (lines) in;
layout (triangle_strip, max_vertices = 4) out;

uniform float thickness;
uniform mat4 projection;
uniform vec2 win_scale; // compensation for the view matrix 

in VS_OUT {
    vec2 pos;
    vec3 color;
} gs_in[];

out vec3 fColor;

void main() {
    fColor = gs_in[0].color;

    vec2 p0 = gs_in[0].pos;
    vec2 p1 = gs_in[1].pos;

    vec2 v0 = normalize(p1-p0);
    vec2 n0 = vec2(-v0.y, v0.x);

    gl_Position = projection * vec4((p0 - thickness*n0)/win_scale, 0.0, 1.0); EmitVertex();  
    gl_Position = projection * vec4((p0 + thickness*n0)/win_scale, 0.0, 1.0); EmitVertex();  
    gl_Position = projection * vec4((p1 - thickness*n0)/win_scale, 0.0, 1.0); EmitVertex();  
    gl_Position = projection * vec4((p1 + thickness*n0)/win_scale, 0.0, 1.0); EmitVertex();  

    EndPrimitive();
}

进一步查看Khronos OpenGL wiki - 几何着色器：

注意，在渲染中，场景的每个对象通常都由模型矩阵、视图矩阵和投影矩阵进行变换。

• 投影矩阵：
  投影矩阵描述了从场景的 3D 点到视口的 2D 点的映射。 投影矩阵从视图空间转换到裁剪空间，裁剪空间中的坐标转换为(-1, -1, -1)到(1, 1, 1)范围内的归一化设备坐标(NDC)通过除以剪辑坐标的w分量。

• 查看矩阵：
  视图矩阵描述了观察场景的方向和位置。 视图矩阵从世界空间转换到视图（眼睛）空间。 在视口的坐标系中，X 轴指向左侧，Y 轴指向上方，Z 轴指向视图外（注意在右手坐标系中，Z 轴是 X 轴的叉积）轴和 Y 轴）。

• 模型矩阵：
  模型矩阵定义了场景中网格的位置、方向和相对大小。 模型矩阵将顶点位置从网格转换到世界空间。

这意味着顶点到裁剪空间的转换是这样工作的：

gl_Position = projection * view * model * vec4( pos.xyz, 1.0 );

由于您有一个带有正交投影的 2D 场景，因此您可以跳过模型矩阵和视图矩阵的转换。 在您的情况下，您可以通过除以win_scale弥补这win_scale ：

gl_Position = projection * vec4( pos.xy/win_scale, 0.0, 1.0 ); 

进一步查看OpenGL - 鼠标坐标到空间坐标：