在Prolog中是否有相当于Haskell的enumFromTo？

Question

我刚刚开始使用Prolog，我希望执行以下任务：

使谓词A(P,N,L)成为对于作为L第n个元素的所有C ， P(N,C) 。

基本上我想在范围[0..N]上执行一个地图。 在Haskell，我最熟悉的语言，这看起来像

f p n = map(p)[0..n]

（Haskell没有谓词，所以我在这里采取一些自由）

或者在无点上

f = (.enumFromTo 0).map

似乎我应该能够轻松地在Prolog中完成它。 Prolog的maplist/3基本上就是这样，所以它应该是一个微不足道的修改。 我的定义应该类似于：

A(P,N,L) :- maplist(P, ??? , L).

但是，我无法弄清楚要放在空白处的内容。 在Haskell中，我会使用像enumFromTo这样的函数，但似乎Prolog中不存在这样的东西。 关闭等价物将between/3 ，但这不是一个列表，所以我不能用于maplist 。

或者，我可以制作自己的范围谓词。

我尝试的第一件事是：

range(0,[0]).
range(N,[N|T]) :- range(N-1,T).
A(P,N,L) :- range(N,rangeN), maplist(P, rangeN, L).

但我根本无法解决这个问题。 我也试过了

range(N,L):-findall(X,between(0,N,X),L),sort(L,L).
A(P,N,L) :- range(N,rangeN), maplist(P, rangeN, L).

但对于这么小的问题，这似乎真的很笨拙。

我怎么可能填补了我的差距maplist ？ 我是以错误的方式解决问题了吗？

Answer 1

-- % f p n = map (p) [0..n] = [p 0, p 1, p 2, ..., p n]

被翻译成Prolog为

f(P,N,L):- f(P,0,N,L).
f(P,I,N,[]):- I > N.
f(P,I,N,L):- call(P,I,X), 
             ( N =:= I -> L = [X]
             ; L = [X|T], J is I+1, f(P,J,N,T) ).

这假设p :: Int -> a表示某些a ，如Haskell代码所暗示的那样。

这也假设给你一个具体的（“地面”）可调用的双参数谓词P和一个整数N

另一种可能性是

g(P,N,L):- findall(X, (between(0, N, I), call(P,I,X)), L).

这找到所有X s，使得（ 0 <= I <= N 且 P(I,X) ）成立。

在SWI-Prolog中测试：

 11 ?- [user]. add1(X,Y):- Y is X+1. |: 12 ?- f(add1,5,L). L = [1, 2, 3, 4, 5, 6]. 13 ?- g(add1,5,L). L = [1, 2, 3, 4, 5, 6]. 

Answer 2

当我试图在Prolog中编写N皇后问题的解决方案时，如Picat home所述（参见示例5，页面附近），我遇到了类似的问题。 这是我的最终结果，并评论了一些替代方案：

:- use_module(library(clpfd)).

queens(N, Q) :-
    length(Q, N),
    Q ins 1..N,
    all_different(Q),
    maplist_index([I,V,P]>>(P#=V+I),1,Q,Ps),all_different(Ps),
    maplist_index([I,V,M]>>(M#=V-I),1,Q,Ms),all_different(Ms),
    /* no
    bagof(P, (nth1(I,Q,V), P #= V + I), Ps), all_different(Ps),
    bagof(M, (nth1(I,Q,V), M #= V - I), Ms), all_different(Ms),
    */
    /* ok
    all_different_p(Q, 1, P), all_different(P),
    all_different_m(Q, 1, M), all_different(M),
    */
    label(Q).

all_different_p([Q|Qs], I, [P|Ps]) :-
    P #= Q + I,
    succ(I, J),
    all_different_p(Qs, J, Ps).
all_different_p([], _I, []).

all_different_m([Q|Qs], I, [P|Ps]) :-
    P #= Q - I,
    succ(I, J),
    all_different_m(Qs, J, Ps).
all_different_m([], _I, []).

maplist_index(P, I, [X|Xs], [Y|Ys]) :-
    call(P, I, X, Y),
    succ(I, J),
    maplist_index(P, J, Xs, Ys).
maplist_index(_, _, [], []).

maplist_index / 4是您需要的一个示例。 值得注意的是，bagof / 3在存在属性变量时效果不佳。