xsltproc合并xml文件不起作用

Question

嗨，我必须在以下条件下合并xml文件：

复制新文件的所有现有节点，然后与旧文件值合并。 例如：

文件abc.xml

<?xml version="1.0"?>
<schedule>
    <Item Id="2">
        <measurements>
            <measurement>Alpha</measurement>
        </measurements>
    </Item>
    <Item Id="9">
        <measurements>
            <measurement>Gamma</measurement>
        </measurements>
    </Item>
</schedule>

文件xyz.xml

<?xml version="1.0"?>
<schedule>
    <Item Id="1">
        <measurements>
            <measurement>Alpha</measurement>
        </measurements>
    </Item>
    <Item Id="4">
        <measurements>
            <measurement>Beta</measurement>
        </measurements>
    </Item>
</schedule>

xslt逻辑文件：logic.xslt

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" standalone="no" indent="yes"/>

<xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()" />
    </xsl:copy>
</xsl:template>

<xsl:template match="Item">
    <xsl:variable name="match" select="document('./abc.xml')/schedule/Item[measurements/measurement=current()/measurements/measurement]"/>
    <xsl:choose>
        <xsl:when test="$match">
            <xsl:copy-of select="$match"/>
        </xsl:when>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

使用的命令：

xsltproc logic.xslt xyz.xml > output.xml

预期产量：

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<schedule>
    <Item Id="2">
        <measurements>
            <measurement>Alpha</measurement>
        </measurements>
    </Item>
    <Item Id="4">
        <measurements>
            <measurement>Beta</measurement>
        </measurements>
    </Item>
    <Item Id="9">
        <measurements>
            <measurement>Gamma</measurement>
        </measurements>
    </Item>
</schedule>

但是实际不同于预期的如下：

<?xml version="1.0" encoding="UTF-8" standalone="no"?>
<schedule>
    <Item Id="2">
        <measurements>
            <measurement>Alpha</measurement>
        </measurements>
    </Item>
    <Item Id="9">
        <measurements>
            <measurement>Gamma</measurement>
        </measurements>
    </Item>
</schedule>

它错过了新xml文件中的节点。

Answer 1

更改

<xsl:choose>
    <xsl:when test="$match">
        <xsl:copy-of select="$match"/>
    </xsl:when>
</xsl:choose>

至

<xsl:choose>
    <xsl:when test="$match">
        <xsl:copy-of select="$match"/>
    </xsl:when>
    <xsl:otherwise>
        <xsl:copy-of select="."/>
</xsl:choose>

通过编辑问题和需要复制第二个文档中的其他元素，我认为问题更加棘手，使用XSLT 3，您可以像在https://xsltfiddle.liberty-development.net/pPqsHTf中那样进行操作

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:xs="http://www.w3.org/2001/XMLSchema"
    exclude-result-prefixes="xs"
    version="3.0">

    <xsl:mode on-no-match="shallow-copy"/>

    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes"/>

    <xsl:param name="doc1" select="/"/>

    <xsl:param name="doc2">
        <schedule>
            <Item Id="2">
                <measurements>
                    <measurement>Alpha</measurement>
                </measurements>
            </Item>
            <Item Id="9">
                <measurements>
                    <measurement>Gamma</measurement>
                </measurements>
            </Item>
        </schedule>      
    </xsl:param>

    <xsl:key name="ref" match="Item" use="measurements/measurement"/>

    <xsl:template match="schedule">
        <xsl:copy>
            <xsl:apply-templates select="Item, $doc2/schedule/Item[not(key('ref', measurements/measurement, $doc1))]"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="Item[root() is $doc1 and key('ref', measurements/measurement, $doc2)]">
        <xsl:copy-of select="key('ref', measurements/measurement, $doc2)"/>
    </xsl:template>

</xsl:stylesheet>

（当然，不用内联第二个文档，您可以使用<xsl:param name="doc2" select="document('abc.xml')"/> ），但是对于XSLT 1，使用变量和键，您不能在匹配模式中使用它们，因此似乎需要一种方法，如https://xsltfiddle.liberty-development.net/pPqsHTf/2

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">


    <xsl:strip-space elements="*"/>
    <xsl:output indent="yes"/>

    <xsl:param name="doc1" select="/"/>

    <xsl:param name="doc2-rtf">
        <schedule>
            <Item Id="2">
                <measurements>
                    <measurement>Alpha</measurement>
                </measurements>
            </Item>
            <Item Id="9">
                <measurements>
                    <measurement>Gamma</measurement>
                </measurements>
            </Item>
        </schedule>      
    </xsl:param>

    <xsl:param name="doc2" select="exsl:node-set($doc2-rtf)" xmlns:exsl="http://exslt.org/common"/>

    <xsl:template match="schedule">
        <xsl:copy>
            <xsl:apply-templates select="Item"/>
            <xsl:copy-of select="$doc2/schedule/Item[not(measurements/measurement = $doc1//Item/measurements/measurement)]"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="Item">
        <xsl:choose>
            <xsl:when test="measurements/measurement = $doc2//Item/measurements/measurement">
                <xsl:copy-of select="$doc2//Item[measurements/measurement = current()/measurements/measurement]"/>              
            </xsl:when>
            <xsl:otherwise>
                <xsl:copy-of select="."/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

当然，再次简单地使用<xsl:param name="doc2" select="document('abc.xml')"/>而不是使用数据内联（我只是做一个完整的示例，不幸的是使用XSLT 1然后需要使用节点集扩展功能）。